Nœud de comte et de la occurence - XSL

J'ai besoin d'écrire générique xsl qui prendrait dans un document xml de sortie et le nombre de nœuds et de leurs noms. Donc, si j'ai un fichier comme suit:

   <assets>
    <asset>
        <type>hardware</type>
        <item>
            <name>HP laptop</name>
            <value>799</value>
        </item>
        <item>
            <name>server</name>
            <value>1000</value>
        </item>
        <item>
            <name>ViewSonic Monitor</name>
            <value>399</value>
        </item>
    </asset>
    <asset>
        <type>software</type>
        <item>
            <name>Windows Vista</name>
            <value>399</value>
        </item>
        <item>
            <name>Office XP</name>
            <value>499</value>
        </item>
        <item>
            <name>Windows 7</name>
            <value>399</value>
        </item>
          <item>
            <name>MS Project Professional 2007</name>
            <value>299</value>
          </item>
       </asset>
    </assets>

La sortie serait:

   <output>
    <node name="assets" count="1"/>
    <node name="asset" count="2"/>
    <node name= "type" count="??"/>
    <node name="item" count=??/>
    <node name="name" count=??/>
    <node name="value" count=??/>
    </output>

OriginalL'auteur user182093 | 2009-09-30

  1. 6

    Vous aurez envie d'utiliser la fonction count:

    <xsl:value-of select="count(assets/asset)" />

    De sorte que votre code devrait ressembler à:

    Assets: <xsl:value-of select="count(assets)" />
Asset:  <xsl:value-of select="count(assets/asset)" />
Item:   <xsl:value-of select="count(assets/asset/item)" />

    OriginalL'auteur Gavin Miller

  2. 4

    La solution générique pour l'entrée contenant les nœuds avec des noms peut être fait à l'aide de la Muenchian méthode:

    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:key name="nodes-by-name" match="*" use="name()"/>
  <xsl:template match="/">
    <output>
      <xsl:for-each select="//*[count(.|key('nodes-by-name', name())[1]) = 1]">
        <node name="{name()}" count="{count(key('nodes-by-name', name()))}"/>
      </xsl:for-each>
    </output>
  </xsl:template>
</xsl:stylesheet>

    Explication: à l'Aide de xsl:key, créez un mappage de noms pour les nœuds ayant ce nom. Puis itérer sur tous les noms uniques, et la sortie du nœud de compte pour le nom. L'astuce ici est de savoir comment parcourir des noms uniques. Voir la page du lien pour une explication de la count(.|foo)=1 idiome utilisé pour déterminer si foo est un ensemble de nœuds contenant uniquement le nœud de contexte.

    +1, même si j'aime generate-id() mieux. La question ressemble un peu à des devoirs à moi.

    OriginalL'auteur Jukka Matilainen

  3. 1

    C'est ma solution à l'aide de XSLT 2.0 :

    <?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   xmlns:xs="http://www.w3.org/2001/XMLSchema" version="2.0">

   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="/">
      <xsl:element name="output">
         <xsl:for-each-group select="//*" group-by="name()">
            <xsl:element name="node">
               <xsl:attribute name="name">
                  <xsl:value-of select="current-grouping-key()"/>
               </xsl:attribute>
               <xsl:attribute name="count">
                  <xsl:value-of select="count(current-group())"/>
               </xsl:attribute>
            </xsl:element>
         </xsl:for-each-group>
      </xsl:element>
   </xsl:template>

</xsl:stylesheet>

    OriginalL'auteur Mohamed