Passage de variable de la Forme au Module VBA

J'ai le bouton suivant dans un Formulaire:

Private Sub CommandButton1_Click()
 Dim pass As String
 pass = UserForm1.TextBox1
 Unload UserForm1
End Sub

J'ai alors d'un Module Module1:

 Public Sub Login()

 ...

 UserForm1.Show
 driver.findElementByName("PASSWORD").SendKeys pass

 ...

End Sub

L'idée est le mot de passe que l'utilisateur entre dans la zone de saisie sera affectée à la variable pass. Ce que je vais avoir du mal à faire, cependant, est de passage pass de UserForm1 dans Module1 de Connexion sub.

Je voudrais de la pensée en ajoutant quelque chose comme Module1.Login (pass) de mon formulaire avant de me décharger, il serait, cependant ça ne semble pas passer n'importe quoi. Toute aide serait grandement appréciée. Merci.

InformationsquelleAutor JimmyK | 2013-11-26

31

Ne pas déclarer la variable dans l'objet userform. Déclarer comme Public dans le module.
```
Public pass As String
```
Dans le Userform
```
Private Sub CommandButton1_Click()
    pass = UserForm1.TextBox1
    Unload UserForm1
End Sub
```
Dans le Module
```
Public pass As String

Public Sub Login()
    '
    '~~> Rest of the code
    '
    UserForm1.Show
    driver.findElementByName("PASSWORD").SendKeys pass
    '
    '~~> Rest of the code
    '
End Sub
```
Vous pouvez aussi ajouter un contrôle supplémentaire juste avant l'appel de la driver.find... ligne?
```
If Len(Trim(pass)) <> 0 Then
```
Cela permettra d'assurer qu'une chaîne vide n'est pas passé.
- +1 Sid c'est un bon moyen de le faire. Sinon, vous pouvez masquer le Userform1 au lieu de déchargement et de l'accès à l'UserForm1.TextBox1 à partir du module puis de Décharger userform1 mais la décision sur l'approche dépend de l'ensemble de la mise en œuvre
- Ahah, je n'ai jamais pensé à déclarer la variable comme Public. C'est une très bonne astuce que je vais devoir commencer à faire plus, merci!!!!
- Le mieux pour décharger le formulaire une fois que vous avez terminé avec elle. Mieux pour la mémoire et la sécurité.
- seulement parce que vous travaillez avec la forme de l'instance par défaut. Traiter des formulaires comme les objets qu'elles sont plutôt que comme global de l'état de l'INTERFACE utilisateur, et à la fois de la "mémoire" et de "sécurité" arguments ne pas en avoir plus.
InformationsquelleAutor Siddharth Rout
21

Siddharth la réponse, c'est sympa, mais s'appuie sur l'échelle mondiale de portée des variables. Il y a de mieux, de plus OOP de manière conviviale.

Un objet UserForm est un module de classe comme les autres - la seule différence, c'est qu'il a caché VB_PredeclaredId attribut True, ce qui rend VB créer un champ d'application mondial variable objet nommé d'après la classe - c'est comment vous pouvez écrire UserForm1.Show sans la création d'une nouvelle instance de la classe.

Pas loin de cette réalité et de traiter votre formulaire comme un objet au lieu - exposer Property Get membres et de l'abstraction de la forme de contrôles, le code d'appel ne se soucie pas contrôles de toute façon:
```
Option Explicit
Private cancelling As Boolean

Public Property Get UserId() As String
    UserId = txtUserId.Text
End Property

Public Property Get Password() As String
    Password = txtPassword.Text
End Property

Public Property Get IsCancelled() As Boolean
    IsCancelled = cancelling
End Property

Private Sub OkButton_Click()
    Me.Hide
End Sub

Private Sub CancelButton_Click()
    cancelling = True
    Me.Hide
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    If CloseMode = VbQueryClose.vbFormControlMenu Then
        cancelling = True
        Me.Hide
    End If
End Sub
```
Maintenant le code appelant peut le faire (en supposant que l'objet UserForm a été nommé LoginPrompt):
```
With New LoginPrompt
    .Show vbModal
    If .IsCancelled Then Exit Sub
    DoSomething .UserId, .Password
End With
```
Où DoSomething serait une procédure qui exige que les deux paramètres de la chaîne:
```
Private Sub DoSomething(ByVal uid As String, ByVal pwd As String)
    'work with the parameter values, regardless of where they came from
End Sub
```
- le retour est toujours apprécié; je suis toujours ouvert à de nouvelles façons d'améliorer mes réponses. Droit maintenant, je suis un peu perplexe sur ce qui est mal à éviter de l'état global et de renforcer le code de l'expressivité et de la robustesse par une simple abstraction. Des acclamations.
- J'aime cette approche de la séparation de la forme à partir des données et des méthodes. Comment aurais-je l'appliquer dans un chemin où l'objet userform peut rester visible. En utilisant l'exemple ci-dessus, dire l'ID ou le mot de passe de revenir incorrect, pourrait le formulaire de rester ouvert et de donner un avertissement?
- dans ce cas, vous devrez déclarer un événement dans la vue/le formulaire, et de le gérer dans le présentateur (qui doit être un module de classe, avec un WithEvents déclaration de la vue/forme). Un peu comme "Appliquer" logique pour UserForm boîte de dialogue
- merci beaucoup pour l'information, je suis en train de lire à travers le site et le pratique maintenant avec mon propre code. Pour information, le lien de téléchargement ne fonctionne plus sur ce site. Merci encore!
- fonctionne pour moi - un peu - ne m'attendais pas à dropbox pour juste bizarrement prévisualiser le fichier directement dans le navigateur... une fois que vous êtes sur dropbox il y a un bouton de téléchargement dans le coin en haut à droite. Assurez-vous de vérifier Rubberduck pendant que vous y êtes! (et star-nous sur GitHub!)
InformationsquelleAutor Mathieu Guindon

Vous devez vous connecter pour publier un commentaire.