Les Fichiers Batch. SI les déclarations?

j'ai un fichier batch qui doit appliquer la attrib +h commande vers un fichier, puis la sortie vers un fichier txt et contenu de l'affichage sur écran. Cela devrait également être fait si le fichier n'a pas été fourni ou ne peut pas être trouvé. J'ai jusqu'à présent, mais ne peut pas le faire fonctionner:

:TOP
IF EXIST "%1" GOTO COMMAND
) ELSE
(
GOTO ERROR1

:COMMAND
attrib +h %1
SHIFT
GOTO TOP
GOTO END

:ERROR1
IF "%1"=="" GOTO ERROR2
) ELSE
(
GOTO ERROR3

:ERROR2
ECHO.
ECHO No file(s) provided. Please re run the batch file.
GOTO END

:ERROR3
ECHO.
ECHO The file was not found. Please re run the batch file.
GOTO END

:END

C'est mon premier cours d'informatique et de toute aide sera grandement appréciée. Merci.

Pour commencer: Comment l'Interpréteur de Commande analyse des scripts Batch beaucoup de Ressources: ss64, Rob van der Woude, DosTips
Afin de rendre votre code plus lisible, envisager de renommer l'erreur étiquettes. Par exemple, au lieu de ERROR2, dire NOFILE. Pour ERROR3, dire NOTFOUND.

OriginalL'auteur SmkErrl | 2014-03-11

  1. 12

    Il existe quelques problèmes avec ce code. Tout d'abord, les fichiers de commandes nécessitent une syntaxe spécifique avec leur IF /ELSE consolidés.

    Quelque chose comme cela

    IF EXIST "%1" (
    echo "it's here!"
) ELSE (
    echo "it isn't here!"
)

    fonctionne correctement, tandis que quelque chose comme cela 

    IF EXIST "%1" 
(
    echo "it's here!"
) 

ELSE 
(
    echo "it isn't here!"
)

    ne le fait pas. Les parenthèses délimitent le bloc, de sorte que votre IF commande sera exécutée tout entre ( et ) si elle est true.

    Deuxièmement, vous n'avez pas besoin de tout ELSE consolidés. Parce que vous êtes à l'aide de GOTO commandes juste avant votre ELSE commandes, vous ne serez jamais atteindre le second GOTO commande si le premier IF évalue à true.

    Enfin, avec le code que vous avez actuellement le montrent, les :TOP tag que vous avez à faire est inutile.

    Après tout cela, vous devriez être à gauche avec quelque chose qui ressemble à ceci:

    @ECHO off
IF EXIST "%1" (
    GOTO COMMAND
)
GOTO ERROR1

:COMMAND
    echo "You entered a file correctly, and it exists!"
    GOTO END

:ERROR1
    IF "%1"=="" (
        GOTO ERROR2
    )
    GOTO ERROR3

:ERROR2
    ECHO.
    ECHO No file(s) provided. Please re run the batch file.
    GOTO END

:ERROR3
    ECHO.
    ECHO The file was not found. Please re run the batch file.
    GOTO END

:END
    Cela le rend plus facile à comprendre, mon professeur avait-il formatées différemment, ce qui rend plus difficile à lire.
    Une astuce pour l'avenir: ne pas dire aux gens que c'est de vos devoirs. Vous aurez probablement obtenir plus d'aide.

    OriginalL'auteur Nate Mara

  2. 2

    Juste quelques problèmes avec la parenthèse et logique de flux

    @ECHO OFF

    IF "%~1"=="" GOTO ERROR1

:TOP
    IF NOT EXIST "%~1" GOTO ERROR2
    attrib +h "%~1"
    IF "%~2"=="" GOTO END
    SHIFT
    GOTO TOP

:ERROR1
    ECHO.
    ECHO No file(s) provided. Please re run the batch file.
    GOTO END

:ERROR2
    ECHO.
    ECHO The file "%~1" was not found. Please re run the batch file.
    GOTO END

:END

    OriginalL'auteur MC ND

  3. 1

    Je ne suis pas familiers avec le Lot, mais il semble comme Si votre déclaration est mal formaté.

    IF EXIST "%1" (
    GOTO COMMAND
) ELSE
(
    GOTO ERROR1
)

    OriginalL'auteur Justin