mise à jour à l'aide de la boucle en plsql

Vous n'avez pas besoin FOR LOOP, juste une mise à JOUR fait le travail:

UPDATE emp
  SET comm = extra
WHERE comm IS NULL AND extra IS NOT NULL;

Voici une démo: http://www.sqlfiddle.com/#!4/aacc3/1

--- EDIT ----

Je n'avais pas remarqué, que dans de la sortie attendue de deptno 10 a été mis à jour à 20,
mise à jour deptno une autre requête est nécessaire:

UPDATE emp
   SET deptno = 20
WHERE deptno = 10;

---- EDIT -----

Si vous souhaitez insérer les valeurs modifiées à l'autre table, essayez une procédure de RETOUR..en VRAC RECUEILLIR et POURTOUT:

CREATE OR REPLACE PROCEDURE pro_cedure( p_dept_id number  ) 
IS
      TYPE changed_table_type IS TABLE OF changed%ROWTYPE;
      changed_buff changed_table_type;
BEGIN
      SELECT deptno, comm, extra BULK COLLECT INTO changed_buff
      FROM emp
      WHERE comm IS NULL AND extra IS NOT NULL AND deptno = p_dept_id
      FOR UPDATE;
      UPDATE emp
      SET comm = extra
      WHERE comm IS NULL AND extra IS NOT NULL AND deptno = p_dept_id;
      FORALL i IN 1 .. changed_buff.count
        INSERT INTO changed VALUES changed_buff( i );
END;
/

La procédure devrait fonctionner si vous n'êtes pas passer grand nombre d'enregistrements dans un appel (plus de 1000 ... ou au maximum quelques milliers). Si l'on dept_id peut contenir des dizaines de milliers et plus de lignes, alors cette procédure peut être lente, car il va consommer une quantité énorme de la PGA de la mémoire. Dans un tel cas, une autre approche avec en vrac collectiong en morceaux est nécessaire.

-- EDIT --- comment stocker les valeurs de séquence -------

Je suppose que la table changed a 4 colonnes, comme ceci:

  CREATE TABLE "TEST"."CHANGED" 
   (    "DEPTNO" NUMBER, 
        "OLDVAL" NUMBER, 
        "NEWVAL" NUMBER, 
        "SEQ_NEXTVAL" NUMBER 
   ) ;

et nous allons stocker les valeurs de séquence dans le seq_nextval colonne.

Dans un tel cas, la procédure pourrait ressembler à ceci:

create or replace 
PROCEDURE pro_cedure( p_dept_id number  ) 
IS
      TYPE changed_table_type IS TABLE OF changed%ROWTYPE;
      changed_buff changed_table_type;
BEGIN
      SELECT deptno, comm, extra, sequence_name.nextval 
        BULK COLLECT INTO changed_buff
        FROM emp
        WHERE comm IS NULL AND extra IS NOT NULL AND deptno = p_dept_id
        FOR UPDATE;
      UPDATE emp
        SET comm = extra
        WHERE comm IS NULL AND extra IS NOT NULL AND deptno = p_dept_id;
      FORALL i IN 1 .. changed_buff.count
        INSERT INTO changed VALUES changed_buff( i );
END;

--- EDIT --- version avec le curseur pour de petits ensembles de données -----

Oui, pour de petits ensembles de données en vrac collecte ne donne pas d'augmentation significative de la vitesse, et la plaine curseur avec pour..la boucle est suffisante dans de tels cas.

Ci-dessous est un exemple de la façon dont tu utiliser le curseur avec la mise à jour, de l'avis de la FOR UPDATE clause, il est nécessaire lorsque nous avons l'intention de mettre à jour un enregistrement extraite à partir du curseur à l'aide de WHERE CURRENT OF clause.

Cette fois, une valeur de séquence est évalué dans le cadre de l'instruction INSERT.

create or replace 
PROCEDURE pro_cedure( p_dept_id number  ) 
IS
      CURSOR mycursor IS 
         SELECT deptno, comm, extra
         FROM emp
         WHERE comm IS NULL AND extra IS NOT NULL 
               AND deptno = p_dept_id
         FOR UPDATE;    
BEGIN
      FOR emp_rec IN  mycursor
      LOOP
         UPDATE emp 
            SET comm = extra
            WHERE CURRENT OF mycursor;
         INSERT INTO changed( deptno, oldval, newval, seq_nextval)
                VALUES( emp_rec.deptno, emp_rec.comm, 
                        emp_rec.extra, sequence_name.nextval );
      END LOOP;
END;

OriginalL'auteur krokodilko