Lot-Script - Itérer à travers les arguments

J'ai un lot de script avec plusieurs arguments. Je lis le nombre total d'entre eux et l'exécution d'une boucle for comme ceci:

@echo off
setlocal enabledelayedexpansion

set argCount=0
for %%x in (%*) do set /A argCount+=1
echo Number of processed arguments: %argCount%

set /a counter=0
for /l %%x in (1, 1, %argCount%) do (
set /a counter=!counter!+1 )

Ce que je veux faire maintenant, c'est d'utiliser ma course variable (x ou counter) pour accéder à des arguments d'entrée. Je pense aobut quelque chose comme ceci:

REM Access to %1 
echo %(!counter!)

Dans un monde idéal, cette ligne doit imprimer mon premier argument de ligne de commande, mais évidemment, il ne le fait pas. Je sais que je fais quelque chose de mal avec l' % de l'opérateur, mais est-il de toute façon j'ai pu accéder à mes arguments comme cela?

//edit: Juste pour clarifier les choses, le problème est que %(!counter!) me donne la valeur de la variable counter. Sens pour counter=2 il me donne 2 et non pas le contenu de %2.

  • si les arguments sont plus que 9 vous ne pouvez pas accéder à toutes, sans shift
  • C'est une autre question que je pourrais rencontrer, mais nous allons simplement supposer que je vais avoir moins de 10 arguments
  • Aussi, for %%x in (%*) do ... ne donnera pas le résultat souhaité si un paramètre contient * ou ? caractère. J'ai toujours utiliser un GOTO boucle avec la touche SHIFT si je veux charger les paramètres dans un tableau de variables.
InformationsquelleAutor Toby | 2013-11-07
  1. 12

    voici un moyen pour accéder à la seconde (par exemple) argument (ce qui peut être mis en /l de la boucle):

    @echo off
setlocal enableDelayedExpansion
set /a counter=2
call echo %%!counter!
endlocal

    donc:

    setlocal enableDelayedExpansion
set /a counter=0
for /l %%x in (1, 1, %argCount%) do (
 set /a counter=!counter!+1
 call echo %%!counter! 
)
endlocal
    • Le problème est que %!counter! me donne la valeur de la variable counter et non le contenu de %2
    • Agghh... sory vous avez besoin de double %.Fixd.
    • êtes-vous sûr?voici mon appel du premier extrait:argtester.bat a b et la sortie est b
    • J'ai fait une erreur stupide (j'ai un peu confus avec mes noms de fichiers, il ne faut pas en parler 🙂 ^^ ) - fonctionne maintenant sur le point de test intégrée dans l'ensemble de mon script
    • Ok j'ai besoin de demander, même si elle peut évident et je suis juste un blackout: Est-il possible comment je peux obtenir cette valeur dans une variable, maintenant? Maintenant que j'ai lu l'Entrée paramaeters je veux les comparer avec des chaînes. Et je ne suis pas tout à fait sûr de savoir comment je peux accéder à cette chaîne maintenant...?
    • avec appel set "_var=%%!counter!".vous avez besoin d'une variable temp parce que si elle ne peut être appelée
    • et puis vous pouvez comparer avec si -> if "!_var!" equ "something" echo this is something
    • Êtes-vous sûr que je dois mettre le " autour de l'ensemble set appel?
    • il est a safe stratégie. ceci vous permet d'inclure des caractères spéciaux dans la valeur comme |&><.... et de vous assurer qu'il n'y a pas d'espace supplémentaire à la fin (qui dans certains cas pourrait briser votre logique)
    • Le problème c'est que quand je l'attribuer à _var , _var aussi juste contient %1 etc (à l'aide de echo !_var!) - Lorsque j'utilise call echo !_var! - je obtenir le contenu une fois encore le problème est quand j'utilise _var dans mon if appel (comme vous le suggérez) malheureusement il ne fonctionne pas
    • call set ...l'appel qui a été accidentellement laissé à l'extérieur du gris bckg.
    • call set "_var=%%!counter!"
    • Fonctionne comme un charme maintenant! Merci
    • Pourquoi ne pas tout simplement for /l %%x in (1 1 %argCount%) do call echo %%%%x? Ou de jeter dans l'ENSEMBLE si vous le souhaitez. Mais je n'aime pas les OP de base de l'approche. La seule approche fiable que je connaisse est d'utiliser un GOTO boucle et de passer à définir un "tableau" de valeurs de paramètre.
    • Cette méthode ne fonctionne pas pour les arguments au-delà de la numéro 9

    InformationsquelleAutor npocmaka
  2. 47
    @echo off
setlocal enabledelayedexpansion

set argCount=0
for %%x in (%*) do (
   set /A argCount+=1
   set "argVec[!argCount!]=%%~x"
)

echo Number of processed arguments: %argCount%

for /L %%i in (1,1,%argCount%) do echo %%i- "!argVec[%%i]!"

    Par exemple:

    C:> test One "This is | the & second one" Third
Number of processed arguments: 3
1- "One"
2- "This is | the & second one"
3- "Third"

    Un autre:

    C:> test One Two Three Four Five Six Seven Eight Nine Ten Eleven Twelve etc...
Number of processed arguments: 13
1- "One"
2- "Two"
3- "Three"
4- "Four"
5- "Five"
6- "Six"
7- "Seven"
8- "Eight"
9- "Nine"
10- "Ten"
11- "Eleven"
12- "Twelve"
13- "etc..."
    • Ce est un travail comme c'est, pour moi, contrairement à la solution actuelle de @npocmaka (windows 10 familly)
    InformationsquelleAutor Aacini
  3. 17
    :loop
@echo %1
shift
if not "%~1"=="" goto loop
    • Où sont les meilleures réponses? Je l'aime parce qu'il est super succincte, minimes, et simple.
    • Ce que je pense @jeb essaie de dire, c'est que vous devez fournir une explication pour votre réponse. Je pense que c'est génial, mais avec des détails sur les fonctions de chaque commande, et peut-être un exemple d'utilisation, vous obtiendrez plus de upvotes 🙂
    InformationsquelleAutor Jay Taylor
  4. 6

    Si pour avoir un code court plutôt que sage, alors

    for %%x in (%*) do (
   echo Hey %%~x 
)
    • Cette approche est dépourvu de sagesse? Et si oui, pourquoi?
    InformationsquelleAutor h22
  5. 2
    @ECHO OFF
SETLOCAL
SET nparms=0
FOR /l %%i IN (1,1,20) DO (
 SET myparm=%%i
 CALL :setparm %*
 IF DEFINED myparm SET nparms=%%i&CALL ECHO Parameter %%i=%%myparm%%
)
ECHO there were %nparms% parameters in %*
GOTO :EOF

:setparm
IF %myparm%==1 SET myparm=%1&GOTO :EOF
shift&SET /a myparm -=1&GOTO setparm
GOTO :eof

    Cela devrait montrer comment extraire des paramètres aléatoires par position.

    • oui . il est possible également avec d'autres sous-routine.+1
    InformationsquelleAutor Magoo
  6. 1

    Pour la simple itération ne peut-on pas vérifier les autres arguments avec "shift /1" à la fin du code et de la boucle de retour? Cela permettra de traiter plus de 10 arguments, limite supérieure non testé.

    :loop

:: Your code using %1
echo %1

:: Check for further batch arguments.     
shift /1
IF [%1]==[] (
goto end
) ELSE (
goto loop
)

:end
pause
    InformationsquelleAutor Gavin