L'écho de la nième ligne à partir d'un fichier texte où " n " est un argument de ligne de commande

J'ai un fichier texte simple avec des chiffres comme:

J'ai besoin d'un lot qui sera de retour le nème ligne de ce fichier. n doivent être prises à partir d'un argument de ligne de commande.

Je suis très nouveau pour lot de script, donc Merci d'avance pour toute aide sur ce.

est-ce windows ou unix?

OriginalL'auteur Marcos | 2011-06-20

batch-file

6

Pour obtenir le fichier de la nième ligne vous pouvez utiliser plus d' +n (line1 est n=0).

Diviser le reste du fichier, vous pouvez utiliser un FOR /F boucle.

Cela fonctionne même si il y a des lignes vides avant la nième ligne.

Il pourrait être nécessaire de régler la fin de vie d'un caractère non utilisé ou de saut de ligne (par défaut ;)
```
set "lineNr=%1"
set /a lineNr-=1
for /f "usebackq delims=" %%a in (`more +%lineNr% text.txt`) DO (
  echo %%a
  goto :leave
)
:leave
```
comment peut - eol être définie à la ligne d'alimentation?
Je l'ai trouvé ici, merci @jeb!

OriginalL'auteur jeb
2

Vous pouvez utiliser le traitement par lots l'extension de fichier.

jeton.chauve-souris
```
 @echo off

 setlocal ENABLEDELAYEDEXPANSION
 set l=%1
 set c=0
 for /f "delims=" %%1 in ('type foo.txt') do (
   set /a c+=1 && if "!c!" equ "%l%" echo %%1%
 )
```
Si vous avez un fichier comme suit,

foo.txt
```
 AAAA
 BBBB
 CCCC
 DDDD
```
Et spécifier le numéro de ligne comme suit
```
 token 3
```
Vous aurez

CCCC

+1, Tu es plus rapide que moi, mais pourquoi vous pouvez définir la delims à ` and n`?
oups, j'ai enlevé "\n". Merci pour l'avis.
Btw, votre version supprime tous les ! et parfois la ^ à partir de la ligne de sortie
Hmm, je ne peux pas comprendre "pourquoi cela arrive".
Le ! sont supprimés, comme l'expansion retardée est activé, seuls les handicapés expansion, vous pouvez accéder en toute sécurité %%1 voir aussi Script pour supprimer les caractères spéciaux dans les noms de fichiers

OriginalL'auteur mattn
0

Vous pouvez utiliser FOR /F avec le skip paramètre:
```
@ECHO OFF
SET skip=%1
SET /A skip-=1
IF %skip% LSS 0 GOTO out
IF %skip% GTR 0 SET params="skip=%skip%"
FOR /F %params% %%L IN (filename) DO (SET "line=%%L"& GOTO out)
:out
ECHO %line%
```
La skip paramètre désigne le FOR /F boucle doit passer le nombre spécifié de lignes au début. Le paramètre s'applique uniquement si vous spécifiez un numéro de ligne supérieure à 1. Si vous spécifiez un nombre moins d'un ou d'une non-nombre, le script génère une chaîne vide.

OriginalL'auteur Andriy M
0

+1 pour Jeb de solution... je ne savais pas que vous pourriez utiliser le plus de commande pour passer les lignes comme ça!

Voici une autre méthode que j'utilise pour obtenir une ligne spécifique à partir d'un fichier (ou du multi-ligne de sortie d'un autre programme):
```
@echo off
for /f "tokens=1* delims=:" %%a in ('findstr /n .* "C:\SomeFile.txt"') do (
  if "%%a" equ "%1" echo.%%b
)
```
- Je utiliser findstr /n .* "Path\FileName.ext" pour ajouter des numéros de ligne, et pour s'assurer qu'aucune des lignes vides sont ignorées par la boucle for.

Je puis mettre "tokens=1* delims=:" pour séparer les numéros de ligne de la ligne de contenu.

Enfin, je compare le numéro de ligne courant (%%un) avec la ligne spécifiée par le %1 paramètre, et l'écho de la ligne de contenus (%%b) sur un match.

OriginalL'auteur Seth McCauley

Pour Trouver Nième au Mois de Caractères Dans la Ligne No. L --- Exemple Pour La Recherche De L'Étiquette

@echo off

REM Next line = Set command value to a file  OR  Just Choose Your File By Skipping The Line
vol E: > %temp%\justtmp.txt
REM  Vol E:  = Find Volume Lable Of Drive E

REM  Next Line to choose line line no. +0 = line no. 1 
for /f "usebackq delims=" %%a in (`more +0 %temp%\justtmp.txt`) DO (set findstringline=%%a& goto :nextstep)

:nextstep

REM  Next line to read nth to mth Character  here 22th Character to 40th Character
set result=%findstringline:~22,40%

echo %result%
pause
exit /b

Enregistrer comme trouver de l'étiquette.cmd

Le Résultat Sera Votre Lecteur De E Label

Profiter de

OriginalL'auteur Amit

Basé sur Amit Réponse, j'ai fait un utilitaire appelé snip.cmd.

UTILISATION: snip FICHIER LIGNE FIRSTCHARACTER LASTCHARACTER

exemple:

foo.txt

    //
    //File Checksum Integrity Verifier version 2.05.
    //
    77752e4c91ba96dcc6c2bb4bdcdbdec5 c:\users\lapinot\desktop\token.bat

snip foo.txt 3 0 33 donnera 77752e4c91ba96dcc6c2bb4bdcdbdec5

Voici mon code pour le snipe.cmd (vous pouvez ajouter de la bécassine à votre ligne de commande par la copie de la capture.cmd pour c:\Windows\System32):

    @echo off
    :: USAGE
    :: snip <file> [Line - Starts at 0] [First Column - Start Count at 0] [Last Colum]


    set file=%1
    set line=%2
    set char1=%3
    set char2=%4

    for /f "usebackq delims=" %%a in (`more +%line% %file%`) DO (set findstringline=%%a& goto :nextstep)

    :nextstep
    echo echo %%findstringline:^~%char1%,%char2%%% > %temp%\result.bat
    %temp%\result.bat
    del %temp%\result.bat
    :EOF
    exit /b

OriginalL'auteur thebunnyrules

-2

echo "enter the line number.."; read i; awk 'NR==$i' <file_name>;

La question est marqué comme [lot-fichier], de sorte que votre solution ne convient pas à

OriginalL'auteur uddeep

Vous devez vous connecter pour publier un commentaire.