Obtenir la liste des fichiers Excel dans un dossier à l'aide de VBA

Vous pouvez utiliser le haut-Dir de la fonction ou l'objet FileSystemObject.

• Fonction Dir: VBA: Fonction Dir

• FileSystemObject: VBA: FileSystemObject - les Fichiers de la Collection

Ils ont chacun leurs propres forces et faiblesses.

Fonction Dir

La Fonction Dir est un intégré, léger méthode pour obtenir une liste de fichiers. Les avantages de son utilisation:

• Facile à Utiliser
• De bonnes performances (c'est rapide)
• Soutien joker

Le truc, c'est de comprendre la différence entre un appel avec ou sans paramètre. Voici un exemple très simple à démontrer:

Public Sub ListFilesDir(ByVal sPath As String, Optional ByVal sFilter As String)

    Dim sFile As String

    If Right(sPath, 1) <> "\" Then
        sPath = sPath & "\"
    End If

    If sFilter = "" Then
        sFilter = "*.*"
    End If

    'call with path "initializes" the dir function and returns the first file name
    sFile = Dir(sPath & sFilter)

   'call it again until there are no more files
    Do Until sFile = ""

        Debug.Print sFile

        'subsequent calls without param return next file name
        sFile = Dir

    Loop

End Sub

Si vous modifiez tous les fichiers à l'intérieur de la boucle, vous obtiendrez des résultats imprévisibles. Il est préférable de lire tous les noms dans un tableau de chaînes de caractères avant de faire des opérations sur les fichiers. Voici un exemple qui s'appuie sur la précédente. C'est une Fonction qui retourne un Tableau de chaînes:

Public Function GetFilesDir(ByVal sPath As String, _
    Optional ByVal sFilter As String) As String()

    'dynamic array for names
    Dim aFileNames() As String
    ReDim aFileNames(0)

    Dim sFile As String
    Dim nCounter As Long

    If Right(sPath, 1) <> "\" Then
        sPath = sPath & "\"
    End If

    If sFilter = "" Then
        sFilter = "*.*"
    End If

    'call with path "initializes" the dir function and returns the first file
    sFile = Dir(sPath & sFilter)

    'call it until there is no filename returned
    Do While sFile <> ""

        'store the file name in the array
        aFileNames(nCounter) = sFile

        'subsequent calls without param return next file
        sFile = Dir

        'make sure your array is large enough for another
        nCounter = nCounter + 1
        If nCounter > UBound(aFileNames) Then
            'preserve the values and grow by reasonable amount for performance
            ReDim Preserve aFileNames(UBound(aFileNames) + 255)
        End If

    Loop

    'truncate the array to correct size
    If nCounter < UBound(aFileNames) Then
        ReDim Preserve aFileNames(0 To nCounter - 1)
    End If

    'return the array of file names
    GetFilesDir = aFileNames()

End Function

Objet De Système De Fichiers

L'Objet Système de Fichiers est une bibliothèque pour les opérations d'e /s qui prend en charge un objet-modèle pour la manipulation des fichiers. Pros pour cette approche:

• Intellisense
• Robuste du modèle objet

Vous pouvez ajouter une référence à "Windows Script Host Object Model" (ou "Windows Scripting Runtime") et de déclarer vos objets comme:

Public Sub ListFilesFSO(ByVal sPath As String)

    Dim oFSO As FileSystemObject
    Dim oFolder As Folder
    Dim oFile As File

    Set oFSO = New FileSystemObject
    Set oFolder = oFSO.GetFolder(sPath)
    For Each oFile In oFolder.Files
        Debug.Print oFile.Name
    Next 'oFile

    Set oFile = Nothing
    Set oFolder = Nothing
    Set oFSO = Nothing

End Sub

Si vous ne voulez pas intellisense vous pouvez faire comme si, sans définition d'une référence:

Public Sub ListFilesFSO(ByVal sPath As String)

    Dim oFSO As Object
    Dim oFolder As Object
    Dim oFile As Object

    Set oFSO = CreateObject("Scripting.FileSystemObject")
    Set oFolder = oFSO.GetFolder(sPath)
    For Each oFile In oFolder.Files
        Debug.Print oFile.Name
    Next 'oFile

    Set oFile = Nothing
    Set oFolder = Nothing
    Set oFSO = Nothing

End Sub

Si tout ce que vous voulez, c'est le nom du fichier sans l'extension de fichier

Dim fileNamesCol As New Collection
Dim MyFile As Variant  'Strings and primitive data types aren't allowed with collection

filePath = "c:\file directory" + "\"
MyFile = Dir$(filePath & "*.xlsx")
Do While MyFile <> ""
    fileNamesCol.Add (Replace(MyFile, ".xlsx", ""))
    MyFile = Dir$
Loop

À la sortie de la feuille de calcul excel

Dim myWs As Worksheet: Set myWs = Sheets("SheetNameToDisplayTo")
Dim ic As Integer: ic = 1

For Each MyFile In fileNamesCol
    myWs.Range("A" & ic).Value = fileNamesCol(ic)
    ic = ic + 1
Next MyFile

Principalement basé sur la technique détaillé ici: https://wordmvp.com/FAQs/MacrosVBA/ReadFilesIntoArray.htm