Pas de max(x,y) de la fonction dans l'Accès

VBA pour Access ne dispose pas d'un simple Max(x,y) fonction pour trouver la mathématique maximum de deux valeurs ou plus. Je suis habitué à avoir une fonction déjà dans l'API de base en provenance d'autres langages tels que perl/php/ruby/python etc.

Je sais qu'il peut être fait: IIf(x > y, x,y). Existe-il d'autres solutions?

Vous pouvez utiliser les fonctions Excel dans Access. (Plus ci-dessous.)

OriginalL'auteur DGM | 2009-08-31

7

Je vais interpréter la question à lire:

Comment implémenter une fonction dans l'Accès qui retourne la valeur Max/Min d'un tableau de nombres? Voici le code que j'utilise (nommé "iMax", par analogie avec l'IIf, c'est à dire, "Si"/"Max"):
```
  Public Function iMax(ParamArray p()) As Variant
  ' Idea from Trevor Best in Usenet MessageID [email protected]
    Dim i As Long
    Dim v As Variant

    v = p(LBound(p))
    For i = LBound(p) + 1 To UBound(p)
      If v < p(i) Then
         v = p(i)
      End If
    Next
    iMax = v
  End Function

  Public Function iMin(ParamArray p()) As Variant
  ' Idea from Trevor Best in Usenet MessageID [email protected]
    Dim i As Long
    Dim v As Variant

    v = p(LBound(p))
    For i = LBound(p) + 1 To UBound(p)
      If v > p(i) Then
         v = p(i)
      End If
    Next
    iMin = v
  End Function
```
Pourquoi l'Accès ne serait pas la mettre en œuvre, ce n'est pas quelque chose de très commun de besoin, me semble. Ce n'est pas très "databasy", soit. Vous avez déjà toutes les fonctions dont vous avez besoin pour trouver des Max/Min à travers le domaine et dans les ensembles de lignes. Il n'est également pas très difficile à mettre en œuvre, ou simplement le code à titre de comparaison, quand vous en avez besoin.

Peut-être les aider quelqu'un.

C'est plus utile que vers la voix d'un an après la question. 🙂
Je suis surpris qu'il n'a pas obtenir une réponse plus rapidement, compte tenu de la façon triviale du problème. C'est peut-être parce que la question a été conflictuel (c'est à dire, de dénigrer l'Accès), de sorte que les gens qui connaissaient la réponse était trop désactivé afin d'essayer d'aider quelqu'un qui semble avoir quelque chose d'une puce sur son épaule.
Vous FAIRE comprendre pourquoi une base de données outil de développement n'aurait pas une fonction intégrée, droit? Il y a beaucoup plus d'omissions qui sont liés aux bases de données qu'une fonction de ce genre.
Quelqu'un peut-il m'indiquer un plus solution commune qui prend comme arguments de fonction non seulement de tableau de nombres, mais les tableaux et les collections?

OriginalL'auteur David-W-Fenton

Appelant Excel VBA Fonctions à partir de MS Access VBA

Si vous ajouter une référence à Excel (Tools → References → Microsoft Excel x.xx Object Library) alors vous pouvez utiliser WorksheetFunction à l'appel de la plupart des fonctions de feuille de calcul Excel, y compris MAX (qui peut également être utilisé sur les tableaux).

Exemples:

MsgBox WorksheetFunction.Max(42, 1999, 888)

ou,

Dim arr(1 To 3) As Long
arr(1) = 42
arr(2) = 1999
arr(3) = 888
MsgBox WorksheetFunction.Max(arr)

Le premier appel prend une seconde à répondre (en fait 1.1 sec pour moi), mais les appels suivants sont beaucoup plus raisonnable (<0.002 sec de chaque pour moi).

Se référant à Excel comme un objet

Si vous utilisez beaucoup de fonctions d'Excel dans votre procédure, vous pouvez être en mesure d'améliorer encore plus les performances à l'aide d'un Application objet à renvoyer directement à Excel.

Par exemple, cette procédure est itérée un ensemble d'enregistrements à plusieurs reprises à l'aide d'Excel MAX sur un Tableau d'Octets afin de déterminer le plus "haut" de caractères ASCII de chaque enregistrement.

Option Compare Text
Option Explicit
'requires reference to "Microsoft Excel x.xx Object Library"
Public excel As New excel.Application 

Sub demo_ListMaxChars()
    'list the character with the highest ASCII code for each of the first 100 records
    Dim rs As Recordset, mx
    Set rs = CurrentDb.OpenRecordset("select myField from tblMyTable")
    With rs
        .MoveFirst
            Do
                mx = maxChar(!myField)
                Debug.Print !myField, mx & "(" & ChrW(mx) & ")"  '(Hit CTRL+G to view)
                .MoveNext
            Loop Until .EOF
        .Close
    End With
    Set rs = Nothing     'always clean up your objects when finished with them!
    Set excel = Nothing  
