Méthode générique permettant de vérifier si une clé est dans une Collection en VBA Excel

J'ai différentes Collections dans mon code. Certaines tenir des Objets (de divers types), d'autres ont des types (type Long).

Est-il un moyen de vérifier si une clé est contenue dans la Collection qui fonctionne pour les types comme des objets?

Pour l'instant j'ai deux fonctions.

Première fonction:

Private Function ContainsObject(objCollection As Object, strName As String) As Boolean
    Dim o As Object
    On Error Resume Next
    Set o = objCollection(strName)
    ContainsObject = (Err.Number = 0)
    Err.Clear
End Function

Deuxième fonction:

Private Function ContainsLong(AllItems As Collection, TheKey As String) As Boolean
    Dim TheValue As Long
    On Error Resume Next
    TheValue = AllItems.Item(TheKey)
    ContainsLong = (Err.Number = 0)
    Err.Clear
End Function

La raison pour laquelle les deux fonctions est que ContainsObject ne semble pas fonctionner si je passe une Collection qui a de Longs paires (la fonction renvoie toujours False.)

P. S.: La première fonction est une copie de la troisième réponse à partir de Tester ou vérifier si la feuille existe

Il semble y avoir une faute de frappe d'erreur. Je pense que Contains = (Err.Number = 0) devrait être ContainsObject = (Err.Number = 0) de Même CheckForKeyInCollection = (Err.Number = 0) devrait être ContainsLong = (Err.Number = 0)
Merci pour la correction! J'ai accepté la réponse qui explique rapidement et résout mon problème. Merci pour la réponse, aussi, la solution est là, aussi, mais un peu plus subtil...

OriginalL'auteur user2606240 | 2016-06-24

12

Vous devez utiliser un Variant dans la première fonction. Vous pouvez affecter un Object à un Variant, par exemple, ce ne sera pas d'erreur:
```
Sub Test()
    Dim var As Variant
    Dim obj As Object
    Set obj = Application
    var = Application
    Debug.Print var
End Sub
```
Mais cela vous donnera une Type Mismatch erreur de compilation c'est à dire en essayant d'attribuer un Long à un Object:
```
Sub Test()
    Dim obj As Object
    Dim lng As Long
    lng = 3
    Set obj = lng
End Sub
```
Ainsi, pour une fonction générique (le long de vos lignes de code) pour vérifier si un Collection clé est valide, vous pouvez utiliser:
```
Function HasKey(coll As Collection, strKey As String) As Boolean
    Dim var As Variant
    On Error Resume Next
    var = coll(strKey)
    HasKey = (Err.Number = 0)
    Err.Clear
End Function
```
Code de Test:
```
Sub Test()
    Dim coll1 As New Collection
    coll1.Add Item:=Sheet1.Range("A1"), Key:="1"
    coll1.Add Item:=Sheet1.Range("A2"), Key:="2"
    Debug.Print HasKey(coll1, "1")

    Dim coll2 As New Collection
    coll2.Add Item:=1, Key:="1"
    coll2.Add Item:=2, Key:="2"
    Debug.Print HasKey(coll2, "1")
End Sub
```
Il y a un article utile sur MSDN à ce sujet. Le contexte est VB6, mais se rapporte à VBA.

En reconnaissance de votre fait et de la réponse que j'ai d'avoir voté.
Remercie de votre réponse conseille d'utiliser Dictionary objet qui j'en conviens est l'approche privilégiée. L'OP est à l'aide de Collection objet et peuvent ne pas avoir la possibilité de passer à Dictionary. Pas toujours possible de "changer de chevaux de milieu de jet" comme ils le disent 🙂

OriginalL'auteur Robin Mackenzie
4

Quelques fautes de frappe que par des commentaires ont déjà été corrigées lors de l'édition de votre message.
En réponse à votre question, je tiens à couvrir d'autres aspects connexes.

Tout en Utilisant les touches dans les collections a principalement trois avantages

- Si l'ordre change votre code d'accès de l'élément correct
- Vous pouvez directement accéder à l'élément sans lire l'intégralité de l'
collection

- Il peut vous rendre le code plus lisible.

*Mais en même temps il y a principalement trois problèmes avec l'utilisation de clés
collections
- Vous ne pouvez pas vérifier si la clé existe
- Vous ne pouvez pas modifier la clé
- Vous ne pouvez pas récupérer la clé
Comme par Pearsons article les Clés d'une Collection sont en écriture seule, il n'y a aucun moyen d'obtenir la liste des Clés d'une Collection. Poursuite à travers citation:-

