Peut un classique de la page ASP à l'aide xmlhttp faire un JSON demande?

Je suis complètement perdu. Je suis en train de poster une API sur un serveur distant à partir d'un classique de la page asp qui utilise vbscript. Mon code:

set xmlhttp = CreateObject("MSXML2.ServerXMLHTTP") 
xmlhttp.open "POST", vURL, false 
xmlhttp.setRequestHeader "Content-type","application/json"
xmlhttp.setRequestHeader "Accept","application/json"
xmlhttp.send "[email protected]&firstname=joe&lastname=smith"
vAnswer = xmlhttp.responseText

- Je recevoir une réponse que la demande n'est pas dans le format attendu. Le support technique m'informe que l'API attend JSON dans le corps post. Puis-je le faire à partir du serveur-côté asp?

OriginalL'auteur user1048348 | 2011-11-15

3

Parce que j'ai couru à travers ce, lorsqu'ils seront effectivement essayer de résoudre le même problème, dans mon cas, l'Affichage de l'ASP Classique à la MailChimp 2.0 de l'API, j'ai voulu faire l'écho de l'utilité de la http://code.google.com/p/aspjson/ lien, mais aussi remarque quelque chose qui était moins pertinent dans le cas de MailChimp. Je pensais que je pouvais tout simplement un format JSON à la recherche de chaîne et l'envoyer, mais il ne fonctionne pas. J'ai dû créer un objet JSON à l'aide de méthodes dans le aspjson bibliothèque, et ensuite utiliser le jsString méthode dans l'instruction send. Si l'extrait de code (après les déclarations appropriées, comprend, etc.) ressemblerait à quelque chose comme ceci:
```
Set objJSON = jsObject()
objJSON("apikey") = "MY API KEY"
Set objJSON("email") = jsObject()
objJSON("email")("email") = strEmail
Set objXMLhttp = Server.Createobject("MSXML2.ServerXMLHTTP")
objXMLhttp.open "POST","https://mailchimpurl/2.0/helper/lists-for-email", false
objXMLhttp.setRequestHeader "Content-type","application/json"
objXMLhttp.setRequestHeader "Accept","application/json"
objXMLhttp.send objJSON.jsString
strResponse = objXMLhttp.responseText
Set objXMLhttp = Nothing
```
Espère que ça aide quelqu'un d'autre le long du chemin.

OriginalL'auteur Bret

'Create a function
Function ASPPostJSON(url)

'declare a variable
Dim objXmlHttp

Set objXmlHttp = Server.CreateObject("Microsoft.XMLHTTP")

'If the API needs userName and Password authentication then pass the values here
objXmlHttp.Open "POST", url, False, "User123", "pass123"
objXmlHttp.SetRequestHeader "Content-Type", "application/json"
objXmlHttp.SetRequestHeader "User-Agent", "ASP/3.0"

'send the json string to the API server
objXmlHttp.Send "{""TestId"": 012345,""Test1Id"": 123456,""Test123"": 37,""Type123"": ""Test_String"",""contact"": {""name"": ""FirstName LastName"",""Organization"": ""XYZ"",""phone"":""123456"",""emailAddress"": ""[email protected]""}}"

'If objXmlHttp.Status = 200 Then
    ASPPostJSON = CStr(objXmlHttp.ResponseText)
'end if

'return the response from the API server
Response.write(ASPPostJSON)
Set objXmlHttp = Nothing

End Function

'call the function and pass the API URL
call ASPPostJSON("https://TheAPIUrl.com/")

Veuillez améliorer la mise en forme par l'indentation de code avec 4 espaces.
Cela devrait vraiment être la accepté de répondre.

OriginalL'auteur Anonymous

1

Vérifier cela, il devrait vous aider à faire ce que vous voulez:

http://code.google.com/p/aspjson/

Bonne chance!

Bugget, j'ai téléchargé que plus tôt, mais je ne vois pas comment il peut être utilisé pour le format JSON demande. Je vais prendre un autre regard.
C'est exactement ce qu'il fait de regarder les exemples dans les pages Wiki. Cependant, votre réponse pourrait être plus utile si vous avez inclus un petit exemple de code pour l'OP, plutôt que de simplement un lien.

OriginalL'auteur Bugget
1

La demande que vous envoyez est ..... pas de JSON. Essayez de l'utiliser comme un programme de validation: JSONLint. Chuck votre chaîne JSON là et il vous dira si c'est valable ou pas. Dans le cas ci-dessus: [email protected]&firstname=joe&lastname=smith. C'est certainement pas plus.

Vous pouvez écrire JSON par la main, par exemple, je voudrais réécrire votre requête comme suit:

{"Email":"[email protected]", "firstname":"joe", "lastname":"smith"}

J'espère que ça aide. Oui, il y a des bibliothèques qui peuvent vous aider à le faire (ASPJSON est l'un d'entre eux), mais pour être honnête, je préfère les écrire moi-même (ASP est donc lourd) ou l'écriture de mes propres fonctions, parce que je sais que je peux leur faire confiance. Voici un exemple de morceau de code que j'ai écrit en ASP qui peuvent faire une chaîne JSON à partir d'un objet Dictionary. Il peut également avoir des tableaux à l'intérieur du dictionnaire éléments. Malheureusement, il n'est pas récursive, donc il ne peut pas faire des tableaux de tableaux ou les dictionnaires les dictionnaires ... mais il ne fonctionne calme, bien pour de simples entrées. Nommé json_encode après la fonction PHP.
```
Function json_encode(ByVal dic)
    ret = "{"
    If TypeName(dic) = "Dictionary" Then
        For each k in dic
            Select Case VarType(dic.Item(k))
                Case vbString
                    ret = ret & """" & k & """:""" & dic.Item(k) & ""","
                Case Else
                    If VarType(dic.Item(k)) > vbArray Then
                        ret = ret & """" & k & """:["
                        For x = 0 to Ubound(dic.Item(k), 1)
                            ret = ret & """" & dic.Item(k)(x) & ""","
                        Next
                        ret = Left(ret, Len(ret) - 1)   'Trim trailing comma
                        ret = ret & "],"
                    Else
                        ret = ret & """" & k & """:""" & dic.Item(k) & ""","
                    End If
            End Select
        Next
        ret = Left(ret, Len(ret) - 1)   'Trim trailing comma
    End If
    ret = ret & "}"
    json_encode = ret
End Function
```
Dans votre exemple, vous avez écrit le JSON entre crochets. Ce n'est pas valide, il doit être accolades par exemple, {"Email":"[email protected]", "prenom":"jean", "lastname":"smith"}
bah merci 🙂

OriginalL'auteur MikeMurko

Vous devez vous connecter pour publier un commentaire.