Ouvrir un fichier Excel à partir d'un site SharePoint

J'essaie d'ouvrir un fichier Excel à partir de SharePoint à l'aide de VBA. Parce que le fichier que je suis à la recherche pourrait être différente à chaque fois que je lance la macro, je veux être en mesure d'afficher le dossier SharePoint et sélectionnez le fichier dont j'ai besoin.

Le code ci-dessous fonctionne très bien quand je veux chercher un fichier sur un lecteur réseau, mais quand je la remplacer avec un SharePoint adresse j'obtiens "erreur d'exécution 76: Chemin d'accès introuvable".

Sub Update_monthly_summary()

Dim SummaryWB As Workbook
Dim SummaryFileName As Variant

ChDir  "http://sharepoint/my/file/path"
SummaryFileName = Application.GetOpenFilename("Excel-files,*.xls", _
1, "Select monthly summary file", , False)
If SummaryFileName = False Then Exit Sub

Set SummaryWB = Workbooks.Open(SummaryFileName)

End Sub

Quand je colle cette adresse dans l'Explorateur Windows je n'ai pas de problèmes d'accès au dossier SharePoint, donc je sais que le chemin est correct.

Pourquoi ne pas VBA?

ChDir() et GetOpenFilename ne fonctionnent pas sur http, mais vous pouvez essayer en utilisant sharepoint "webdav" chemin d'accès au lieu de le http route.
Vous devez utiliser une adresse WebDAV pour lier le fichier Excel va la considérer comme un emplacement réseau. Voir ma réponse ci-dessous pour une fonction qui analyse les Url dans WebDAV adresses pour vous.

OriginalL'auteur Pocahontas | 2013-10-21

Essayer ce code pour récupérer un fichier à partir d'un site SharePoint:

Dim SummaryWB As Workbook
Dim vrtSelectedItem As Variant

With Application.FileDialog(msoFileDialogOpen)
    .InitialFileName = "https://sharepoint.com/team/folder" & "\"
    .AllowMultiSelect = False
    .Show
    For Each vrtSelectedItem In .SelectedItems
        Set SummaryWB = Workbooks.Open(vrtSelectedItem)
    Next
End With

If SummaryWB Is Nothing then Exit Sub

Si je me souviens bien, le Microsoft Scripting Runtime de référence doit être activé. Aussi, votre site peut utiliser des barres obliques inverses, la mine utilise des barres obliques.

OriginalL'auteur ARich

- Je convertir les URL en adresse WebDAV en utilisant la fonction suivante que j'ai créé. Cette fonction retourne également un système régulier des sentiers et des chemins UNC indemne.

Appeler cette fonction en l'ajoutant dans un module dans votre projet VBA et en entrant MyNewPathString = Parse_Resource(myFileDialogStringVariable) juste après votre boîte de dialogue de fichier de commande et avant l'utilisation de la voie choisie par la boîte de dialogue de fichier. Puis de référence "MyNewPathString" lors de l'utilisation de la cible de l'emplacement du fichier.

 Public Function Parse_Resource(URL As String)
'Uncomment the below line to test locally without calling the function & remove argument above
'Dim URL As String
Dim SplitURL() As String
Dim i As Integer
Dim WebDAVURI As String
'Check for a double forward slash in the resource path. This will indicate a URL
If Not InStr(1, URL, "//", vbBinaryCompare) = 0 Then
'Split the URL into an array so it can be analyzed & reused
SplitURL = Split(URL, "/", , vbBinaryCompare)
'URL has been found so prep the WebDAVURI string
WebDAVURI = "\\"
'Check if the URL is secure
If SplitURL(0) = "https:" Then
'The code iterates through the array excluding unneeded components of the URL
For i = 0 To UBound(SplitURL)
If Not SplitURL(i) = "" Then
Select Case i
Case 0
'Do nothing because we do not need the HTTPS element
Case 1
'Do nothing because this array slot is empty
Case 2
'This should be the root URL of the site. Add @ssl to the WebDAVURI
WebDAVURI = WebDAVURI & SplitURL(i) & "@ssl"
Case Else
'Append URI components and build string
WebDAVURI = WebDAVURI & "\" & SplitURL(i)
End Select
End If
Next i
Else
'URL is not secure
For i = 0 To UBound(SplitURL)
'The code iterates through the array excluding unneeded components of the URL
If Not SplitURL(i) = "" Then
Select Case i
Case 0
'Do nothing because we do not need the HTTPS element
Case 1
'Do nothing because this array slot is empty
Case 2
'This should be the root URL of the site. Does not require an additional slash
WebDAVURI = WebDAVURI & SplitURL(i)
Case Else
'Append URI components and build string
WebDAVURI = WebDAVURI & "\" & SplitURL(i)
End Select
End If
Next i
End If
'Set the Parse_Resource value to WebDAVURI
Parse_Resource = WebDAVURI
Else
'There was no double forward slash so return system path as is
Parse_Resource = URL
End If
End Function

Cette fonction permet de vérifier si votre chemin d'accès au fichier est une URL et si elle est sécurisée (HTTPS) ou non sécurisé (HTTP). Si c'est une URL, alors il sera de construire approprié WebDAV chaîne de sorte que vous pouvez lien direct vers le fichier cible dans SharePoint.

L'utilisateur sera susceptible de être invité pour les informations d'identification chaque fois que le fichier est ouvert en particulier si elles ne sont pas assis sur le même domaine que votre batterie de serveurs SharePoint.

VEUILLEZ NOTER: je n'ai pas testé avec un site http, cependant, je suis certain que cela va fonctionner.

Aussi, cette réponse ne fonctionne pas dans Windows XP, car Windows XP ne prend pas en charge le protocole WebDAV. Donc Win 7 et versions plus récentes uniquement.
C'est très utile!
Content que ça a aidé!

OriginalL'auteur Shrout1

1

De vous un script pour ne pas utiliser http://sharepoint/my/file tant que chemin d'accès, mais plutôt
\\sharepoint\my\file puis est devrait fonctionner. Il fonctionne fo mes programmes en C#.

OriginalL'auteur Jacek
1

Veuillez noter qu'il y est une faute de frappe dans votre code initial
```
MyNewPathString = ParseResource(myFileDialogStringVariable)
```
doit être remplacé par
```
MyNewPathString = Parse_Resource(myFileDialogStringVariable)
```
Le trait de soulignement manquait.

Merci pour la mention de cette! N'oubliez pas de laisser des commentaires et des observations et non des réponses 🙂 j'ai corrigé ça dans ma réponse initiale.

OriginalL'auteur Ed van Harmelen
0

Vous pouvez utiliser mon approche de la map SharePoint dossier sur les lecteurs réseau. Ensuite, vous pouvez procéder comme vous l'avez fait jusqu'à présent.

Excel VBA Téléchargement à partir de plusieurs dossiers SharePoint

Alors vous pouvez aussi naviguer à travers les fichiers avec Dir ou un Objet de Système de Fichiers

OriginalL'auteur psychicebola

-1

Essayer quelque chose comme cela:

Shell ("C:\Program Files\Internet Explorer\iexplore.exe http://sharepoint/my/file/path")

Il a travaillé pour moi.

OriginalL'auteur Steve

Vous devez vous connecter pour publier un commentaire.