Oracle CLAUSE De question lors de l'utilisation avec plusieurs valeurs, le rendant dynamique

Je viens de passer une heure sur google et ici, en essayant d'obtenir une réponse claire de la façon de faire dans Oracle. Ce dont j'ai besoin est la capacité à utiliser sélectionnez dans la clause qui construit automatiquement comme

select col1 from table1 where id.table IN ('1','2','3');

où les valeurs d'id sont transmis à la procédure stockée à l'intérieur du tableau. Le tableau associatif a été définie comme suit:

 TYPE varchar_array_type IS TABLE OF VARCHAR2 (40)      INDEX BY BINARY_INTEGER;

Est-il simple, de béton moyen de le faire? grâce

OriginalL'auteur sarsnake | 2010-12-15

  1. 5

    Malheureusement, si votre type de collection est définie en PL/SQL (plutôt que SQL), vous ne pouvez pas l'utiliser dans SQL, car le moteur SQL ne sais pas comment le gérer.

    Si au contraire vous avez défini le type de collection en SQL, c'est à dire

    CREATE TYPE varchar_tbl
    IS TABLE OF varchar2(40);

    Ensuite, vous pouvez faire quelque chose comme

    SELECT col1
  FROM table1 t1
 WHERE t1.id IN (SELECT column_value
                   FROM TABLE( <<variable of type varchar2_tbl>> ) )

    en fonction de la version Oracle-- la syntaxe d'utilisation de collections dans SQL a évolué au fil du temps-les anciennes versions de Oracle avait plus d'une syntaxe complexe.

    Vous pouvez convertir un PL/SQL tableau associatif (votre VARCHAR_ARRAY_TYPE) à un SQL de la table imbriquée collection en PL/SQL, mais qui nécessite une itération dans le tableau associatif et le remplissage de la table imbriquée, ce qui est un peu de douleur. En supposant que le VARCHAR_TBL table imbriquée de la collection a déjà été créé

    SQL> CREATE OR REPLACE TYPE varchar_tbl
         IS TABLE OF varchar2(40);

    vous pouvez convertir le tableau associatif à la table imbriquée et utiliser une table imbriquée dans une instruction SQL comme ceci (à l'aide de la SCOTT.Table EMP)

    declare
  type varchar_array_type
    is table of varchar2(40)
       index by binary_integer;
  l_associative_array varchar_array_type;
  l_index             binary_integer;
  l_nested_table      varchar_tbl := new varchar_tbl();
  l_cnt               pls_integer;
begin
  l_associative_array( 1 ) := 'FORD';
  l_associative_array( 10 ) := 'JONES';
  l_associative_array( 100 ) := 'NOT A NAME';
  l_associative_array( 75 ) := 'SCOTT';
  l_index := l_associative_array.FIRST;
  while( l_index IS NOT NULL )
  loop
    l_nested_table.EXTEND;
    l_nested_table( l_nested_table.LAST ) :=
             l_associative_array( l_index );
    l_index := l_associative_array.NEXT( l_index );
  end loop;
  SELECT COUNT(*)
    INTO l_cnt
    FROM emp
   WHERE ename IN (SELECT column_value
                     FROM TABLE( l_nested_table ) );
  dbms_output.put_line( 'There are ' || l_cnt || ' employees with a matching name' );
end;

    En raison de la conversion entre les types de collection est un peu de douleur, cependant, vous seriez généralement préférable d'utiliser simplement la table imbriquée collection (et en passant, que pour la procédure stockée) sauf s'il y a une raison particulière pour que le tableau associatif est nécessaire.

    merci, c'est la partie facile. comment puis-je jeter mon tableau de valeurs dans varchar_tbl? J'ai essayé quelques choses, tout en me donnant des erreurs. Ce devrait être facile, mais pour une raison quelconque est terrible et maladroit. Ugh.
    nous avons Oracle 11g
    aussi, veuillez expliquer ce que vous entendez par "si votre type de collection est définie en PL/SQL (plutôt que SQL), vous ne pouvez pas l'utiliser dans SQL". Tout ce que nous faisons est à l'intérieur de procédures stockées. Veuillez garder cela à l'esprit, merci.
    Posté un exemple de conversion entre les types de collection. Vous pouvez utiliser les types de collection défini dans SQL (c'est à dire CRÉER TYPE) en SQL et PL/SQL depuis PL/SQL est construit sur le haut de SQL. Vous pouvez utiliser uniquement les types de collection défini dans PL/SQL PL/SQL-- vous ne pouvez pas utiliser ces types de données dans SQL.
    merci pour votre code. Mais toujours pas l'aider. Comment puis-je créer une table temporaire à l'INTÉRIEUR de ma procédure stockée(ou plutôt de DÉFINIR la table temporaire type)? Est-ce possible? Ou dois-je le faire par le biais de l'invite SQL. merci encore. Je ne peux pas juste de créer facilement de la table temporaire dans ma procédure stockée???

    OriginalL'auteur Justin Cave