Obtenez de début de gamme et de gamme d'une cellule fusionnée verticalement avec Excel en utilisant VBA

J'ai besoin de savoir la cellule première et la dernière cellule d'une cellule fusionnée verticalement..

Disons que j'ai fusionner les Cellules B2 vers le bas pour B50.

Comment puis-je obtenir en VBA le début de la cellule(=B2) et la fin de la cellule(=B50)?

Que voulez-vous faire une fois que vous trouvez ces valeurs? Comment voulez-vous que la réponse de sortie? Comme une chaîne de caractères? Comme un objet de la plage?

OriginalL'auteur vbauser | 2010-06-01

Sub MergedAreaStartAndEnd()

    Dim rng As Range
    Dim rngStart As Range
    Dim rngEnd As Range

    Set rng = Range("B2")

    If rng.MergeCells Then

        Set rng = rng.MergeArea
        Set rngStart = rng.Cells(1, 1)
        Set rngEnd = rng.Cells(rng.Rows.Count, rng.Columns.Count)

        MsgBox "First Cell " & rngStart.Address & vbNewLine & "Last Cell " & rngEnd.Address

    Else

        MsgBox "Not merged area"

    End If

End Sub

Vous pouvez également faire rng.MergeArea.Address

OriginalL'auteur dendarii

En dessous de macro passe par toutes les feuilles dans un classeur et trouve des cellules fusionnées, les annuler et mettre la valeur d'origine de toutes les cellules fusionnées.

Ce qui est fréquemment nécessaire pour DB applications, donc je voulais la partager avec vous.

Sub BirlesenHucreleriAyirDegerleriGeriYaz()
    Dim Hucre As Range
    Dim Aralik
    Dim icerik
    Dim mySheet As Worksheet

    For Each mySheet In Worksheets

    mySheet.Activate
    MsgBox mySheet.Name & “ yapılacak…”

    For Each Hucre In mySheet.UsedRange
        If Hucre.MergeCells Then
           Hucre.Orientation = xlHorizontal
           Aralik = Hucre.MergeArea.Address
           icerik = Hucre
           Hucre.MergeCells = False
           Range(Aralik) = icerik
        End If
    Next

 MsgBox mySheet.Name & " Bitti!!"

 Next mySheet
End Sub

OriginalL'auteur Mustafa Aksit

0

Bien, en supposant que vous connaissez l'adresse de l'une des cellules de la fusion de gamme, vous pouvez simplement sélectionner le décalage à partir de la gamme et d'obtenir de la ligne/colonne:
```
Sub GetMergedRows()
    Range("A7").Select 'this assumes you know at least one cell in a merged range.
    ActiveCell.Offset(-1, 0).Select
    iStartRow = ActiveCell.Row + 1
    Range("A7").Select
    ActiveCell.Offset(1, 0).Select
    iEndRow = ActiveCell.Row - 1
    MsgBox iStartRow & ":" & iEndRow
End Sub
```
Le code ci-dessus va générer des erreurs si le décalage de la ligne ne peut pas être sélectionné (c'est à dire si la fusion de lignes A1 à quoi que ce soit) de sorte que vous voulez ajouter la gestion des erreurs que dit le code, si il ne peut pas compenser, le haut des gradins doit être à 1 et si il ne peut pas aller vers le bas, le bas de ligne doit être de 65 536. Ce code est également à seulement un dimensions de sorte que vous voudrez peut-être ajouter de l'axe des abscisses.

OriginalL'auteur Bradley Mountford
0

Si vous voulez les références de cellules comme des chaînes de caractères, vous pouvez utiliser quelque chose comme cela, où l'Emplacement, StartCell, et EndCell sont variables de chaîne de caractères.
```
Location = Selection.Address(False, False)
Colon = InStr(Location, ":")
If Colon <> 0 Then
    StartCell = Left(Location, Colon - 1)
    EndCell = Mid(Location, Colon + 1)
End If
```
Si vous souhaitez définir comme des chaînes, vous pouvez ajouter cette, où StartRange et EndRange sont Gamme d'objets.
```
set StartRange = Range(StartCell)
set EndRange = Range (EndCell)
```
OriginalL'auteur KevenDenen
0

Supposons que vous avez fusionné B2 vers le bas pour B50.

Ensuite, démarrez l'adresse de la cellule sera:
```
MsgBox Range("B2").MergeArea.Cells(1, 1).Address
```
La fin de l'adresse de la cellule sera:
```
With Range("B2").MergeArea
    MsgBox .Cells(.Rows.Count, .Columns.Count).Address
End With
```
Vous pouvez mettre l'adresse de n'importe quelle cellule de la zone fusionnée à la place de B2 dans le code ci-dessus.

OriginalL'auteur ePandit

Vous devez vous connecter pour publier un commentaire.