L'obtention de navigateur et la version à l'aide de Coldfusion

Est-il quelque chose de construit en Coldfusion, ce qui devrait laisser le moi savoir le navigateur et le numéro de version surf sur mon site? Sont il n'existe pas de bibliothèques qui me permettrait de faire cela?

Mon google-fu n'a pas montré beaucoup d'autres choses que de simples si les déclarations de la détection IE.

J'ai fait faire un dump du cgi.http_user_agent variable dans google Chrome:

Mozilla/5.0 (Windows NT 5.1) AppleWebKit/534.24 (KHTML, like Gecko) Chrome/11.0.696.77 Safari/534.24

Il y a trois différents navigateurs mentionnés dans les il y! Faire une déclaration à la recherche pour l'un et l'autre renvoie la valeur true. Il faut une approche plus formelle?

Tu ne seras pas la détection de browser.
D'accord. Je suis juste en train de reproduire un JS composant Coldfusion. Browser sniffing est qu'une infime partie de ce qu'il fait.
Ce n'est pas en train de dire trois navigateurs. Le AppleWebKit partie juste dit que vous êtes en utilisant un navigateur construit sur le moteur de rendu WebKit (Safari partie est en train de dire la même chose). Je n'ai jamais été sûr de ce que l'Mozilla partie est, mais la seule partie de vous dire un navigateur est google Chrome et la version c'est sur. Lors de la vérification pour Chrome, vous voulez juste pour vérifier AppleWebKit puisque la plupart des navigateurs webkit soutiendra les mêmes choses.

OriginalL'auteur TekiusFanatikus | 2011-06-09

coldfusion user-agent

Il y a une Fonction Définie par l'Utilisateur qui peut analyser le user_agent chaîne.

browserDetect

<cfscript>
/**
 * Detects 130+ browsers.
 * v2 by Daniel Harvey, adds Flock/Chrome and Safari fix.
 * 
 * @param UserAgent      User agent string to parse. Defaults to cgi.http_user_agent. (Optional)
 * @return Returns a string. 
 * @author John Bartlett ([email protected]) 
 * @version 4, June 28, 2009 
 */
function browserDetect() {

//Default User Agent to the CGI browser string
var UserAgent=CGI.HTTP_USER_AGENT;

//Regex to parse out version numbers
var VerNo="/?v?_? ?v?[\(?]?([A-Z0-9]*\.){0,9}[A-Z0-9\-.]*(?=[^A-Z0-9])";

//List of browser names
var BrowserList="";

//Identified browser info
var BrowserName="";
var BrowserVer="";

//Working variables
var Browser="";
var tmp="";
var tmp2="";
var x=0;


//If a value was passed to the function, use it as the User Agent
if (ArrayLen(Arguments) EQ 1) UserAgent=Arguments[1];

//Allow regex to match on EOL and instring
UserAgent=UserAgent & " ";

//Browser List (Allows regex - see BlackBerry for example)
BrowserList="1X|Amaya|Ubuntu APT-HTTP|AmigaVoyager|Android|Arachne|Amiga-AWeb|Arora|Bison|Bluefish|Browsex|Camino|Check&Get|Chimera|Chrome|Contiki|cURL|Democracy|" &
            "Dillo|DocZilla|edbrowse|ELinks|Emacs-W3|Epiphany|Galeon|Minefield|Firebird|Phoenix|Flock|IceApe|IceWeasel|IceCat|Gnuzilla|" &
            "Google|Google-Sitemaps|HTTPClient|HP Web PrintSmart|IBrowse|iCab|ICE Browser|Kazehakase|KKman|K-Meleon|Konqueror|Links|Lobo|Lynx|Mosaic|SeaMonkey|" &
            "muCommander|NetPositive|Navigator|NetSurf|OmniWeb|Acorn Browse|Oregano|Prism|retawq|Shiira Safari|Shiretoko|Sleipnir|Songbird|Strata|Sylera|" &
            "ThunderBrowse|W3CLineMode|WebCapture|WebTV|w3m|Wget|Xenu_Link_Sleuth|Oregano|xChaos_Arachne|WDG_Validator|W3C_Validator|" &
            "Jigsaw|PLAYSTATION 3|PlayStation Portable|IPD|" &
            "AvantGo|DoCoMo|UP.Browser|Vodafone|J-PHONE|PDXGW|ASTEL|EudoraWeb|Minimo|PLink|NetFront|Xiino|";
            //Mobile strings
            BrowserList=BrowserList & "iPhone|Vodafone|J-PHONE|DDIPocket|EudoraWeb|Minimo|PLink|Plucker|NetFront|PIE|Xiino|" &
            "Opera Mini|IEMobile|portalmmm|OpVer|MobileExplorer|Blazer|MobileExplorer|Opera Mobi|BlackBerry\d*[A-Za-z]?|" &
            "PPC|PalmOS|Smartphone|Netscape|Opera|Safari|Firefox|MSIE|HP iPAQ|LGE|MOT-[A-Z0-9\-]*|Nokia|";

            //No browser version given
            BrowserList=BrowserList & "AlphaServer|Charon|Fetch|Hv3|IIgs|Mothra|Netmath|OffByOne|pango-text|Avant Browser|midori|Smart Bro|Swiftfox";

            //Identify browser and version
Browser=REMatchNoCase("(#BrowserList#)/?#VerNo#",UserAgent);

if (ArrayLen(Browser) GT 0) {

    if (ArrayLen(Browser) GT 1) {

        //If multiple browsers detected, delete the common "spoofed" browsers
        if (Browser[1] EQ "MSIE 6.0" AND Browser[2] EQ "MSIE 7.0") ArrayDeleteAt(Browser,1);
        if (Browser[1] EQ "MSIE 7.0" AND Browser[2] EQ "MSIE 6.0") ArrayDeleteAt(Browser,2);
        tmp2=Browser[ArrayLen(Browser)];

        for (x=ArrayLen(Browser); x GTE 1; x=x-1) {
            tmp=Rematchnocase("[A-Za-z0-9.]*",Browser[x]);
            if (ListFindNoCase("Navigator,Netscape,Opera,Safari,Firefox,MSIE,PalmOS,PPC",tmp[1]) GT 0) ArrayDeleteAt(Browser,x);
        }

        if (ArrayLen(Browser) EQ 0) Browser[1]=tmp2;
    }

    //Seperate out browser name and version number
    tmp=Rematchnocase("[A-Za-z0-9. _\-&]*",Browser[1]);

    Browser=tmp[1];

    if (ArrayLen(tmp) EQ 2) BrowserVer=tmp[2];

    //Handle "Version" in browser string
    tmp=REMatchNoCase("Version/?#VerNo#",UserAgent);

    if (ArrayLen(tmp) EQ 1) {
        tmp=Rematchnocase("[A-Za-z0-9.]*",tmp[1]);
        BrowserVer=tmp[2];
    }

    //Handle multiple BlackBerry browser strings
    if (Left(Browser,10) EQ "BlackBerry") Browser="BlackBerry";

    //Return result
    return Browser & " " & BrowserVer;

}

//Unable to identify browser
return "Unknown";

}
</cfscript>

