Obtenir des Détails des ANNONCES basées sur le nom d'utilisateur

J'ai un code pour récupérer les informations d'un utilisateur de l'AD telles que l'adresse e-mail, numéro de téléphone, etc, etc. Les codes que j'utilise actuellement est:

Set objSysInfo = CreateObject("ADSystemInfo")
strUser = objSysInfo.UserName
msgbox(strUser)
Set objUser = GetObject("LDAP://" & strUser)

Il obtient l'utilisateur actuellement connecté. Mais ce que je dois faire maintenant est d'analyser dans le nom de l'utilisateur et de récupérer les détails sur cette base.

J'ai essayé de changer objSysinfo.Nom d'utilisateur le nom d'utilisateur et il est revenu vide.

Set objSysInfo = CreateObject("ADSystemInfo")
strUser = "SomeUserName"
msgbox(strUser)
Set objUser = GetObject("LDAP://" & strUser)

Comment puis-je récupérer les détails de l'ANNONCE de basé sur un nom d'utilisateur fourni?

OriginalL'auteur Bloopie Bloops | 2014-01-14

  1. 14

    Uri LDAP besoin d'un nom unique. Les noms de compte ne fonctionne pas. Si vous souhaitez obtenir des objets utilisateur basée sur le nom du compte que vous avez besoin d'un "régulier" à la requête LDAP:

    username = "SomeUserName"

Set rootDSE = GetObject("LDAP://RootDSE")
base  = "<LDAP://" & rootDSE.Get("defaultNamingContext") & ">"
'filter on user objects with the given account name
fltr  = "(&(objectClass=user)(objectCategory=Person)" & _
        "(sAMAccountName=" & username & "))"
'add other attributes according to your requirements
attr  = "distinguishedName,sAMAccountName"
scope = "subtree"

Set conn = CreateObject("ADODB.Connection")
conn.Provider = "ADsDSOObject"
conn.Open "Active Directory Provider"

Set cmd = CreateObject("ADODB.Command")
Set cmd.ActiveConnection = conn
cmd.CommandText = base & ";" & fltr & ";" & attr & ";" & scope

Set rs = cmd.Execute
Do Until rs.EOF
  WScript.Echo rs.Fields("distinguishedName").Value
  rs.MoveNext
Loop
rs.Close

conn.Close

    Depuis que je suis fâché d'avoir à écrire tout ce que le code réutilisable et plus et plus encore une fois, je l'ai enveloppé dans une classe (ADQuery) il y a quelques temps.

    il fonctionne très bien! Merci beaucoup! Donc, c'est une requête qui récupère de l'ANNONCE de la base de données?
    Correct.
    J'ai récemment trouvé un codeur avec une Github site qui avait une commande pour la construction de fichiers Excel qui contenait VBA. C'était impressionnant. Mon lieu de travail, la sécurité ne me permet pas d'enregistrer votre .vba fichier de mon disque dur ou de le renommer. Est-il une chance que vous pouvez poster votre bibliothèque de Github ou quelque chose de similaire?
    Je vais y réfléchir.

    OriginalL'auteur Ansgar Wiechers

  2. 0

    Juste un commentaire supplémentaire à Ansgar le RootDSE est idéal si vous avez un domaine. Vous pouvez modifier son code de point d'ailleurs où l':

        base  = "<LDAP://" & rootDSE.Get("defaultNamingContext") & ">"

    à quelque chose comme:

        base  = "<LDAP://" & "DC=corp,DC=foo,DC=com" & ">"

    si votre domaine est domaine AD est corp.foo.com

    OriginalL'auteur Michael Berg