Macro Excel pour concaténer

Besoin d'aide pour créer une Macro Excel.J'ai une feuille Excel.La feuille Excel n'est pas cohérente.
J'ai l'intention de rendre uniforme et structurée.

Par exemple.

  A            B            C         D
1 test      tester         tester
2 hai       test
3 Bye       test           tested
4 GN        test           tested    Fine

  A            B            C         D
1 test      testertester   
2 hai       test
3 Bye       testtested     
4 GN        testtestedFine

Fondamentalement, je dois trouver la dernière cellule où l'élément est placé en se basant sur que je peux écrire mon CONCATÉNER une fonction.

Dans ce cas, il serait de la Colonne D et donc ma fonction concatener aurait été
=CONCATENATE(B1,C1,D1)
Encore une fois je voudrais que le résultat soit en B1, mais pas un problème si j'ai à cacher.

Quelqu'un peut m'aider à faire cela?

OriginalL'auteur Harish | 2010-03-23

  1. 4

    Vous pouvez utiliser la fonction VBA suivante qui rejoint (concatène les valeurs de l'arbitraire d'un plage de cellules, avec une option de délimiteur.

    Public Function Join(source As Range, Optional delimiter As String)
    Dim text As String
    Dim cell As Range: For Each cell In source.Cells
        If cell.Value = "" Then GoTo nextCell

        text = text & cell.Value & delimiter

nextCell:
    Next cell

    If text <> "" And delimiter <> "" Then
        text = Mid(text, 1, Len(text) - Len(delimiter))
    End If

    Join = text
End Function

    Pour un exemple d'utilisation de la fonction, entrez =JOIN(A1:D1) dans n'importe quelle cellule de la feuille de calcul.

    OriginalL'auteur Adam Ralph

  2. 2

    =B1&C1&D1

    ou

    Adam fonction que j'ai optimisé.

    Function Join(source As Range, Optional delimiter As String) As String
'
' Join Macro
' Joins (concatenates) the values from an arbitrary range of cells, with an optional delimiter.
'

'optimized for strings
'   check len is faster than checking for ""
'   string Mid$ is faster than variant Mid
'   nested ifs allows for short-circuit
'   + is faster than &

    Dim sResult As String
    Dim oCell As Range

    For Each oCell In source.Cells
        If Len(oCell.Value) > 0 Then
            sResult = sResult + CStr(oCell.Value) + delimiter
        End If
     Next

    If Len(sResult) > 0 Then
        If Len(delimiter) > 0 Then
            sResult = Mid$(sResult, 1, Len(sResult) - Len(delimiter))
        End If
    End If

    Join = sResult
End Function
    Comment appeler la fonction à partir de Ma feuille excel?
    Tout comme AdamRalph mentionné.

    OriginalL'auteur AMissico