Mot clé "surcharges" dans VB.NET

Cela montre bien haut dans les résultats de Google, et je pense que ça pourrait être expliqué plus clairement ici.

Il n'y a aucune raison d'utiliser la Overloads mot-clé lorsque vous êtes à la surcharge de diverses méthodes à l'intérieur de la même classe. La raison principale que vous pouvez utiliser Overloads est de permettre à une classe dérivée pour appeler une méthode de sa classe de base qui a le même nom que la méthode surchargée, mais une signature différente.

Supposons que vous avez deux classes, Foo et SonOfFoooù SonOfFoo hérite de Foo. Si Foo implémente une méthode appelée DoSomething et SonOfFoo implémente la méthode avec le même nom, le SonOfFoo méthode permet de masquer les parents d'implémentation de la classe...même si les deux méthodes utilisent des paramètres différents. La spécification de la Overloads mot-clé va permettre à la classe dérivée appeler le parent de la classe des surcharges de la méthode.

Voici un code pour le démontrer, avec les classes Foo et SonOfFoo mis en œuvre comme décrit, et l'autre paire de classes, Bar et SonOfBar qui utilisent le Overloads mot-clé:

Class Foo
    Public Sub DoSomething(ByVal text As String)
        Console.WriteLine("Foo did: " + text)
    End Sub
End Class

Class SonOfFoo
    Inherits Foo

    Public Sub DoSomething(ByVal number As Integer)
        Console.WriteLine("SonOfFoo did: " + number.ToString())
    End Sub
End Class

Class Bar
    Public Sub DoSomething(ByVal text As String)
        Console.WriteLine("Bar did: " + text)
    End Sub
End Class

Class SonOfBar
    Inherits Bar

    Public Overloads Sub DoSomething(ByVal number As Integer)
        Console.WriteLine("SonOfBar did: " + number.ToString())
    End Sub
End Class

Sub Main()
    Dim fooInstance As Foo = New SonOfFoo()
    'works
    fooInstance.DoSomething("I'm really a SonOfFoo")
    'compiler error, Foo.DoSomething has no overload for an integer
    fooInstance.DoSomething(123)

    Dim barInstance As Bar = New SonOfBar()
    'works
    barInstance.DoSomething("I'm really a SonOfBar")
    'compiler error, Bar.DoSomething has no overload for an integer
    barInstance.DoSomething(123)

    Dim sonOfFooInstance As New SonOfFoo()
    'compiler error, the base implementation of DoSomething is hidden and cannot be called
    sonOfFooInstance.DoSomething("I'm really a SonOfFoo")
    'works
    sonOfFooInstance.DoSomething(123)

    Dim sonOfBarInstance As New SonOfBar()
    'works -- because we used the Overloads keyword
    sonOfBarInstance.DoSomething("I'm really a SonOfBar")
    'works
    sonOfBarInstance.DoSomething(123)
End Sub

Voici quelques informations sur la façon dont cette compile de manière différente dans les CLI.

Miky D est la droite. Il n'y a pas de différence entre une méthode surchargée déclaré Surcharges et une autre qui ne l'est pas.

Je voulais juste faire remarquer que les Surcharges mot-clé est obligatoire lorsqu'une autre méthode avec le même nom est déclarée des Remplacements ou des Surcharges. Par exemple, si vous substituez la méthode Equals comme ceci:

Public Overrides Function Equals(ByVal obj As Object) As Boolean ...

Alors vous voulez créer une surcharge comme ceci:

Public Function Equals(ByVal otherProduct As Product) As Boolean ...

Vous obtiendrez l'erreur suivante:

"function 'Equals' must be declared 'Overloads' because another 'Equals' 
is declared 'Overloads' or 'Overrides'."

Vous obtiendrez la même erreur si quelqu'un a déclaré une méthode que les Surcharges, et que vous voulez la surcharge de cette méthode. Vous n'aurez qu'à ajouter les Surcharges de mot-clé pour votre méthode ou le supprimer de l'autre méthode.

J'ai personnellement jamais déclarer une méthode surchargée Surcharges, à moins que je n'ai pas le choix, comme dans la situation ci-dessus.

La Overloadsmot-Clé est totalement facultatif - je ne vois pas les avantages de l'utilisation de cela.