L'utilisation de CMake pour obtenir au moment de la construction de révision Subversion

C'est plus d'une douleur à faire que cela doit l'être. Vous pouvez exécuter un programme au moment de la construction pour extraire les informations de version subversion. CMake lui-même peut être utilisé comme programme à l'aide de son langage de script. Vous pouvez lancer CMake script à l'aide de la ligne de commande-P drapeau. Le morceau de code pour faire ce serait (Pour être placé dans le fichier getsvn.cmake):

# the FindSubversion.cmake module is part of the standard distribution
include(FindSubversion)
# extract working copy information for SOURCE_DIR into MY_XXX variables
Subversion_WC_INFO(${SOURCE_DIR} MY)
# write a file with the SVNVERSION define
file(WRITE svnversion.h.txt "#define SVNVERSION ${MY_WC_REVISION}\n")
# copy the file to the final header only if the version changes
# reduces needless rebuilds
execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different
                        svnversion.h.txt svnversion.h)

Cet extrait de la révision subversion de l'information et de l'écrit dans un fichier d'en-tête. Ce fichier d'en-tête est mise à jour uniquement lorsque cela est nécessaire pour éviter de recompiler tout le temps. Dans votre programme, vous devez inclure que le fichier d'en-tête pour obtenir à la SVNVERSION définir.

La CMakeLists.txt fichier que vous devez exécuter le script serait quelque chose comme ceci:

# boilerplate
cmake_minimum_required(VERSION 2.8)
project(testsvn)

# the test executable
add_executable(test main.c ${CMAKE_CURRENT_BINARY_DIR}/svnversion.h)

# include the output directory, where the svnversion.h file is generated
include_directories(${CMAKE_CURRENT_BINARY_DIR})

# a custom target that is always built
add_custom_target(svnheader ALL
    DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/svnheader.h)

# creates svnheader.h using cmake script
add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/svnheader.h
    COMMAND ${CMAKE_COMMAND} -DSOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}
                         -P ${CMAKE_CURRENT_SOURCE_DIR}/getsvn.cmake)

# svnversion.h is a generated file
set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/svnversion.h
    PROPERTIES GENERATED TRUE
    HEADER_FILE_ONLY TRUE)

# explicitly say that the executable depends on the svnheader
add_dependencies(test svnheader)

Vous devez utiliser add_custom_target et add_custom_command car il n'y a pas d'apports à l'svnheader.h de fichier, il "apparaît de nulle part" de cmake. J'ai déjà abordé la question de l'inutile reconstruit dans le getsvn.cmake fichier même si, pour la reconstruction de la "svnheader" cible est un no-op si la révision subversion n'a pas changé.

Enfin, un exemple main.c fichier:

#include "svnversion.h"

int main(int argc, const char *argv[])
{
    printf("%d\n", SVNVERSION);
    return 0;
}

OriginalL'auteur richq

J'ai trouvé que la réponse donnée par richq n'est pas exactement ce à quoi on pourrait s'attendre - à savoir qu'il ne met pas automatiquement à jour le fichier svnversion.h (dont la révision svn info est stockée) lorsque seul bâtiment (mais pas à la configuration) de la source, c'est à dire lorsque l'appelant simplement make.

Ici est une version légèrement modifiée de la procédure qu'il convient donc de comportement. Crédit pour la solution d'origine va à richq de cours.

Son getsvn.cmake script reste inchangée, elle est ici par souci d'exhaustivité (voir sa réponse aux observations et explication)

INCLUDE(FindSubversion)
Subversion_WC_INFO(${SOURCE_DIR} MY)
FILE(WRITE svnversion.h.txt "#define SVNVERSION ${MY_WC_REVISION}\n")
EXECUTE_PROCESS(COMMAND ${CMAKE_COMMAND} -E copy_if_different
      svnversion.h.txt svnversion.h)

Maintenant, le truc est d'utiliser ADD_CUSTOM_COMMAND avec une signature différente (voir La Documentation De CMake), à savoir la spécification de la cible avec laquelle la commande doit être associé. Ensuite, il est exécuté à chaque fois que la cible est intégré avec une cible vide de ADD_CUSTOM_TARGET qui est toujours considéré comme out-of-date, ce qui donne le comportement souhaité. Voici ce que le CMakeLists.txt pourrait ressembler (en se basant à nouveau sur le script par richq):

CMAKE_MINIMUM_REQUIRED(VERSION 2.8)
PROJECT(testsvn)

# the test executable
ADD_EXECUTABLE(test main.c)

# include the output directory, where the svnversion.h file is generated
INCLUDE_DIRECTORIES(${CMAKE_CURRENT_BINARY_DIR})

# a custom target that is always built
ADD_CUSTOM_TARGET(revisiontag ALL)

# creates svnversion.h using cmake script
ADD_CUSTOM_COMMAND(TARGET revisiontag COMMAND ${CMAKE_COMMAND}
   -DSOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR} 
   -P ${CMAKE_CURRENT_SOURCE_DIR}/getsvn.cmake)

# explicitly say that the executable depends on custom target
add_dependencies(test revisiontag)

Maintenant, le script getsvn.cmake est exécuté à chaque fois que la cible revisiontag est construit, ce qui signifie que chaque fois make est émis. Test en commentant la ligne avec FILE(..) dans getsvn.cmake et de modifier manuellement svnversion.h.txt.

OriginalL'auteur janitor048

Dans l'idéal, ce serait un commentaire sur richq réponse, mais je n'ai pas assez de réputation encore. Si un admin pourrait le convertir en un seul, ce serait génial.

Seul problème que j'ai trouvé (en dehors de la dépendance de celui qui a été résolu par la Marque), c'est que la version SVN de soutien dans CMake n'inclut que la "révision de base", pas de modificateurs (en particulier si c'est un "M" (modifié) construire).

Ainsi, au lieu de l'a suggéré getsvn.cmake, j'ai utilisé ceci:

# Set current SVN version into a variable
execute_process(COMMAND svnversion ${SOURCE_ROOT} OUTPUT_VARIABLE MY_WC_REVISION OUTPUT_STRIP_TRAILING_WHITESPACE)
# write a file with the SVNVERSION define
file(WRITE svnversion.h.txt "#define SVN_REV \"${MY_WC_REVISION}\"\n")
# copy the file to the final header only if the version changes
# reduces needless rebuilds
execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different
                    svnversion.h.txt svnversion.h)

Et parce que je ne veux pas la révision du répertoire courant, je suis de passage SOURCE_ROOT (le répertoire pour le haut de la SVN de l'arbre) à la commande personnalisée, au lieu de SOURCE_DIR, et je travaille la valeur correcte pour que ailleurs dans mon CMakeLists.txt arbre

OriginalL'auteur Michael Firth