Passage de paramètres à partir de vbscript pour fichier batch

Salut, je vais avoir un problème de passage de paramètres par le biais d'un vbscript pour un fichier de commandes.
Je ne suis pas très bon en programmation donc je suis sûr que j'en manque juste quelque chose de stupide.
De toute façon je suis à l'aide de vbscript pour, de manière invisible, exécutez le fichier de commandes

Le vbscript est appelé comme "C:\Program Files (x86)\scripts\check.vbs" %S "%D"

Où %S est dans l'état et %D est un répertoire.

Si j'appelle directement le fichier de commandes que "C:\Program Files (x86)\scripts\checkdir.bat" %S "%D" tout fonctionne bien sauf il y a un dos de windows qui s'affiche, ce qui est gênant.

Alors, j'ai cherché sur internet et trouvé ce vbscript qui peut exécuter un fichier de commandes en mode silencieux. Il ne fait exécuter en mode silencieux toutefois, il ne passe pas les paramètres pour le fichier de commandes.

Voici le vbscript:

Set WshShell = CreateObject("WScript.Shell") 
WshShell.Run chr(34) & "C:\Program Files (x86)\scripts\checkdir.bat" & Chr(34), 0
Set WshShell = Nothing

Comment puis-je passer les paramètres? J'ai cherché mais je ne pouvais pas trouver quelque chose qui a fonctionné pour moi, je voudrais obtenir une erreur de fonctionnement ou les paramètres ne serait pas passer.

InformationsquelleAutor user2411206 | 2013-05-23
  1. 4

    En supposant que vous appelez le VBScript dans cette voie...

    wscript myscript.vbs ArgumentS ArgumentD

    Puis remplacement de la ligne 2 pour cela devrait fonctionner...

    WshShell.Run """C:\Program Files (x86)\scripts\checkdir.bat"" " & WScript.Arguments.Item(0) & " """ & WScript.Arguments.Item(1) & """", 0

    Remarque que je suis en supposant que vous avez besoin de passer l'Argument D avec des guillemets doubles autour de sorte que j'ai inclus ces. À l'intérieur d'une chaîne de VBScript remplacera double-guillemets doubles avec des guillemets. Si cela ne fonctionne pas, changer WshShell.Exécuter à wscript.echo et vous devriez voir exactement ce que VBScript est d'essayer de passer. Si ce n'est pas tout à fait à droite, réglez-la et essayez à nouveau avec WshShell.Exécutez.

    Bonne chance.

    • Merci beaucoup cela a parfaitement fonctionné.
    InformationsquelleAutor NYCdotNet
  2. 1

    Vous avez besoin de moins de chance, si vous abordez le problème de la construction complexe de la ligne de commande dans un recours plus systématique à la mode:

    checkdir.chauve-souris:

    @echo off
echo '%1' '%2' > checkdir.log

    vérifier.vbs:

    Option Explicit

Dim oFS  : Set oFS  = CreateObject("Scripting.FileSystemObject")
Dim oWAU : Set oWAU = WScript.Arguments.Unnamed
Dim oWS : Set oWS = CreateObject("WScript.Shell")

Dim S : S = "state"
If oWAU.Count >= 1 Then S = oWAU(0)
Dim D : D = "directory"
If oWAU.Count >= 2 Then D = oWAU(1)

Dim sBFspec : sBFSpec = oFS.GetAbsolutePathName(".\checkdir.bat")

' One way of building a command from parts that need quoting
' Replacing placeholders in a template is another one
' Everything is better than concatenating, cf:
' """C:\Program Files (x86)\scripts\checkdir.bat"" " & WScript.Arguments.Item(0) & " """ & WScript.Arguments.Item(1) & """", 0
Dim sCmd    : sCmd    = Join(Array( _
      qq(sBFSpec) _
    , qq(S) _
    , qq(D) _
))

' sanity check
WScript.Echo "About to call:"
WScript.Echo sCmd
WScript.Echo "Your last chance to check!"

Dim iRet : iRet = oWS.Run(sCmd, 0, True)
If 0 = iRet Then
   WScript.Echo "looks ok:"
   WScript.Echo oFS.OpenTextFile(".\checkdir.log").ReadAll()
Else
   WScript.Echo "looks bad:", iRet
End If

WScript.Quit 0

Function qq(s) : qq = """" & s & """" : End Function

    De sortie:

    cscript check.vbs
About to call:
"E:\trials\SoTrials\answers722567\vbs\checkdir.bat" "state" "directory"
Your last chance to check!
looks ok:
'"state"' '"directory"'

cscript check.vbs "i don't care" "c:\ \ \simsalabim"
About to call:
"E:\trials\SoTrials\answers722567\vbs\checkdir.bat" "i don't care" "c:\ \ \simsalabim"
Your last chance to check!
looks ok:
'"i don't care"' '"c:\ \ \simsalabim"'

    ou:

    checkdir.bat "i don't care" "c:\ \ \simsalabim"

type  checkdir.log
'"i don't care"' '"c:\ \ \simsalabim"'

    (La préservation de la " citations est venu comme une surprise pour moi)

    • Merci ce n'est pas pour résoudre mon problème, mais a été un bon exercice d'apprentissage.
    InformationsquelleAutor Ekkehard.Horner