Perl - Démarrer la lecture à partir de la ligne spécifique, et la première colonne de la ligne, jusqu'à la fin

J'ai un fichier texte qui se présente comme suit:

Line 1
Line 2
Line 3
Line 4
Line 5
filename2.tif;Smpl/Pix & Bits/Smpl are missing.

Il y a 5 lignes qui sont toujours les mêmes, et sur la ligne 6 est où je veux commencer la lecture des données. Lors de la lecture des données, chaque ligne (à partir de la ligne 6) est délimitée par des points-virgules. J'ai besoin pour obtenir juste la première entrée de chaque ligne (en commençant à la ligne 6).

Par exemple:

Line 1
Line 2
Line 3
Line 4
Line 5
filename2.tif;Smpl/Pix & Bits/Smpl are missing.
filename4.tif;Smpl/Pix & Bits/Smpl are missing.
filename6.tif;Smpl/Pix & Bits/Smpl are missing.
filename8.tif;Smpl/Pix & Bits/Smpl are missing.

De sortie souhaité serait:

filename2.tif
filename4.tif
filename6.tif
filename8.tif

Est-ce possible, et si oui, où dois-je commencer?

  • Il est possible de faire. Avez-vous des code encore?
  • Oui et non. Pas encore - mais j'ai plus de 300 lignes de code que j'essaie de mettre en œuvre cette dans. En gros, c'est une nouvelle fonctionnalité que je suis en train de mettre en œuvre pour traiter les fichiers à partir d'un fichier texte qui existe déjà.
  • La réponse à toutes les questions du début, “En Perl, ¿je peux faire ...?” est “¡Oui!” Toutefois, la réponse à certaines de ces continue avec “Oui, mais ....”
InformationsquelleAutor drewrockshard | 2010-11-24
  1. 4

    Il utilise le Perl 'autosplit' (ou 'awk') mode:

    perl -n -F'/;/' -a -e 'next if $. <= 5; print "$F[0]\n";' < data.file

    Voir " perlrun "et"perlvar'.

    Si vous avez besoin de faire une fonction qui est donnée à un descripteur de fichier et un nombre de lignes à ignorer, alors vous ne serez pas en utilisant le Perl 'autosplit mode.

    sub skip_N_lines_read_column_1
{
    my($fh, $N) = @_;
    my $i = 0;
    my @files = ();
    while (my $line = <$fh>)
    {
        next if $i++ < $N;
        my($file) = split /;/, $line;
        push @files, $file;
    }
    return @files;
}

    Ce initialise une boucle, lit les lignes, en sautant, en N d'entre eux, puis fractionnement de la ligne et de la capture de la première à la suite seulement. Cette ligne avec my($file) = split... est subtil; les parenthèses signifient que la scission a un contexte de liste, de sorte qu'il génère une liste de valeurs (plutôt que d'un nombre de valeurs) et attribue la première à la variable. Si les parenthèses sont omises, vous fournirait un contexte scalaire à une liste de l'opérateur, de sorte que vous obtiendrez le nombre de champs dans la fraction de sortie affecté à $file - pas ce que vous avez besoin. Le nom de fichier est ajouté à la fin du tableau, et le tableau est retourné. Étant donné que le code n'a pas ouvert le descripteur de fichier, ne le ferme pas. Une interface alternative serait de passer le nom du fichier (au lieu d'un descripteur de fichier ouvert) dans la fonction. Vous devez ensuite ouvrir et de fermer le fichier en fonction de, se soucier de la gestion des erreurs.

    Et si vous avez besoin de l'aide avec l'ouverture du fichier, etc, alors:

    use Carp;

sub open_skip_read
{
    my($name) = @_;
    open my $fh, '<', $name or croak "Failed to open file $name ($!)";
    my @list = skip_N_lines_read_column_1($fh, 5);
    close $fh or croak "Failed to close file $name ($!)";
    return @list;
}
    • +1. Meilleure réponse, vraiment. Je dois sauver le perl partie de mon cerveau 🙂
    • Comment pourrais-je écrire cela dans un script, et non dans une ligne de commande, et de les lire à partir d'un descripteur de fichier ouvert d'un fichier qui existe déjà?
    • Il me fait peur, perl sait à avaler votre barre oblique délimiteurs autour du séparateur. Je ne savais pas que!
    • Voir perl courir...non, je veux dire, voir "perlrun'... '-Fpattern spécifie le motif de split sur la si -a est également en vigueur. Le motif peut être entouré par // , "" , ou " , sinon il sera mis entre guillemets simples. Vous ne pouvez pas utiliser littérale espaces dans le modèle.' Je n'ai pas vraiment besoin de la des barres obliques dans cet exemple.
    • Je suis sur la bonne voie. J'ai changé la dernière partie de la open_skip_read sous-routine pour return $list[0]; et maintenant il affiche le nom de fichier. Le problème est qu'un seul nom de fichier est renvoyé, mais il n'y a plus de résultats. J'ai besoin d'elle pour retourner chaque match c'est contre.
    • Compris; il a couru à travers une boucle foreach et qui a fait le tour. J'apprécie vraiment votre aide sur ce coup - c'était certainement la meilleure réponse.

    InformationsquelleAutor Jonathan Leffler
  2. 2
    #!/usr/bin/env perl
