Ne peut pas VBA écrire des données dans des cellules dans Excel 2007/2010 au sein d'une fonction

De votre commentaire ci-dessus vous voulais essayer cette approche

Si vous entrez

=abb()

dans n'importe quelle cellule

Puis la cellule A1 de la feuille de wil être mis à 12333

C'est la ligne de mise à jour de choisir la cellule de mise à jour, et de placer une valeur dans il

Range("A1").Value = 122333

De Je ne veux pas que mon Excel Add-In pour retourner un tableau (à la place j'ai besoin d'une fonction pour modifier d'autres cellules)

Je suis reposter ce morceau de la magie de Kevin Jones aka Zorvek comme il se trouve derrière l'EE Paywall (lien joint si quelqu'un a accès)

Alors que Excel strictement interdit à un UDF de modifier une cellule de feuille de calcul,
ou les propriétés de classeur, il y a un moyen pour effet de tels changements lorsque un
UDF est appelée à l'aide d'une horloge de Windows et d'une Application.OnTime minuterie dans
la séquence. L'horloge de Windows doit être utilisé au sein de l'UDF, parce que
Excel ignore tout de l'Application.OnTime les appels à l'intérieur d'une UDF. Mais, parce que
l'horloge de Windows a des limites (Excel instantanément quitter si un
Horloge de Windows tente d'exécuter du code VBA si une cellule est en cours d'édition ou un
boîte de dialogue est ouverte), il est utilisé uniquement pour programmer une Application.OnTime
un chronomètre, d'un coffre-fort timer qui Excel permet seulement d'être déclenché si une cellule est
pas en cours d'édition et pas de boîtes de dialogue sont ouvertes.

L'exemple de code ci-dessous illustre la façon de démarrer une horloge de Windows à partir de
à l'intérieur d'une UDF, comment faire pour utiliser la minuterie pour démarrer une routine
Application.OnTime minuterie, et comment passer de l'information connue seulement de
l'UDF ultérieure de la minuterie exécuté routines. Le code ci-dessous doit être
placé dans un module normal.

Declare Function SetTimer Lib "user32" ( _
ByVal HWnd As Long, _
ByVal nIDEvent As Long, _
ByVal uElapse As Long, _
ByVal lpTimerFunc As Long _
) As Long
Private Declare Function KillTimer Lib "user32" ( _
ByVal HWnd As Long, _
ByVal nIDEvent As Long _
) As Long
Private mCalculatedCells As Collection
Private mWindowsTimerID As Long
Private mApplicationTimerTime As Date
Public Function abb()
' This is a UDF that returns the sum of two numbers and starts a windows timer
' that starts a second Appliction.OnTime timer that performs activities not
' allowed in a UDF. Do not make this UDF volatile, pass any volatile functions
' to it, or pass any cells containing volatile formulas/functions or
' uncontrolled looping will start.
abb = "Whatever you want"
' Cache the caller's reference so it can be dealt with in a non-UDF routine
If mCalculatedCells Is Nothing Then Set mCalculatedCells = New Collection
On Error Resume Next
mCalculatedCells.Add Application.Caller, Application.Caller.Address
On Error GoTo 0
' Setting/resetting the timer should be the last action taken in the UDF
If mWindowsTimerID <> 0 Then KillTimer 0&, mWindowsTimerID
mWindowsTimerID = SetTimer(0&, 0&, 1, AddressOf AfterUDFRoutine1)
End Function
Public Sub AfterUDFRoutine1()
' This is the first of two timer routines. This one is called by the Windows
' timer. Since a Windows timer cannot run code if a cell is being edited or a
' dialog is open this routine schedules a second safe timer using
' Application.OnTime which is ignored in a UDF.
' Stop the Windows timer
On Error Resume Next
KillTimer 0&, mWindowsTimerID
On Error GoTo 0
mWindowsTimerID = 0
' Cancel any previous OnTime timers
If mApplicationTimerTime <> 0 Then
On Error Resume Next
Application.OnTime mApplicationTimerTime, "AfterUDFRoutine2", , False
On Error GoTo 0
End If
' Schedule timer
mApplicationTimerTime = Now
Application.OnTime mApplicationTimerTime, "AfterUDFRoutine2"
End Sub
Public Sub AfterUDFRoutine2()
' This is the second of two timer routines. Because this timer routine is
' triggered by Application.OnTime it is safe, i.e., Excel will not allow the
' timer to fire unless the environment is safe (no open model dialogs or cell
' being edited).
Dim Cell As Range
' Do tasks not allowed in a UDF...
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
Do While mCalculatedCells.Count > 0
Set Cell = mCalculatedCells(1)
mCalculatedCells.Remove 1
Range("A1").Value = 122333
Loop
Application.Calculation = xlCalculationAutomatic
Application.ScreenUpdating = True
End Sub

Si vous souhaitez modifier deux cellules dont l'une formule, vous pouvez envisager de retourner un tableau à partir de votre fonction. Voici un exemple:

Function abb()
Dim arr As Variant
ReDim arr(1 To 2)
arr(1) = "aardvark"
arr(2) = "bee"
abb = arr
End Function

Sélectionnez les cellules A2 à B2. Type =abb() et appuyez sur MajCtrlEntrée pour indiquer qu'il s'agit d'une formule matricielle. Cette formule modifie alors les deux cellules (A2 et B2) en même temps.

Peut-être que vous pouvez personnaliser cette de faire ce que vous voulez.