Obtenir des valeurs mises en forme à partir d'une plage de cellules

Dim myText As String
myText= Range("a3").Text

Renvoie la valeur mise en forme dans la cellule A3, mais

myText= Range("a3:c7").Text

me donne une erreur.

Comment puis-je obtenir chaînes représentant les valeurs mises en forme à partir d'une plage de cellules, tout en préservant le format de nombre? c'est à dire le format du texte de sortie serait le même que si le copier-coller à partir de la gamme d'un éditeur de texte.

Remarque: vous pouvez soit obtenir le visible formaté résultat dans la cellule à l'aide .De texte, ou vous pouvez obtenir le sous-jacent sans mise en forme de la valeur de la cellule à l'aide .Valeur

OriginalL'auteur Thunder | 2011-04-08

  1. 9

    La seule façon d'obtenir plusieurs valeurs de cellule dans un tableau avec une seule instruction (pas de boucle) est un tableau de type Variant.

    Dim varItemName As Variant
varItemName = Range("a3:c7")

    Si vous avez vraiment besoin absolument les noms de type de String, puis il suffit de CStr plus tard lorsque vous les utilisez. 

    output = FunctionRequiringStringArgument(CStr(varItemName(1,2))

    MODIFIER: Okay, Okay, vous voulez des chaînes de caractères avec le même format que dans la feuille.

    Ici un exemple de travail.

    Dim strMyFormat1 As String
Dim varItemName As Variant
Dim strItemName() As String
Dim strItemNameBF() As String
Dim iCol As Long
Dim iRow As Long
Dim rngMyRange As Range

Set rngMyRange = Range("A3:C7")
varItemName = rngMyRange
ReDim strItemName(LBound(varItemName, 1) To UBound(varItemName, 1), _
    LBound(varItemName, 2) To UBound(varItemName, 2))

'//Take a sample of the format
strMyFormat1 = Range("A3").NumberFormat

'//Apply format sample to all values
For iRow = LBound(varItemName, 1) To UBound(varItemName, 1)
    For iCol = LBound(varItemName, 2) To UBound(varItemName, 2)
        strItemName(iRow, iCol) = Format(varItemName(iRow, iCol), strMyFormat1)
    Next iCol
Next iRow
'//Can also apply to only some values -- adjust loops.
'//More loops go here if many format samples.

'//If all cells have different formats, must use brute force -- slower.
ReDim strItemNameBF(1 To rngMyRange.Rows.Count, _
    1 To rngMyRange.Columns.Count)
For iRow = 1 To rngMyRange.Rows.Count
    For iCol = 1 To rngMyRange.Columns.Count
        strItemNameBF(iRow, iCol) = rngMyRange.Cells(iRow, iCol).Text
    Next iCol
Next iRow
    Le format de la sortie de texte comme par exemple, alors que nous aurions lors de la copie à partir de la plage et de la coller dans un bloc-notes.
    Édité pour répondre à cette. Je suppose que je suis confus par le double "tout".

    OriginalL'auteur Jean-François Corbett

  2. 5
    For Each c In Range("a3:c7")
    ItemName = c.Text
Next c

    Cela vous donnera de chaque cellule, l'un après l'autre.

    Si vous avez un grand ensemble de données, puis en boucle à travers la gamme est incroyablement lent. Mais seulement pour un petit nombre de cellules, il fonctionne. Aussi, en utilisant le .Le texte peut couper certaines de vos informations, car il ne renvoie que ce que voit l'utilisateur.
    J'ai eu une baisse de vote ????? OK, à mon avis, c'est le parfait, Excel construire en solution à visiter, chaque cellule de la plage (par une petite quantité de cellules). À partir de l'OP, je ne sais pas ce qu'il veut faire avec les données. Donc, l'exemple de la question est d'environ 15 cellules ==> la solution parfaite. Je sais qu'il n'est pas rapide à boucle à travers les cellules. Si il y a grande quantité de jeux de données puis de charger les Données dans la mémoire (voir Jean-François Corbetts réponse). Personnellement, je travaille sur mes Données (~ 40000 grands ensembles de données) à l'aide de Perl et de l'utilisation d'Excel uniquement pour l'analyse et la visualisation.

    OriginalL'auteur stema

  3. 5

    Ceci est une version modifiée de l'un de la poster ici, et il a travaillé pour moi.

        Function Range2Text(ByVal my_range As Range) As String
        Dim i As Integer, j As Integer
        Dim v1 As Variant
        Dim Txt As String

        v1 = my_range
        For i = 1 To UBound(v1)
            For j = 1 To UBound(v1, 2)
                Txt = Txt & v1(i, j)
            Next j
            Txt = Txt & vbCrLf
        Next i

        Range2Text = Txt
    End Function

    OriginalL'auteur Deepak Ninnar

  4. 1

    Faire une collection et courir à travers tous les Domaines de la plage et de recueillir le texte dans
    la collecte.

    OriginalL'auteur Friedrich

  5. 1
    dim i as integer, j as integer
Dim v1 as variant

v1=range("a3:c7")

for i=1 to ubound(v1)
  for j=1 to ubound(v1,2)
    debug.print v1(i,j)
  next j
next i
    Cette solution n'inclut pas la mise en forme qui est nécessaire en question. Cet extrait simplement la valeur des cellules.

    OriginalL'auteur Jon49