L'espace libre dans un CMD shell

Si vous exécutez "dir c:\", la dernière ligne vous donnera l'espace disque libre.

Edit:
Meilleure solution: "fsutil volume diskfree c:"

Vous pouvez éviter les virgules par l'utilisation de /-C sur la commande DIR.

FOR /F "usebackq tokens=3" %%s IN (`DIR C:\ /-C /-O /W`) DO (
    SET FREE_SPACE=%%s
)
ECHO FREE_SPACE is %FREE_SPACE%

Si vous voulez comparer l'espace disponible à l'espace nécessaire, vous pourriez faire quelque chose comme ce qui suit. J'ai spécifié le nombre avec séparateur de milliers, puis les retirer. Il est difficile de saisir le nombre sans virgule. L'UNE est belle, mais elle arrête de travailler avec de grands nombres.

SET EXITCODE=0
SET NEEDED=100,000,000
SET NEEDED=%NEEDED:,=%

IF %FREE_SPACE% LSS %NEEDED% (
    ECHO Not enough.
    SET EXITCODE=1
)
EXIT /B %EXITCODE%

df.exe

Montre tous vos disques; total, utilisé et l'espace disponible. Vous pouvez modifier la sortie par les différentes options de ligne de commande.

Vous pouvez l'obtenir à partir d' http://www.paulsadowski.com/WSH/cmdprogs.htm, http://unxutils.sourceforge.net/ ou quelque part d'autre. C'est un standard unix-util comme du.

df -h montrera tous de votre disque dur espace disque utilisé et disponible. Par exemple:

M:\>df -h
Filesystem      Size  Used Avail Use% Mounted on
C:/cygwin/bin   932G   78G  855G   9% /usr/bin
C:/cygwin/lib   932G   78G  855G   9% /usr/lib
C:/cygwin       932G   78G  855G   9% /
C:              932G   78G  855G   9% /cygdrive/c
E:              1.9T  1.3T  621G  67% /cygdrive/e
F:              1.9T  201G  1.7T  11% /cygdrive/f
H:              1.5T  524G  938G  36% /cygdrive/h
M:              1.5T  524G  938G  36% /cygdrive/m
P:               98G   67G   31G  69% /cygdrive/p
R:               98G   14G   84G  15% /cygdrive/r

Cygwin est disponible gratuitement à partir de: https://www.cygwin.com/
Il ajoute de nombreux outils puissants à l'invite de commande. Pour obtenir tout l'espace disponible sur le lecteur M (comme mappé dans windows sur un lecteur partagé), on pourrait entrer dans:

M:\>df -h | grep M: | awk '{print $4}'

À l'aide de paxdiablo excellente solution, j'ai écrit un peu plus sophistiqué script batch, qui utilise la lettre de lecteur que l'argument entrant et vérifie si le lecteur existe un sujet délicat (mais pas de la beauté) de manière à:

@echo off
setlocal enableextensions enabledelayedexpansion
set chkfile=drivechk.tmp
if "%1" == "" goto :usage
set drive=%1
set drive=%drive:\=%
set drive=%drive::=%
dir %drive%:>nul 2>%chkfile%
for %%? in (%chkfile%) do (
  set chksize=%%~z?
)
if %chksize% neq 0 (
  more %chkfile%
  del %chkfile%
  goto :eof
)
del %chkfile%
for /f "tokens=3" %%a in ('dir %drive%:\') do (
  set bytesfree=%%a
)
set bytesfree=%bytesfree:,=%
echo %bytesfree% byte(s) free on volume %drive%:
endlocal

goto :eof
:usage
  echo.
  echo   usage: freedisk ^<driveletter^> (eg.: freedisk c)

note1: vous pouvez taper simple lettre (par exemple. x) ou peut utiliser x: x:\ format en tant que lettre de lecteur dans l'argument

note2: script va afficher la sortie stderr d' %chkfile% seulement si la taille plus grand que 0

nota3: j'ai sauvé ce script comme freedisk.cmd (voir la section utilisation)

Sur Windows 10, le copy et xcopy opérations ne sont pas immédiatement, dans le cas où un fichier est copié qui est trop grand pour le répertoire cible. Donc, il n'est pas nécessaire pour vérifier l'espace disque disponible avant de commencer l'opération de copie.