Microsoft Access VBA pour modifier des requêtes SQL

La question est un peu mince sur ce genre de requête que vous souhaitez modifier, mais dire que c'est une requête select qui n'a pas besoin de paramètres dynamiques.

Puis, à l'aide de la CopyObject méthode, faire une copie de la requête que vous avez fait. Utiliser le Catalog objet (vous aurez besoin de faire référence à l'ADO Ext). Ensuite, vous pouvez simplement modifier le SQL de la copie comme ci-dessous. En fonction de votre requête, il peut être d'une Vue ou d'une Procédure, mais d'une requête de sélection doit être répertorié comme un point de Vue.

Dim catDB As ADOX.Catalog
Dim cmd As ADODB.Command
Dim sQueryName As String
Dim sSQL As String

Set cn = CurrentProject.Connection
Set catDB = New ADOX.Catalog

catDB.ActiveConnection = cn
DoCmd.CopyObject , "Query1_c", acQuery, "Query1"
sQueryName = "Query1_c"
sSQL = "SELECT a,b,c FROM Table1"

Set cmd = New ADODB.Command
Set cmd = catDB.Views(sQueryName).Command
cmd.CommandText = sSQL
Set catDB.Views(sQueryName).Command = cmd

Set catDB = Nothing
cn.Close

Je fais ce genre de chose tout le temps! J'ai utilisé VBA pour réécrire les requêtes Access ainsi que les requêtes que "passer" à une base de données MySQL. Réécriture d'une requête en VBA dépend de la complexité que vous voulez obtenir.

J'ai toujours utilisé des DAO, ce qui est plus âgé de la technologie (voir les commentaires ci-dessous pour des précisions sur DAO vs ADO), mais il a travaillé pour moi dans ce cas. Vous aurez besoin d'ajouter une référence à DAO en VBA en allant dans Outils > Références, puis ajouter "Microsoft DAO 3.6 Object Library".

Vous pouvez écrire une procédure qui ressemble à ceci:

Sub RewriteQuerySQL(strQueryName As String, strParameter As String)
    Dim db As DAO.Database
    Dim qdf As DAO.QueryDef
    Set db = CurrentDb()
    Set qdf = db.QueryDefs(strQueryName)

    qdf.SQL = "SELECT [Table].Field1, [Table].Field2 " & vbCrLf & _
              "FROM [Table] " & vbCrLf & _
              "WHERE ([Table].Field1 = " & chr(34) & strParameter & chr(34) & ");"
End Sub

Le code ci-dessus va changer le code SQL de la requête que vous spécifiez avec la requête SQL dans le code VBA avec la strParameter incorporé dans la requête SQL.

Voici une autre façon de faire. C'est le code que j'ai utilisé dans une déclaration des ventes de demande de réécriture d'une requête sur la base d'un vendeur numéro:

Sub rewriteAccountsBySalesRepSortSQL(lngSalesRep As Long)
    Dim db As DAO.Database
    Dim qdf As DAO.QueryDef
    Dim strSQL As String
    Dim strOriginal As String
    Dim strReplacePart As String
    Dim strSQLReplace As String
    Dim lngLocSalesperson As Long
    Dim lngLocMyRoundUp As Long
    Dim lngLocParen As Long
    Dim lngLocEndParen As Long

    Set db = CurrentDb()
    Set qdf = db.QueryDefs("qryS Accounts by Sales Rep Sorted by Diff DESC")
    strSQL = qdf.SQL

    lngLocSalesperson = InStr(strSQL, "Salesperson1)=")
    lngLocEndParen = InStr(lngLocSalesperson + 14, strSQL, ")")
    strOriginal = Mid(strSQL, lngLocSalesperson, lngLocEndParen - lngLocSalesperson)
    'lngLocParen = InStrRev(strSQL, "(", lngLocSalesperson)

    strReplacePart = "Salesperson1)=" & lngSalesRep

    strSQLReplace = Replace(strSQL, strOriginal, strReplacePart)
    qdf.SQL = strSQLReplace
End Sub

Au lieu d'écrire la totalité de la requête, le code trouve tout simplement l'actuel représentant des ventes, le nombre et le remplace par le nouveau numéro. Je préfère la méthode de ce dernier. Cette dernière méthode a été utilisée pour envoyer directement une requête à MySQL, donc la syntaxe avec une requête Access peuvent être légèrement différentes.