Il sera, bien sûr, commencer à l'échec si les cordes ne sont pas ajoutés comme les nouveaux navigateurs sortir.
J'ai donné +1 pour ce que cela correspond à ce que l'OP a l'intention, mais ce n'est rien, je voudrais compter sur, d'une manière générale.
J'ai juste essayé de le au-dessus de 7 ans UDF et il est revenu "Chrome 42" pour un avantage client. Ont-elles été mises à jour depuis 2011? Comme un résultat, je suis passé à BrowscapCFC & mises en cache résultats de la recherche (pour la performance) que l'BrowsCap.org site web maintient la base de données mise à jour et fournit plus d'informations (plate-forme, robot, table, mobile, etc)

OriginalL'auteur ale

5

Pourriez-vous pas utiliser de javascript à la place? http://cssuseragent.org/

CSSUA est génial, ajoute des classes simples pour le tag et vous permet de cibler le contenu en CSS/Javascript à l'aide de classes comme ua-ie-6 etc

Merci pour l'astuce!
C'est la meilleure solution que j'ai est venu autour

OriginalL'auteur Jon Joyce
5

C'est beaucoup plus facile que la fonction compliquée présenté plus tôt...
```
<CFIF FindNoCase('Chrome','#CGI.HTTP_USER_AGENT#') GREATER THAN 0>
  <CFSET browser = 'Chrome'>
</CFIF>
```
de crédit: http://www.paulsilver.co.uk/code/coldfusion_detect_browser.php

C'était assez bon pour ce que j'ai besoin de savoir.

OriginalL'auteur Klog
2

J'ai créé BrowscapCFC alimenté par http://browscap.org/. Il peut s'adapter à vos besoins

OriginalL'auteur Henry
1

Il n'y a rien construit dans ColdFusion qui vous permettra de le faire. La capture de la user_agent chaîne et l'analyser manuellement est sur le meilleur que vous pouvez faire.

