multiplot - l'empilement 3 graphes sur une grande toile

J'ai essayé très en vain de pile 3 graphiques ensemble dans un multi-parcelle mise en page sur une toile qui est un ratio de 2:3(largeur par hauteur).

set terminal postscript eps enhanced "Helvetica" 24 color
set output "data.eps"
set timefmt "%s"

#set size 1.0,1.5
#set bmargin 2
#set tmargin 2

set size 1.0,1.5
set multiplot layout 3,1
set size 1.0,0.5

set tmargin 2
set bmargin 0
set ylabel 'Distance'
set format x ""
set ytics nomirror font "Helvetica,10"
set key top
plot "trace1.dat" using 1:3 axes x1y1 title "distances" with lines lw 2 lc rgb 'blue'

set size 1.0,0.5
set bmargin 0
set tmargin 0
set ylabel 'Power (W)'
set format x ""
set ytics nomirror font "Helvetica,10"
set key top
plot "trace2.dat" using 1:2 axes x1y1 title "device" with lines lw 2 lc rgb 'red'

set size 1.0,0.5
set bmargin
set tmargin 0 
set xdata time
set ylabel 'Power (W)'
set xlabel 'Time (EST)' offset 0,-2.8 font "Helvetica,32
set format x "%b %d, %H:%M"
set ytics nomirror font "Helvetica,10"
set xtics nomirror rotate by 90 offset 0,-2.0 out font "Helvetica,10"
set key top
plot "trace3.dat" using 1:2 axes x1y1 title "aggr" with lines lw 2 lc rgb 'blue'

unset multiplot

Quand je fais quelque chose comme ci-dessus, j'obtiens le tracé indiqué ci-dessous, il y a beaucoup d'espace vide en haut de la toile et le 3 multiplot graphiques semblent se chevaucher les uns les autres.

De l'aide ou un pointeur sera grandement apprécié.

OriginalL'auteur Sandman | 2013-10-02

gnuplot

15

Dans un souci de plus grande toile, vous devez utiliser le size option lors de la configuration du terminal, par exemple:
```
set terminal postscript eps enhanced size 10cm,15cm
```
set size change juste la taille de la parcelle par rapport à votre toile. Pour voir cela, considérons
```
set terminal wxt
set size 1.0,1.5
plot sin(x)
```
Les parties de l'intrigue disparaître, car il est beaucoup trop haut par rapport à la toile.

La pile de trois parcelles de même hauteur, à mon avis, de son mieux pour utiliser des marges fixes:
```
set terminal pngcairo size 600, 900
set output 'stacking.png'

set lmargin at screen 0.15
set rmargin at screen 0.95

TOP=0.98
DY = 0.29

set multiplot
set offset 0,0,graph 0.05, graph 0.05

set xlabel 'time'
set ylabel 'ylabel 1' offset 1
set tmargin at screen TOP-2*DY
set bmargin at screen TOP-3*DY
set ytics -1000,500,1000
plot 1150*cos(x) title 'First'

set xtics format ''
unset xlabel
set ylabel 'ylabel 2' offset 0
set tmargin at screen TOP-DY
set bmargin at screen TOP-2*DY
set ytics -100,50,100
plot 101*sin(x) title 'Second'

set ylabel 'ylabel 3' offset -1
set tmargin at screen TOP
set bmargin at screen TOP-DY
set ytics -8,4,8
plot 10*sin(2*x) title 'Third'

unset multiplot; set output
```
Le résultat est (avec 4.6.3):

Afin d'éviter le chevauchement des étiquettes de la ytics, vous devez modifier la plage où les tics sont tirés, par exemple, avec set ytics -100,50,100, qui met ytics entre -100 et 100 dans les étapes de 50. À l'aide de set ytics rangelimited ne fonctionne pas

Pour augmenter la distance entre le tracé de la courbe et de la frontière, à l'utilisation set offset avec graph coordonnées, comme le fait dans le script ci-dessus.

J'ai commencé avec le plus bas de la parcelle, car seulement que a x étiquettes et une xlabel.

Cela a fonctionné pour moi! Apprécier des tonnes! Ne pouvait pas se déplacer à l'acceptation de votre réponse plus tôt, désolé pour cela, mais des marges fixes semble être la voie à suivre. Merci! 🙂

OriginalL'auteur Christoph

Vous devez utiliser set origin, trop.

set terminal postscript eps enhanced
set output "data.eps"

set size 1.0,1.5
set multiplot layout 3,1

set size 1.0,0.5
set origin 0,1
...
plot ...

set size 1.0,0.5
set origin 0,0.5
...
plot ...

set size 1.0,0.5
set origin 0,0
...
plot ...

unset multiplot

merci pour le code 🙂

OriginalL'auteur ztik

Vous devez vous connecter pour publier un commentaire.