End Sub

Function maxChar(st As String)
    Dim b() As Byte                             'declare Byte Array
    ReDim b(1 To Len(st))                       'resize Byte Array
    b = StrConv(st, vbFromUnicode)              'convert String to Bytes
    maxChar = excel.WorksheetFunction.Max(b)    'find maximum Byte (with Excel function)
End Function

OriginalL'auteur ashleedawg

1

Car ils ont probablement pensé que vous pouvez utiliser DMAX et DMIN ou sql MAX et travaillant uniquement avec la base de données dans access?

Je suis également curieux de savoir pourquoi.. Sa semble exagéré pour créer un temp-table et ajouter les valeurs d'un formulaire pour la table, puis exécutez une DMAX ou MAX-requête sur la table pour obtenir le résultat...

ouais, et les valeurs que je suis en utilisant la base de données, mais dans les deux colonnes de la même ligne. Ce n'est pas un agrégat Max, mais une mathématique simple Max.

OriginalL'auteur Stefan
1

J'ai été connu pour créer un petit projMax() fonction pour traiter ces. Non pas que VBA sera probablement toujours être améliorée, mais seulement dans le cas où elles ne ajouter un Max (et Min) de la fonction, il n'entre pas en conflit avec mes fonctions. BTW, l'affiche originale suggère de le faire IIF... Qui fonctionne, mais dans ma fonction, j'ai l'habitude de jeter un couple de néo-Zélandais()'pour éviter un nul de ruiner la fonction.

OriginalL'auteur Knox
1

J'ai aimé DGM de l'utilisation de l'instruction IIF et David utilisation de la/la boucle Suivante, je suis donc de les combiner ensemble.

Parce que VBA dans access n'a pas une stricte vérification de type, je vais être en utilisant des variantes de préserver tous les nombres entiers et décimaux, et re-type de la valeur de retour.

Bravo à HansUP pour attraper mon paramètre de vérification 🙂

Commentaires ajoutés afin de rendre le code plus convivial.
```
Option Compare Database
Option Base 0
Option Explicit

Function f_var_Min(ParamArray NumericItems()) As Variant
If UBound(NumericItems) = -1 Then Exit Function ' No parameters
Dim vVal As Variant, vNumeric As Variant
vVal = NumericItems(0)
For Each vNumeric In NumericItems
    vVal = IIf(vNumeric < vVal, vNumeric, vVal) ' Keep smaller of 2 values
Next
f_var_Min = vVal ' Return final value
End Function

Function f_var_Max(ParamArray NumericItems()) As Variant
If UBound(NumericItems) = -1 Then Exit Function ' No parameters
Dim vVal As Variant, vNumeric As Variant
vVal = NumericItems(0)
For Each vNumeric In NumericItems
    vVal = IIf(vNumeric < vVal, vVal, vNumeric) ' Keep larger of 2 values
Next
f_var_Max = vVal ' Return final value
End Function
```
La seule différence entre les 2 fonctions est de l'ordre de vVal et vNumeric dans l'instruction IIF.
Pour chaque clause utilise en interne le VBA logique pour gérer la boucle de la matrice et de la vérification de limites, alors que de Base "0" commence à l'index du tableau à 0.

IsNull(NumericItems) ne sera jamais True. Si vous quittez la fonction lorsqu'elle est appelée sans arguments, essayez de vérifier pour UBound(NumericItems) = -1
Bon oeil, utilisé vos suggestions sur un échantillon de données et il a travaillé comme annoncée, keep it up!

OriginalL'auteur CoveGeek

Les deux fonctions ont des problèmes avec la valeur Null. Je pense que ce sera mieux.

Public Function iMin(ParamArray p()) As Variant
  Dim vVal As Variant, vMinVal As Variant

  vMinVal = Null
  For Each vVal In p
    If Not IsNull(vVal) And (IsNull(vMinVal) Or (vVal < vMinVal)) Then _
      vMinVal = vVal
  Next

  iMin = vMinVal
End Function

OriginalL'auteur The Unknown

-1

Vous pouvez faire Worksheetfunction.max() ou worksheetfunction.min() dans Access VBA. Espérons que cette aide.

Un peu plus d'informations serait utile, puisque cela ne peut pas être utilisé comme tel. (J'ai développé sur ce ci-dessous.)

OriginalL'auteur Joe D.

Vous devez vous connecter pour publier un commentaire.