Les constructeurs de surcharge dans VBScript

J'ai trouvé un moyen d'étendre des classes en VBScript, mais est-il possible de passer des paramètres ou la surcharge du constructeur? Je suis actuellement en utilisant une fonction Init pour initialiser les propriétés, mais j'aimerais être capable de faire cela quand je crée l'objet.
C'est mon exemple de classe:

Class Test
    Private strText

    Public Property Get Text
        Text = strText
    End Property

    Public Property Let Text(strIn)
        strText = strIn
    End Property

    Private Sub Class_Initialize()  
        Init
    End Sub  

    Private Sub Class_Terminate()   

    End Sub 

    Private Function Init
        strText = "Start Text"
    End Function    
End Class

Et j'ai créer il

Set objTest = New Test

Mais voudrais faire quelque chose comme ceci

Set objTest = New Test(strInitText)

Est-ce possible, ou est-ce l'objet doit être créé et initialisé dans deux setps?

source d'informationauteur Tester101

  1. 22

    Juste de modifier légèrement sur svinto de la méthode...

    Class Test
  Private m_s
  Public Default Function Init(s)
    m_s = s
    Set Init = Me
  End Function
  Public Function Hello()
    Hello = m_s
  End Function
End Class

Dim o : Set o = (New Test)("hello world")

    Est de savoir comment je le fais. Malheureusement, pas de surcharge.

    [modifier]
    Mais si vous avez vraiment envie de vous pourriez faire quelque chose comme ça...

    Class Test
    Private m_s
    Private m_i

    Public Default Function Init(parameters)
         Select Case UBound(parameters)
             Case 0
                Set Init = InitOneParam(parameters(0))
             Case 1
                Set Init = InitTwoParam(parameters(0), parameters(1))
             Else Case
                Set Init = Me
         End Select
    End Function

    Private Function InitOneParam(parameter1)
        If TypeName(parameter1) = "String" Then
            m_s = parameter1
        Else
            m_i = parameter1
        End If
        Set InitOneParam = Me
    End Function

    Private Function InitTwoParam(parameter1, parameter2)
        m_s = parameter1
        m_i = parameter2
        Set InitTwoParam = Me
    End Function
End Class

    Qui donne les constructeurs...

    Test()
Test(string)
Test(integer)
Test(string, integer)

    lequel vous pouvez appeler:

    Dim o : Set o = (New Test)(Array())
Dim o : Set o = (New Test)(Array("Hello World"))
Dim o : Set o = (New Test)(Array(1024))
Dim o : Set o = (New Test)(Array("Hello World", 1024))

    Peu de douleur.

  2. 6

    Vous pouvez contourner le problème en ayant votre fonction Init retour de l'objet lui-même...

    Class Test
  Private m_s
  Public Function Init(s)
    m_s = s
    Set Init = Me
  End Function
  Public Function Hello()
    Hello = m_s
  End Function
End Class

Dim o
Set o = (New Test).Init("hello world")
Echo o.Hello
  3. 2

    Vous devez procéder en deux étapes. VB Script ne prend pas en charge la surcharge de sorte que vous ne pouvez pas modifier le constructeur par défaut avec de nouveaux paramètres. En va de même pour Vb6

  4. 1

    Un peu hackish, pour sûr, mais quand j'ai besoin varargs dans les appels, l'un de mes paramètres je passe comme un tableau, c'est à dire

    Rem printf done poorly
sub printf(fmt, args)
  dim fp, vap:
  dim outs:
  dim fini:
      fini = 0:
      vap = 0:
  while (not fini)
    fp = index(fmt,"%"):
    if (not(isNull(fp))) then
        ' do something with %f, %s
        select case(fp)
        case 'c':
          outs = outs & charparse(args(vap)):
        case 's':
          outs = outs & args(vap):
        ' and so on.  Quite incomplete but you get the idea.
        end select
        vap = vap + 1
    end if
  wend
end sub

printf("%s %d\n",array("Hello World", 42)):