Le tableau de sortie de MsgBox

Je ne PowerShell pas VBScript, donc je suis un peu perdu. Je suis en train de la liste de tous les lecteurs mappés (lettre de lecteur et le chemin d'accès au partage) dans un MsgBox. Je reçois une erreur d'incompatibilité de type lors de l'exécution du script. Si je change "Dim montableau()" à "Dim montableau" je obtenir un seul élément de la variable.

Set objNetwork = WScript.CreateObject("WScript.Network")
Set colDrives = objNetwork.EnumNetworkDrives
Dim myArray()
For i = 0 to colDrives.Count-1 Step 2
 myArray = colDrives.Item(i) & vbTab & colDrives.Item (i + 1)
Next
MsgBox(myArray)

Comment puis-je obtenir les données sont enregistrées dans un tableau, puis la sortie d'une boîte de Message?

InformationsquelleAutor user3208164 | 2014-07-24
  1. 3

    Vous pouvez utiliser une chaîne de caractères et de garder ajout (&en a).

    Dim s
For i = 0 To colDrives.Count-1 Step 2
    s = s & colDrives.Item(i) & vbTab & colDrives.Item (i + 1) & vbCrLf
Next

MsgBox s
    • C'est super, merci!
    InformationsquelleAutor Bond
  2. 4

    La raison pour laquelle votre code ne fonctionne pas c'est parce que vous êtes la création de tableau de taille fixe sans taille réelle (Dim myArray()), puis essayez d'affecter les valeurs de ce tableau. En VBScript, vous devez affecter des valeurs à des positions de tableau (myArray(pos) = val), et vous ne pouvez pas ajouter à la fonction intégrée dans les tableaux (au moins pas sans un peu plus de travail).

    L'approche la plus simple dans votre cas, serait la méthode @Bond suggéré. Cependant, vous peut le faire avec des tableaux si vous le souhaitez. Vous avez juste besoin d'un redimensionnable tableau comme ceci:

    ReDim myArray(-1)  'empty array
For i = 0 to colDrives.Count-1 Step 2
  ReDim Preserve myArray(UBound(myArray)+1)
  myArray(UBound(myArray)) = colDrives.Item(i) & vbTab & colDrives.Item(i+1)
Next

MsgBox Join(myArray, vbNewLine)

    ou (à l'aide d'un ArrayList), comme ceci:

    Set myArray = CreateObject("System.Collections.ArrayList")
For i = 0 to colDrives.Count-1 Step 2
  myArray.Add colDrives.Item(i) & vbTab & colDrives.Item(i+1)
Next

MsgBox Join(myArray.ToArray, vbNewLine)

    Puisque la taille de la matrice peuvent déjà être déterminé avant d'entrer dans la boucle, vous pouvez également la dimension du tableau avec la bonne taille tout de suite pour éviter la répétition redimensionnement des images (qui tend à faire mal pour VBScript intégré dans les tableaux):

    ReDim myArray(colDrives.Count \ 2 - 1)
For i = 0 to colDrives.Count-1 Step 2
  myArray(i\2) = colDrives.Item(i) & vbTab & colDrives.Item(i+1)
Next

MsgBox Join(myArray, vbNewLine)

    Une autre option serait d'utiliser un Dictionnaire:

    Set myArray = CreateObject("Scripting.Dictionary")
For i = 0 to colDrives.Count-1 Step 2
  myArray(colDrives.Item(i)) = colDrives.Item(i) & vbTab & colDrives.Item(i+1)
Next

MsgBox Join(myArray.Items, vbNewLine)
    • Ce est grande.
    InformationsquelleAutor Ansgar Wiechers