Obtenir le dernier caractère d'une chaîne à partir d'une variable

Je suis d'avoir des problèmes avec un problème réalisé très facilement dans la plupart des langues, mais je n'arrive pas à comprendre dans le lot. Je veux extraire le dernier caractère d'une chaîne. En pseudo-code..

if var1.substring(var1.length, -1) = "0"
  do something

En anglais...si le dernier caractère de la chaîne est 0 alors...

  • pour obtenir de l'aide, tapez help set.
InformationsquelleAutor mgrenier | 2013-03-27
  1. 44
    set var=%var:~-1%

    voir SET /? à partir de l'invite de docco.

    @ECHO OFF
SETLOCAL
SET var=abcd
SET var2=%var:~-1%
CALL :show "-1"
SET var2=%var:~-2%
CALL :show "-2"
SET var2=%var:~-3%
CALL :show "-3"
SET var2=%var:~1%
CALL :show "1"
SET var2=%var:~2%
CALL :show "2"
SET var2=%var:~3%
CALL :show "3"
SET var2=%var:~0,1%
CALL :show "0,1"
SET var2=%var:~0,2%
CALL :show "0,2"
SET var2=%var:~0,3%
CALL :show "0,3"
SET var2=%var:~0,-1%
CALL :show "0,-1"
SET var2=%var:~0,-2%
CALL :show "0,-2"
SET var2=%var:~0,-3%
CALL :show "0,-3"
SET var2=%var:~1,-1%
CALL :show "1,-1"
SET var2=%var:~1,-2%
CALL :show "1,-2"
SET var2=%var:~1,-3%
CALL :show "1,-3"
GOTO :eof

:show
echo Test with "var:~%~1" : var=%var% var2=%var2%
GOTO :eof

    Résultats:

    Test with "var:~-1" : var=abcd var2=d
Test with "var:~-2" : var=abcd var2=cd
Test with "var:~-3" : var=abcd var2=bcd
Test with "var:~1" : var=abcd var2=bcd
Test with "var:~2" : var=abcd var2=cd
Test with "var:~3" : var=abcd var2=d
Test with "var:~0,1" : var=abcd var2=a
Test with "var:~0,2" : var=abcd var2=ab
Test with "var:~0,3" : var=abcd var2=abc
Test with "var:~0,-1" : var=abcd var2=abc
Test with "var:~0,-2" : var=abcd var2=ab
Test with "var:~0,-3" : var=abcd var2=a
Test with "var:~1,-1" : var=abcd var2=bc
Test with "var:~1,-2" : var=abcd var2=b
Test with "var:~1,-3" : var=abcd var2=

    Pour votre IF déclaration, essayez

    IF "%var:~-1%"=="0" (dosomething) else (dosomethingelse)
    • lors de l'utilisation de cette logique-je obtenir tout, mais le premier caractère...c'est à dire avec la valeur "test" est dans la variable elle renvoie "est"
    • désolé de mon erreur, j'ai oublié l' - je viens d'avoir 1...merci pour votre aide!
    • Unknownly vous avez répondu à ma prochaine question, qui étais-je besoin de tous les personnages, MAIS la dernière...merci de poster les exemples et les résultats!! Très utile
    InformationsquelleAutor Magoo
  2. 6

    Lot ne pas utiliser de style C logique, alors vous devez vraiment penser différemment pour beaucoup.

    Cela dit, Corde à droite semble être ce que vous voulez:
    http://www.dostips.com/DtTipsStringManipulation.php#Snippets.RightString

    %str:~-1%

    Que vous obtiendrez le dernier caractère.

    InformationsquelleAutor Austin T French