Lot de fichiers pour supprimer les 3 premières lignes d'un fichier texte

Comme le titre j'ai besoin d'un fichier de commandes pour supprimer les 3 PREMIÈRES lignes d'un fichier texte.

par exemple:

A    
B    
C    
D    
E   
F    
G

dans cet exemple, j'ai besoin de A,B et C supprimée avec la ligne

[Voir ce lien][1]. Espérons que cela fonctionnera pour vous. [1]: stackoverflow.com/questions/418916/...
Arun Jain qui ne fonctionne que si vous savez ce qui est dans la ligne je n'ai pas

OriginalL'auteur kriegy | 2012-07-11

  1. 11

    Cela devrait le faire

    for /f "skip=3 delims=*" %%a in (C:\file.txt) do (
echo %%a >>C:\newfile.txt    
)
xcopy C:\newfile.txt C:\file.txt /y
del C:\newfile.txt /f /q

    Qui sera re-créer le fichier avec les 3 premières lignes supprimées.

    À l'utilisateur de se tenir à jour vous pourriez intégrer les messages dans le fichier de commandes dans le style vbscript ou de messages de sortie dans l'invite de commande.

    @echo off
echo Removing...
for /f "skip=3 delims=*" %%a in (C:\file.txt) do (
echo %%a >>C:\newfile.txt
) >nul
echo Lines removed, rebuilding file...
xcopy C:\newfile.txt C:\file.txt /y >nul
echo File rebuilt, removing temporary files
del C:\newfile.txt /f /q >nul
msg * Done!
exit >nul

    Espère que cette aide.

    il me semble avoir exécuté une erreur ">> a été unexcpected en ce moment"
    Désolé, il y avait une faute de frappe, j'avais mis un " signe dans le nom de fichier dans la for boucle, essayez-le maintenant.
    ok qui a retourné le premier mot sur les 3 DERNIÈRES lignes
    Désolé, je ne pouvais pas tester le code quand je l'ai posté. J'ai édité de nouveau et testé ce moment et il fonctionne. J'ai oublié le delims donc, il était en rupture quand il a frappé un espace. Essayez-le maintenant.
    il nous a fallu un certain temps, mais nous y suis arrivé merci, je vais mettre en place une autre question, il comporte des instructions if ...yay

    OriginalL'auteur

  2. 15
    more +3 "file.txt" >"file.txt.new"
