L'exportation de données à partir de PowerPivot

Pour obtenir une table PowerPivot dans Excel:

1. Créer un tableau croisé dynamique basé sur vos données PowerPivot.
2. Assurez-vous que le tableau croisé dynamique vous avez créé a quelque chose dans la zone valeurs, mais rien dans les filtres, les colonnes ou les lignes domaines.
3. Go de Données > Connexions.
4. Sélectionnez votre modèle de Données, puis cliquez sur Propriétés.
5. Dans l'onglet Utilisation, OLAP, Percer définir le nombre Maximal d'enregistrements à récupérer aussi haut que vous avez besoin (maximum est de 9999999 de dossiers).
6. Double-cliquez sur les mesures de la zone dans le tableau croisé dynamique de forage.

Un pur Excel /VBA solution est ci-dessous. C'est adapté à partir du code ici à utiliser FileSystemObject et écrire 1k lignes à la fois dans le fichier. Vous aurez besoin d'ajouter de la Bibliothèque Microsoft ActiveX Data Objects et Microsoft Scripting Runtime comme références.

Option Explicit

Public FSO As New FileSystemObject

Public Sub ExportToCsv()

    Dim wbTarget As Workbook
    Dim ws As Worksheet
    Dim rs As Object
    Dim sQuery As String

    'Suppress alerts and screen updates
    With Application
        .ScreenUpdating = False
        .DisplayAlerts = False
    End With

    'Bind to active workbook
    Set wbTarget = ActiveWorkbook

    Err.Clear

    On Error GoTo ErrHandler

    'Make sure the model is loaded
    wbTarget.Model.Initialize

    'Send query to the model
    sQuery = "EVALUATE <Query>"
    Set rs = CreateObject("ADODB.Recordset")
    rs.Open sQuery, wbTarget.Model.DataModelConnection.ModelConnection.ADOConnection
    Dim CSVData As String
    Call WriteRecordsetToCSV(rs, "<ExportPath>", True)

    rs.Close
    Set rs = Nothing

ExitPoint:
    With Application
        .ScreenUpdating = True
        .DisplayAlerts = True
    End With
    Set rs = Nothing
    Exit Sub

ErrHandler:
    MsgBox "An error occured - " & Err.Description, vbOKOnly
    Resume ExitPoint
End Sub



Public Sub WriteRecordsetToCSV(rsData As ADODB.Recordset, _
        FileName As String, _
        Optional ShowColumnNames As Boolean = True, _
        Optional NULLStr As String = "")
    'Function returns a string to be saved as .CSV file
    'Option: save column titles

    Dim TxtStr As TextStream
    Dim K As Long, CSVData As String

    'Open file
    Set TxtStr = FSO.CreateTextFile(FileName, True, True)

    If ShowColumnNames Then
        For K = 0 To rsData.Fields.Count - 1
            CSVData = CSVData & ",""" & rsData.Fields(K).Name & """"
        Next K

        CSVData = Mid(CSVData, 2) & vbNewLine
        TxtStr.Write CSVData
    End If

    Do While rsData.EOF = False
        CSVData = """" & rsData.GetString(adClipString, 1000, """,""", """" & vbNewLine & """", NULLStr)
        CSVData = Left(CSVData, Len(CSVData) - Iif(rsData.EOF, 3, 2))
        TxtStr.Write CSVData
    Loop

    TxtStr.Close

End Sub