Open Office Spreadsheet (Calc) - Concatène les cellules de texte avec des délimiteurs

Je suis en utilisant Open Office tableur et suis en train de concaténer plusieurs cellules de texte avec les délimiteurs. Par exemple, supposons que j'ai les cellules ci-dessous:

+--------+
| cell 1 |
+--------+
| cell 2 |
+--------+
| cell 3 |
+--------+
| cell 4 |
+--------+
| cell 5 |
+--------+

Je voudrais concaténer avec des délimiteurs de sorte que le résultat est dans une cellule comme celle-ci:

+----------------------------------------------+
| (cell 1),(cell 2),(cell 3),(cell 4),(cell 5) |
+----------------------------------------------+

Ma première pensée a été d'essayer et de faire une macro ou quelque chose, mais je ne pense pas que open office prend en charge ces. Des idées?

source d'informationauteur Markus O'Reilly

  1. 29

    Merci beaucoup Markus pour trouver une solution à cette question.

    Ici sont quelques-uns un peu plus des instructions détaillées pour le bénéfice de OpenOffice Base débutants comme moi. Cela s'applique à la version 3.1:

    Outils -> les Macros -> gérer les Macros -> OpenOffice.org de Base...

    Maintenant, sélectionnez à partir de l'arborescence de l'explorateur d'où vous voulez que votre fonction live,
    par exemple, il peut être dans votre propre bibliothèque de macro (Mes Macros /Standard) ou
    stockées directement dans la feuille de calcul actuelle.

    Maintenant, entrez un nouveau nom de la Macro et cliquez sur Nouveau pour ouvrir la OO.org IDE de Base. Vous verrez un REM
    déclaration et certains stub Sous des définitions. Supprimer tout ce qui et de le remplacer
    avec:

    Function STRJOIN(range, Optional delimiter As String, Optional before As String, Optional after As String)
    Dim row, col As Integer
    Dim result, cell As String

    result = ""

    If IsMissing(delimiter) Then
        delimiter = ","
    End If
    If IsMissing(before) Then
        before = ""
    End If
    If IsMissing(after) Then
        after = ""
    End If

    If NOT IsMissing(range) Then
        If NOT IsArray(range) Then
            result = before & range & after
        Else
            For row = LBound(range, 1) To UBound(range, 1)
                For col = LBound(range, 2) To UBound(range, 2)
                    cell = range(row, col)
                    If cell <> 0 AND Len(Trim(cell)) <> 0 Then
                        If result <> "" Then
                            result = result & delimiter
                        End If
                        result = result & before & range(row, col) & after
                    End If
                Next
            Next
        End If
    End If

    STRJOIN = result
End Function

    Le code ci-dessus a une légère amélioration de Markus' origine:

    • Ne commence pas par un délimiteur lors de la première cellule de la plage est vide.

    • Permet en option de choix de la délimiteur (par défaut,","), et la
      les chaînes de laquelle aller de l'avant et après chaque non-entrée vide dans la gamme
      (par défaut,"").

    • Je l'ai renommé STRJOIN depuis "join" est le nom classique de cette
      fonction dans plusieurs langues populaires, tels que Perl, Python et Ruby.

    • Variables en minuscules

    Maintenant enregistrer la macro, aller à la cellule où vous souhaitez le rejoindre à apparaître,
    et type:

      =STRJOIN(C3:C50)

    remplacement C3:C50 avec la gamme de chaînes que vous voulez joindre.

    Pour personnaliser le délimiteur, au lieu d'utiliser quelque chose comme:

      =STRJOIN(C3:C50; " /")

    Si vous voulais me joindre un tas d'adresses e-mail, vous pouvez utiliser:

      =STRJOIN(C3:C50; ", "; "<"; ">")

    et le résultat serait quelque chose comme

    <[email protected]>, <[email protected]>, <[email protected]>, <[email protected]>
  2. 8

    Bien, après beaucoup plus de recherche et d'expérimentation, j'ai trouvé que vous pouvez faire votre propre dans calc. C'est une fonction que j'ai faite c'est ce que je veux:

    Function STRCONCAT(range)
    Dim Row, Col As Integer
    Dim Result As String
    Dim Temp As String

    Result = ""
    Temp = ""

    If NOT IsMissing(range) Then
        If NOT IsArray(range) Then
            Result = "(" & range & ")"
        Else
            For Row = LBound(range, 1) To UBound(range, 1)
                For Col = LBound(range, 2) To UBound(range, 2)
                    Temp = range(Row, Col)
                    Temp = Trim(Temp)
                    If range(Row, Col) <> 0 AND Len(Temp) <> 0 Then
                        If(NOT (Row = 1 AND Col = 1)) Then Result = Result & ", "
                        Result = Result & "(" & range(Row, Col) & ") "
                    End If
                Next
            Next
        End If
    End If

    STRCONCAT = Result
End Function
  3. 1

    Jamais donc je serais souvent profiter de la facilité et de la rapidité de remplacer & Options de calcul ainsi que, en général, la manipulation rapide & modifiant les Options, quand une fois de plus assis en face d'un dumping-fichier-listes ou que ce soit.

    Je n'ai jamais compris pourquoi ils n'ont pas une telle fonction essentielle dès le début, vraiment.

    Il est basé sur Adam script, mais avec l'extension de swap CONCAT la verticale à l'horizontale, tout en gardant les délimiteurs dans l'ordre.

    Function CONCAT2D(Optional range,   Optional delx As String, Optional dely As String, _
                                    Optional xcell As String, Optional cellx As String, _
                                    Optional swop As Integer)
    Dim xy(1), xyi(1), s(1) As Integer
    Dim out, cell, del, dxy(1) As String

    'ReDim range(2, 1)           'Gen.RandomMatrix 4 Debugging
    'For i = LBound(range, 1) To UBound(range, 1)
    '   For j = LBound(range, 2) To UBound(range, 2)
    '       Randomize
    '       range(i,j) = Int((100 * Rnd) )
    '   Next
    'Next

    out  = ""
    If IsMissing(delx)  Then : delx  = ","      : End If
    If IsMissing(dely)  Then : dely  = delx()   : End If
    If IsMissing(xcell) Then : xcell = ""       : End If
    If IsMissing(cellx) Then : cellx = xcell()  : End If
    If IsMissing(swop)  Then : swop  = 0        : End If
    dxy(0) = delx() : dxy(1) = dely()
    xyi(0) = 1      : xyi(1) = 2
    If swop = 0     Then :  s(0) = 0 : s(1) = 1
                    Else    s(0) = 1 : s(1) = 0 : End If

    If NOT IsMissing(range) Then
        If   NOT IsArray(range) _
        Then :  out = xcell & range & cellx
        Else    del = delx
                For xy(s(0)) = LBound(range, xyi(s(0))) To UBound(range, xyi(s(0))
                For xy(s(1)) = LBound(range, xyi(s(1))) To UBound(range, xyi(s(1))
                    cell = range(xy(0), xy(1))
                    If cell <> 0 AND Len(Trim(cell)) <> 0 _
                    Then :  If out <> "" Then : out = out & del : End If
                            out = out & xcell & cell & cellx
                            del = dxy(s(0))
                    End If
                Next :      del = dxy(s(1))
                Next
        End If
    Else        out = "ERR"
    End If

    CONCAT2D = out
End Function