#
# name_of_program - what the program does as brief one-liner
#
# Your Name <your_email@your_host.TLA>
# Date program written/released
#################################################################

use 5.10.0;

use utf8;
use strict;
use autodie;
use warnings FATAL => "all";

#  ⚠ change to agree with your input: ↓
use open ":std" => IN    => ":encoding(ISO-8859-1)",
                   OUT   => ":utf8";
#  ⚠ change for your output: ↑ — *maybe*, but leaving as UTF-8 is sometimes better

END {close STDOUT}

our $VERSION = 1.0;

$| = 1;

if (@ARGV == 0 && -t STDIN) {
   warn "reading stdin from keyboard for want of file args or pipe";
}

while (<>) {
    next if 1 .. 5;
    my $initial_field = /^([^;]+)/ ? $1 : next;
    #    ╔═══════════════════════════╗
    #   ☞ your processing goes here ☜
    #    ╚═══════════════════════════╝
} continue {
    close ARGV if eof;
}

__END__
    • Les gars, je suis encore perdu - ** nouveau Perl **. J'ai déjà un fichier qui contient tout. J'ai juste besoin d'ouvrir le fichier dans mon script, passez les 5 premières lignes, et la sortie de la première colonne de chaque ligne après la ligne 5.
    • C'est ce que mon programme n'. De l'essayer.
    • Pouvez-vous montrer un exemple sur la façon d'exécuter cette et où placer votre "fichier d'entrée"?
    • Vous exécutez comme n'importe quel autre script. Et vous placez votre fichier d'entrée partout où vous s'il vous plaît; je ne connais pas son nom. perl this_program your_input_file ou perl this_program < your_input_file ou cat your_input_file | perl this_program ou gzcat your_input_file.gz | perl this_program ou wget -O - http://remote_url | perl this_program ou de l'un quelconque d'un nombre infini de suppléant formulations du même acabit et l'effet.
    • C'est mon point de vue et ce que j'ai continué à obtenir au est le fait que je n'ai pas besoin d'un "script", j'avais besoin de code à mettre en place pour mon programme de lecture d'un fichier qui existe déjà dans le. Tous les exemples que vous avez énumérés apparaissent que j'exécute ce code et, d'une certaine façon, de la tuyauterie le fichier texte de la mine de elle, ou vice-versa. Jonathan exemple de code que j'ai pu mettre en œuvre dans mon propre script, et j'ai été en mesure de déterminer mon fichier existant. Je ne savais pas comment le faire avec votre script. J'apprécie votre aide bien.
    InformationsquelleAutor tchrist
  3. 2

    Un peu laid mais, lire les lignes factices et de la diviser ensuite sur ; pour le reste d'entre eux.

    my $logfile = '/path/to/logfile.txt';

open(FILE, $logfile) || die "Couldn't open $logfile: $!\n";

for (my $i = 0 ; $i < 5 ; $i++) {
   my $dummy = <FILE>;
}

while (<FILE>) {
   my (@fields) = split /;/;
   print $fields[0], "\n";
}

close(FILE);
    • Cela peut être écrit quelque chose comme: my @dummy; @dummy[0..4] = <STDIN>;map {($a) = split /;/;print $a,"\n"} <STDIN>;.
    • Que faire si je suis en train de lire dans un fichier, mais pas à partir de la ligne de commande. J'ai un fichier qui se trouve dans une position relative (si je peux l'appeler par logfile.txt, par exemple). Je vais avoir des problèmes de lecture, de si loin, mon code est le tournage d'une boucle while en permanence et je dois CTRL+C hors de lui.
    • desgracia, qui ne fonctionne pas parce que vous venez de liste fournie par le contexte de la readline opérateur dans votre tranche d'affectation, ce qui épuisant d'entrée. Les lignes restantes ont été écartées.
    • J'ai édité la réponse à l'ouverture de votre dossier logfile.txt.
    • Merci! Je vais aussi donner un aller - j'ai d'abord aimé celui-ci le meilleur, comme il semblait le plus simple de tous.
    • vous avez raison! Eh bien, je voulais juste donner une approche plus fonctionnelle... me Semble que j'ai à étudier de plus, les fonctionnalités de Perl 🙂

    InformationsquelleAutor dmah