N'VBA ont tout construit dans l'URL de décodage?

J'ai juste besoin de décoder une URL, par exemple, remplacer %2E avec .
Je peux pirater une méthode si l'on n'est pas à construire, mais mon hypothèse est qu'il doit y avoir une URL de décodage de l'outil déjà existant.

Je ne pense pas qu'il y a quelque chose de construit en.
double possible de Comment puis-je encoder une chaîne en VBA Excel?
Vous pouvez utiliser windows natif JScript encodeURIComponent() via htmlfile ActiveX.

OriginalL'auteur Russell Steen | 2011-02-14

  1. 6

    Pas.

    Mais en voici un: URL de l'Encodeur et du Décodeur pour VB

    Ou quelque chose le long des lignes de (peut-être pas exhaustive):

    Public Function URLDecode(ByVal strEncodedURL As String) As String
   Dim str As String
   str = strEncodedURL 
   If Len(str) > 0 Then
      str = Replace(str, "&amp", " & ")
      str = Replace(str, "&#03", Chr(39))
      str = Replace(str, "&quo", Chr(34))
      str = Replace(str, "+", " ")
      str = Replace(str, "%2A", "*")
      str = Replace(str, "%40", "@")
      str = Replace(str, "%2D", "-")
      str = Replace(str, "%5F", "_")
      str = Replace(str, "%2B", "+")
      str = Replace(str, "%2E", ".")
      str = Replace(str, "%2F", "/")

      URLDecode = str
  End If

End Function

    Aussi, jetez un oeil à Comment puis-je encoder une chaîne de caractères dans Excel VBA?

    Si, à supposer qu'il n'existe qu'-unis dans le monde, la liste est complète.
    voir ce bit?: "...(peut-être pas complet)"
    Merci pour l'idée Mitch... @Paul, vous avez raison, pour dire.. "%20" (de l'espace) est manquant..

    OriginalL'auteur Mitch Wheat

  2. 5

    Voici un morceau de code que j'ai écrit il y a des années

    -markus

    Public Function URLDecode(sEncodedURL As String) As String

On Error GoTo Catch

Dim iLoop   As Integer
Dim sRtn    As String
Dim sTmp    As String

If Len(sEncodedURL) > 0 Then
    ' Loop through each char
    For iLoop = 1 To Len(sEncodedURL)
        sTmp = Mid(sEncodedURL, iLoop, 1)
        sTmp = Replace(sTmp, "+", " ")
        ' If char is % then get next two chars
        ' and convert from HEX to decimal
        If sTmp = "%" and LEN(sEncodedURL) + 1 > iLoop + 2 Then
            sTmp = Mid(sEncodedURL, iLoop + 1, 2)
            sTmp = Chr(CDec("&H" & sTmp))
            ' Increment loop by 2
            iLoop = iLoop + 2
        End If
        sRtn = sRtn & sTmp
    Next
    URLDecode = sRtn
End If

Finally:
    Exit Function
Catch:
    URLDecode = ""
    Resume Finally
End Function
    Dans la version MAC de microsoft Excel 2011, le functin CDec n'existe pas. Je l'ai remplacé par CDbl avec succès

    OriginalL'auteur markus diersbock

  3. 1

    EncodeURL et DecodeURL fonction à l'aide de htmlfile objet(liaison Tardive)

    J'ai eu cette source à partir de ce site: http://cocosoft.kr/442

    Function ENCODEURL(varText As Variant, Optional blnEncode = True)
    Static objHtmlfile As Object
    If objHtmlfile Is Nothing Then
        Set objHtmlfile = CreateObject("htmlfile")
        With objHtmlfile.parentWindow
            .execScript "function encode(s) {return encodeURIComponent(s)}", "jscript"
        End With
    End If
    If blnEncode Then
        ENCODEURL = objHtmlfile.parentWindow.encode(varText)
    End If
End Function

Function DECODEURL(varText As Variant, Optional blnEncode = True)
    Static objHtmlfile As Object
    If objHtmlfile Is Nothing Then
        Set objHtmlfile = CreateObject("htmlfile")
        With objHtmlfile.parentWindow
            .execScript "function decode(s) {return decodeURIComponent(s)}", "jscript"
        End With
    End If
    If blnEncode Then
        DECODEURL = objHtmlfile.parentWindow.decode(varText)
    End If
End Function

    Par exemple,

    str = ENCODEURL("/?&=") 'returns "%2F%3F%26%3D"
str = DECODEURL("%2F%3F%26%3D") 'returns "/?&="

    OriginalL'auteur konahn