Ici, Coll est un objet de Collection qui nous permettra de stocker plusieurs
CFile objets. Le CollKeys Collection est utilisée pour stocker les clés de
le CFile les objets stockés dans le Coll de la Collection. Nous avons besoin de cette deuxième
Collection parce que les Clés d'une Collection sont en écriture seule -- il est
pas moyen d'obtenir la liste des Clés d'une Collection. L'un des
améliorations apportées par la CFiles est la possibilité de récupérer une liste de
Les clés de la Collection.

Personnalisé Classes De Collection

Une façon est d'itérer sur les membres de la collecte et de voir si il y a match pour ce que vous êtes à la recherche pour, l'autre pour attraper le Item not in collection erreur, puis définir un indicateur pour dire que l'article n'existe pas. Les Opinions diffèrent sur ces approches alors que certaines personnes se sentent ce n'est pas une bonne méthode pour attraper erreur, tandis que d'autres de la section estime qu'il sera nettement plus rapide que d'itération pour tout moyen à large collection.

Donc, si nous faisons une méthode de capture d'erreur puis le numéro de l'erreur nous obtenons dépend exactement ce qui a causé l'erreur. Nous avons besoin d'un code de routine pour vérifier l'erreur. La manière la plus simple qu'il pourrait être.
```
'c1 is the collection
 For i = 1 To c1.Count
     Debug.Print Err.Number, Err.Description
     If Err.Number <> 0 Then Err.Clear
 Next i
```
Erreur attraper les routines proposées par les différents professionnels diffèrent dans le nombre d'erreur qu'ils jugent importants et de les inclure dans leur routine.Divers fréquentes numéros d'erreur associée à l'objet de collection sont:-
- Error 5 Invalid argument ou appel de procédure.Cette erreur peut également se produire
  si une tentative est faite pour appeler une procédure qui n'est pas valide sur le
  plate-forme actuelle. Par exemple, certaines procédures ne peut être valable pour
  Microsoft Windows ou pour Macintosh, et ainsi de suite.
- error 438 "cet objet ne gère pas cette propriété ou cette méthode d'Un objet
  est une instance de classe. Une instance de classe prend en charge certaines propriétés
  définis dans cette classe de la définition de type et ne prend pas en charge cette.
- Error 457 Cette clé est déjà associé à un élément de cette
  collection.Vous avez spécifié une clé pour une collection membre déjà
  identifie un autre membre de la collection. Choisissez une clé différente
  pour ce membre.
- Error 91 Variable objet ou variable bloc with non définie.Il y a deux
  étapes pour la création d'une variable objet. D'abord, vous devez déclarer le
  variable objet. Ensuite, vous devez attribuer une référence valide à l'objet
  variable à l'aide de l'instruction Set. Vous avez tenté d'utiliser un objet
  variable qui n'est pas encore le référencement d'un objet valide.
- Error 450 Mauvais nombre d'arguments ou de propriété non valide
  affectation.Le nombre d'arguments dans l'appel à la procédure
  n'était pas le même que le nombre d'arguments requis prévu par la
  procédure.Si vous avez essayé d'assigner une valeur à une propriété en lecture seule,
Parmi les erreurs ci-dessus le numéro de l'erreur 438 a été considéré comme important, et l'autre est de 5. Je suis en intégrant une Fonction de routine dans mon exemple de programme de test, qui a été publiée par la Marque Nold 7 ans en arrière, en 2008, vide DONC, la question Déterminer si un objet est un membre d'une collection en VBA avec du crédit en raison de lui.

Certains comme l'erreur 457 ne sera pas autorisée au moment de l'essai. J'ai essayé de me renseigné avec des doubles de clés de données, il a donné à l'erreur au moment de l'essai lui-même comme le montre le cliché.

Après le retrait c'est de montrer de bons résultats, comme indiqué dans la capture d'écran.

Il peut ne pas être possible d'obtenir la liste des clés d'une collection de vanille collection sans stocker les valeurs dans un tableau indépendant. La meilleure alternative à faire est d'ajouter une référence à Microsoft Scripting Runtime & utilisation plus capable d'Dictionnaire de la place.
J'ai inclus cette approche pour obtenir la liste des clés dans mon programme.

Pendant le remplissage de la Collection de veiller à ce que la clé est le deuxième paramètre doit être une chaîne unique.