Il sont applications tierces comme Browserhawk (http://www.cyscape.com/Default.aspx) qui va le faire... et que je n'ai pas utilisé Browserhawk moi-même, je comprends qu'il ne veut bien le travail.

Googler aussi tours jusqu' http://www.andrewdixon.co.uk/aebrowser/, mais qui est âgé de 6 ans. Peut toujours fonctionner... mais selon combien de balles vous avez besoin de la solution, vous pourriez envisager quelque chose comme Browserhawk. Vous pourriez google pour une liste de chaînes d'agent utilisateur et de gérer vous-même... mais étant donné le grand nombre de navigateurs (et les versions) à travers les OS, je pense que ce serait un travail à temps plein en lui-même.

OriginalL'auteur charliegriefer
0

La fonction définie par l'utilisateur ci-dessus a très bien fonctionné, mais j'ai dû ajouter le code suivant pour obtenir le numéro de version pour fonctionner correctement avec internet explorer (MSIE):
```
//Handle MSIE Version issue
IF (Left(Browser,4) EQ "MSIE") {
        tmpBrowser = Browser;
    IF (listLen("#tmpBrowser#", " ") EQ 2) {
        Browser = listGetAt("#tmpBrowser#", 1, " ");
        BrowserVer = listGetAt("#tmpBrowser#", 2, " ");
    }
}
```
Avec un user_agent comme ceci:

Mozilla/4.0 (compatible; MSIE 8.0; Windows NT 6.1; Trident/4.0; SLCC2; .NET CLR 2.0.50727; .NET CLR 3.5.30729; .NET CLR 3.0.30729; PC Media Center 6.0; .NET4.0C)

Il était en train de revenir à une version vierge et d'un navigateur du nom de "MSIE 8.0"

IE11 rend les choses encore plus intéressantes. Apparemment, il n'a plus de rapports MSIE.

OriginalL'auteur Steve Grundy

Ici est une version récente du navigateur, le nom et la version
Testé sur Opra /IE 8 ET IE 9 /10 IE /IE 11 /Edge /Chrome /Firefox

<cffunction name="GetBrowser" access="public">
<cfset var l = {}>
<cfset l.UserInfo = cgi.HTTP_USER_AGENT>
<cfset l.Browser = {}>
<cfif FindNoCase ( "Opera", l.UserInfo ) >
<cfset l.Browser.type = "Opera">
<cfset l.Browser.Name = "Opera">
<cfelseif FindNoCase ( "OPR", l.UserInfo )>
<cfset l.Browser.type = "OPR">
<cfset l.Browser.Name = "Opera">
<cfelseif FindNoCase ( "Edge", l.UserInfo )>
<cfset l.Browser.type = "Edge">
<cfset l.Browser.Name = "Edge">
<cfelseif FindNoCase ( "Chrome", l.UserInfo )>
<cfset l.Browser.type = "Chrome">
<cfset l.Browser.Name = "Chrome">
<cfelseif FindNoCase ( "Safari", l.UserInfo )>
<cfset l.Browser.type = "Safari">
<cfset l.Browser.Name = "Safari">
<cfelseif FindNoCase ( "FireFox", l.UserInfo )>
<cfset l.Browser.type = "FireFox">
<cfset l.Browser.Name = "FireFox">
<cfelseif FindNoCase ( "MSIE", l.UserInfo ) >
<cfset l.Browser.type = "MSIE">
<cfset l.Browser.Name = "Internet Explorer">
<cfelseif FindNoCase ( "Trident", l.UserInfo ) >
<cfset l.Browser.type = "Trident">
<cfset l.Browser.Name = "Internet Explorer">
<cfelse>
<cfset l.Browser.type = "Unknown">
<cfset l.Browser.Name = "Unknown">
<cfset l.Browser.Version = "Unknown">
</cfif>
<cfif FindNoCase ( "rv:" , l.UserInfo ) NEQ 0>
<cfset l.Params = REFindNoCase ( "rv:[0-9.]+", l.UserInfo, Find ( "rv:", l.UserInfo ), true )>
<cfset l.FirstOccurrence = l.Params.POS[1]>
<cfset l.ParamLength = l.Params.LEN[1]>
<cfset l.BrowserNameLength = Len ( "rv:" )>
<cfset l.Browser.Version = Mid ( l.UserInfo, ( l.FirstOccurrence + l.BrowserNameLength ), ( l.ParamLength - l.BrowserNameLength ) )>
<cfelse>
<cfset l.Params = REFindNoCase ( #l.Browser.type# & "/?[ 0-9.]+", l.UserInfo, Find ( "#l.Browser.type#", l.UserInfo ), true )>
<cfset l.FirstOccurrence = l.Params.POS[1]>
<cfset l.ParamLength = l.Params.LEN[1]>
<cfset l.BrowserNameLength = Len ( l.Browser.type ) + 1>
<cfset l.Browser.Version = Mid ( l.UserInfo, ( l.FirstOccurrence + l.BrowserNameLength ), ( l.ParamLength - l.BrowserNameLength ) )>
</cfif>
<cfreturn l.Browser>
</cffunction>
<cfdump var="#GetBrowser()#">

OriginalL'auteur SeriesBlue

Vous devez vous connecter pour publier un commentaire.