Match espaces, mais pas les retours à la ligne

Utiliser un double négatif:

/[^\S\r\n]/

Qui est, non-non-blanc (la capitale S complète) ou pas-le transport-retour ou non-retour à la ligne. La distribution de l'extérieur pas (c'est à dire, le complément de ^ dans la classe de caractères) avec De Morgan, la loi de, c'est l'équivalent des “espaces blancs, mais pas de retour chariot ou saut de ligne.” Y compris les deux \r et \n dans le modèle gère correctement tous les Unix (LF), le classique de Mac OS (CR), et DOS-ish (CR LF) newline conventions.

Pas besoin de prendre mon mot pour cela:

#! /usr/bin/env perl

use strict;
use warnings;

use 5.005;  # for qr//

my $ws_not_crlf = qr/[^\S\r\n]/;

for (' ', '\f', '\t', '\r', '\n') {
  my $qq = qq["$_"];
  printf "%-4s => %s\n", $qq,
    (eval $qq) =~ $ws_not_crlf ? "match" : "no match";
}

De sortie:

" " => match 
"\f" => match 
"\t" => match 
"\r" => pas de match 
"\n" => pas de match

Noter l'exclusion de tabulation verticale, mais c'est adressées en v5.18.

Avant de s'opposer trop sévèrement, la documentation Perl utilise la même technique. Une note de bas de page dans le “Espaces” de la section de perlrecharclass lit

Avant Perl v5.18, \s ne correspond pas à la verticale de l'onglet. [^\S\cK] (vaguement) correspond à ce que \s traditionnellement fait.

La même la section de perlrecharclass propose également d'autres approches qui ne sera pas offenser les enseignants de langues de l'opposition à double-négatifs.

À l'extérieur des paramètres régionaux et Unicode règles ou lorsque le /a interrupteur est en effet, “\s correspond [\t\n\f\r ] et, à partir de Perl v5.18, l'onglet vertical, \cK.” Jetez \r et \n de quitter /[\t\f\cK ]/ pour la mise en correspondance des espaces, mais pas de saut de ligne.

Si votre texte est en Unicode, utilisez un code similaire à la sous ci-dessous pour construire un modèle à partir du tableau de susmentionnés section documentation.

sub ws_not_nl {
  local($_) = <<'EOTable';
0x0009        CHARACTER TABULATION   h s
0x000a              LINE FEED (LF)    vs
0x000b             LINE TABULATION    vs  [1]
0x000c              FORM FEED (FF)    vs
0x000d        CARRIAGE RETURN (CR)    vs
0x0020                       SPACE   h s
0x0085             NEXT LINE (NEL)    vs  [2]
0x00a0              NO-BREAK SPACE   h s  [2]
0x1680            OGHAM SPACE MARK   h s
0x2000                     EN QUAD   h s
0x2001                     EM QUAD   h s
0x2002                    EN SPACE   h s
0x2003                    EM SPACE   h s
0x2004          THREE-PER-EM SPACE   h s
0x2005           FOUR-PER-EM SPACE   h s
0x2006            SIX-PER-EM SPACE   h s
0x2007                FIGURE SPACE   h s
0x2008           PUNCTUATION SPACE   h s
0x2009                  THIN SPACE   h s
0x200a                  HAIR SPACE   h s
0x2028              LINE SEPARATOR    vs
0x2029         PARAGRAPH SEPARATOR    vs
0x202f       NARROW NO-BREAK SPACE   h s
0x205f   MEDIUM MATHEMATICAL SPACE   h s
0x3000           IDEOGRAPHIC SPACE   h s
EOTable

  my $class;
  while (/^0x([0-9a-f]{4})\s+([A-Z\s]+)/mg) {
    my($hex,$name) = ($1,$2);
    next if $name =~ /\b(?:CR|NL|NEL|SEPARATOR)\b/;
    $class .= "\\N{U+$hex}";
  }

  qr/[$class]/u;
}

---

D'Autres Applications

Le double négatif astuce est également très pratique pour la mise en correspondance des caractères alphabétiques. Rappelez-vous que \w correspond à “la parole des personnages, des” caractères alphabétiques et chiffres et des caractères de soulignement. Nous laid-Américains parfois envie de l'écrire comme, disons,

if (/[A-Za-z]+/) { ... }

mais un double caractère négatif de la classe peut respecter les paramètres régionaux:

if (/[^\W\d_]+/) { ... }

Exprimant “un caractère de mot, mais pas de chiffre ou un caractère de soulignement” de cette façon est un peu opaque. Un de caractères POSIX-classe communique l'intention plus directement

if (/[[:alpha:]]+/) { ... }

ou avec une propriété Unicode comme szbalint suggéré

if (/\p{Letter}+/) { ... }

OriginalL'auteur Greg Bacon

Ce que vous cherchez est la POSIX blank classe de personnage. En Perl, il est mentionné que:

[[:blank:]]

en Java (n'oubliez pas d'activer UNICODE_CHARACTER_CLASS):

\p{Blank}

Comparativement à la même \h, POSIX blank est pris en charge par un peu plus de regex moteurs (référence). Un avantage majeur est que sa définition est fixée dans Annexe C: Propriétés de Compatibilité de l'Unicode des Expressions Régulières et standards pour l'ensemble des regex saveurs qui s'en charge Unicode. (En Perl, par exemple, \h choisit de préciser, en outre, la MONGOLIAN VOWEL SEPARATOR.) Cependant, un argument en faveur de \h est qu'il détecte des caractères Unicode (même si les moteurs ne sont pas d'accord sur qui), tandis que les classes de caractères POSIX sont souvent par défaut ASCII (comme en Java).

Mais le problème est que même en collant Unicode ne résout pas le problème à 100%. Considérer les caractères suivants qui ne sont pas considérés comme des espaces en Unicode:

• U+180E MONGOL VOYELLE SÉPARATEUR
• U+200B ZERO WIDTH SPACE
• U+200C LARGEUR NULLE DE NON-MENUISIER
• U+200D ZÉRO LARGEUR MENUISIER
• U+2060 MOT MENUISIER

• U+FEFF ZÉRO DE LA LARGEUR DE L'ESPACE INSÉCABLE

  _{Prises de https://en.wikipedia.org/wiki/White-space_character}

Ladite mongol voyelle séparateur n'est pas inclus pour ce qui est probablement une bonne raison. Il, avec 200C et 200D, se produisent à l'intérieur des mots (autant que je sache), et donc casse la règle que tous les autres espaces obéit: vous pouvez marquer avec elle. Ils ressemblent plus à des modificateurs. Cependant, ZERO WIDTH SPACE, WORD JOINER, et ZERO WIDTH NON-BREAKING SPACE (si elle a utilisé autrement que comme une marque d'ordre d'octet) ajustement de l'espace de la règle dans mon livre. Donc, je inclure dans mon blanc horizontal classe de personnage.

En Java:

static public final String HORIZONTAL_WHITESPACE = "[\\p{Blank}\\u200B\\u2060\\uFFEF]"

OriginalL'auteur Aleksandr Dubinsky

m//g juste donner de l'espace dans //, et il va fonctionner. Ou utiliser \S — il remplace tous les caractères spéciaux comme tab, les sauts de lignes, des espaces, et ainsi de suite.

OriginalL'auteur saiprathapreddy.obula