Code complet de mon programme.
```
Sub Generic_key_check()
Dim arr As Variant
Dim c1 As New Collection
Dim dic As Object
With Application
.ScreenUpdating = False
End With
Set dic = CreateObject("Scripting.Dictionary")
dic.CompareMode = vbTextCompare
'Populate the collection
c1.Add "sheet1", "sheet1"
c1.Add "sheet2", "sheet2"
c1.Add "sheet3", "sheet3"
c1.Add "sheet4", "sheet4"
c1.Add "sheet5", "sheet5"
c1.Add 2014001, "Long1"
c1.Add 2015001, "Long2"
c1.Add 2016001, "Long3"
c1.Add 2015002, "Long4"
c1.Add 2016002, "Long5"
'Populate the dictionary
dic.Add "sheet1", "sheet1"
dic.Add "sheet2", "sheet2"
dic.Add "sheet3", "sheet3"
dic.Add "sheet4", "sheet4"
dic.Add "sheet5", "sheet5"
dic.Add "Long1", 2014001
dic.Add "Long2", 2015001
dic.Add "Long3", 2016001
dic.Add "Long4", 2015002
dic.Add "Long5", 2016002
' Get a list of key items by Dictionary Method
Dim N As Variant
For Each N In dic.Keys
Debug.Print "Key: " & N, "Value: " & dic.item(N)
Next
'Test for two types of data whether key exists or not.
If InCollection(c1, "Long1") Then
'If Exists("Long1", c1) Then
Debug.Print "Good"
Else
' If there is error then print out the error number and its description.
Debug.Print Err.Number, Err.Description
Debug.Print "Not Good"
End If
If InCollection(c1, "sheet2") Then
Debug.Print "Good"
Else
Debug.Print Err.Number, Err.Description
Debug.Print "Not Good"
End If
'Checking whether desired key has populated correctly
Debug.Print c1("Sheet1")
Debug.Print c1("Long3")
'Listing out collection items to check theyexist in the collection.
For i = 1 To c1.Count
Debug.Print c1.item(i)
Next i
With Application
.ScreenUpdating = True
End With
Set c1 = Nothing
End Sub
Public Function InCollection(col As Collection, key As String) As Boolean
Dim var As Variant
Dim errNumber As Long
InCollection = False
Set var = Nothing
Err.Clear
On Error Resume Next
var = col.item(key)
errNumber = CLng(Err.Number)
On Error GoTo 0
'5 is not in, 0 and 438 represent incollection
If errNumber = 5 Then ' it is 5 if not in collection
InCollection = False
Else
InCollection = True
End If
End Function
```
Sortie finale selon le programme, comme indiqué dans la fenêtre d'exécution a été montré dans la capture d'écran.

+1 pour montrer l'application de Dictionary de Scripting Runtime library. C'est une honte que ce n'est pas un défaut d'Excel VBA.

OriginalL'auteur skkakkar

La méthode de Robin échouera si la Collection contient des objets plutôt que des types primitifs parce qu'ils ont besoin d'être affectée à l'aide d'Ensemble et autrement générer une erreur de sorte que la méthode de retour Faux. Voici une petite adaptation:

'Test if a key is available in a collection
Public Function HasKey(coll As Collection, strKey As String) As Boolean
On Error GoTo IsMissingError
Dim val As Variant
'        val = coll(strKey)
HasKey = IsObject(coll(strKey))
HasKey = True
On Error GoTo 0
Exit Function
IsMissingError:
HasKey = False
On Error GoTo 0
End Function

OriginalL'auteur Apostle

0

Apôtre est presque correct avec leur réponse. Robin réponse ne fonctionnera pas avec des objets génériques, mais fonctionne comme écrit en raison d'Excel objet de la Plage sera de retour la valeur de la cellule. J'aime Apôtre de l'utilisation de IsObject (surtout parce que la sat est ce que j'avais compris ainsi). Le code est un peu plus compliqué.

Si la clé existe dans la collection IsObject sera de définir la variante à True ou à False, sinon une erreur sera ignorée de quitter la variante vide.
```
Function HasKey(col As Collection, Key As String) As Boolean
Dim v As Variant
On Error Resume Next
v = IsObject(col.Item(Key))
HasKey = Not IsEmpty(v)
End Function
```
OriginalL'auteur PaulE

Vous devez vous connecter pour publier un commentaire.