move /y "file.txt.new" "file.txt" >nul

    Ci-dessus est rapide et fonctionne très bien, avec les limitations suivantes:

    • ONGLET caractères sont convertis en une série d'espaces.
    • Le nombre de lignes pour être conservé, doit être inférieure à ~65535. PLUS se bloque, (attendre qu'une touche), si le numéro de ligne est dépassée.
    • Toutes les lignes sera terminée par un retour chariot et saut de ligne, quelle que soit la façon dont ils ont été formatés dans la source.

    La solution suivante à l'aide DE /F avec FINDSTR est plus robuste, mais il est beaucoup plus lent. Contrairement à un simple FOR /F solution, il conserve des lignes vides. Mais comme POUR tous /F solutions, il est limité à un maximum de longueur de ligne de un peu moins de 8 191 octets. Encore une fois, toutes les lignes sera terminée par un retour chariot et saut de ligne.

    @echo off
setlocal disableDelayedExpsnsion
>"file.txt.new" (
  for /f "delims=" %%A in ('findstr /n "^" "file.txt"') do (
    set "ln=%%A"
    setlocal enableDelayedExpansion
    echo(!ln:*::=!
    endlocal
  )
)
move /y "file.txt.new" "file.txt" >nul

    Si vous avez mon handy dandy JREPL.Chauve-souris regex utilitaire de traitement de texte, alors vous pouvez utiliser les éléments suivants pour un très robuste et rapide de la solution. Cela va encore mettre fin à toutes les lignes avec un retour chariot et saut de ligne (\r\n), quel que soit le format d'origine.

    jrepl "^" "" /k 0 /exc 1:3 /f "test.txt" /o -

    Vous pouvez écrire \n terminateurs de ligne au lieu de \r\n ajout de la /U option.

    Si vous devez conserver l'original en ligne de terminateurs, alors vous pouvez utiliser la variation suivante. Il charge le fichier source en entier en une seule JScript variable, de sorte que la taille totale des fichiers est limitée à environ 1 ou 2 gigaoctets (j'ai oublié le nombre exact).

    jrepl "(?:.*\n){1,3}([\s\S]*)" "$1" /m /f "test.txt" /o -

    Rappelez-vous que JREPL est un fichier de commandes, vous devez utiliser l'APPEL JREPL si vous utilisez la commande dans un autre script de commandes.

    est-ce la peine d'avoir vbscript msgbox GUI?
    ne vous inquiétez pas je l'ai résolu
    EDIT - Ajout d'un plus robuste mais lent POUR /F solution, aussi bien que rapide et robuste JREPL.BATTE de solutions.

    OriginalL'auteur

  3. 3

    Utiliser sed pour imprimer uniquement commençant par la ligne 4 (Edit: Seulement si vous utilisez un*x 🙂

    $ sed -e '4,$p' in.txt
    je préfère garder toutes les indigènes comme je pourrais distribuer un couple de copies merci bien
    Cette question est étiqueté comme lot. Vous aurez à obtenir Sed pour windows pour le faire fonctionner.
    Si je lis les réponses qui utilisent un seul lot, je vous recommande de le faire 🙂

    OriginalL'auteur

  4. 1

    Je utiliser la commande "plus pour outting fichier après la nième ligne
    De commande (windows)

    More +n orginalfilename.txt > outputfilename.txt

    Description:
    La sortie d'un fichier txt après la nième ligne

    OriginalL'auteur

  5. 0

    Si vous souhaitez passer la première et de la queue, les dernières lignes, vous pouvez utiliser mon code
    http://www.harchut.de/download/ms-dos/skip-tail-flatfile-example.zip

    set L_TRIMFILE_CNT=0
set L_TRIMFILE_TMPFILE=work.countrows.find.tmp
find /c /v "" %P_TRIMFILE_INFILE% > %L_TRIMFILE_TMPFILE%
for /f "skip=1 tokens=3* " %%a in (%L_TRIMFILE_TMPFILE%) do (
  if %L_TRIMFILE_CNT% == 0 set L_TRIMFILE_CNT=%%a
)
del %L_TRIMFILE_TMPFILE%
set /a L_TRIMFILE_EOF=%L_TRIMFILE_CNT%-%P_TRIMFILE_TAIL%
findstr /n .* "%P_TRIMFILE_INFILE%" > %L_TRIMFILE_TMPFILE%
if exist %P_TRIMFILE_OUTFILE% del %P_TRIMFILE_OUTFILE%
set V_TRIMFILE_SKIP="skip=%P_TRIMFILE_SKIP% tokens=1* delims=:"
if %P_TRIMFILE_SKIP% equ 0 set V_TRIMFILE_SKIP="tokens=1* delims=:"
for /f %V_TRIMFILE_SKIP% %%a in (%L_TRIMFILE_TMPFILE%) do (
  if %%a leq %L_TRIMFILE_EOF% if exist %P_TRIMFILE_OUTFILE% @echo.%%b>>%P_TRIMFILE_OUTFILE%
  if %%a leq %L_TRIMFILE_EOF% if not exist %P_TRIMFILE_OUTFILE% @echo.%%b>%P_TRIMFILE_OUTFILE%
)
del %L_TRIMFILE_TMPFILE%

    Vous pouvez sauter ou de la queue de ligne d'un fichier plat, sans aucune utilité.

    Vous voudrez peut-être ajouter un peu d'explication sur cette réponse. Toujours mieux de donner à une personne une canne à pêche que de lui donner un poisson.

    OriginalL'auteur