Peuvent le web deploy exécution de l'agent sur un port autre que le port 80 sur IIS6?

J'ai eu un peu d'un défi avec un Windows 2003 de la machine où j'ai besoin pour exécuter le web déployer l'agent sur un port qui n'est pas 80. Par défaut, l'installation de ce sera exposer un point de terminaison http://[serveur]/MsDeployAgentService qui, évidemment, implicitement écoute sur le port 80.

Le problème que j'ai c'est que la machine est également en cours d'exécution Visual Serveur SVN qui utilise le port 80, et comme un résultat, le déploiement web de service de l'agent refuse de démarrer. (Au moins c'est la seule conclusion logique que je peux en tirer.) J'ai un petit SVN de gestion de l'application sur la même machine que je voudrais publier sur le web déployer d'où le dilemme.

Est-il possible d'exécuter l'agent sur un autre port? Évidemment, si c'était IIS7 nous serions sur 8172 et tout ce serait bien, mais malheureusement ce n'est pas le cas ici. Des suggestions?

InformationsquelleAutor Troy Hunt | 2011-05-03

62

Il ya un couple de façons de le faire:

Option 1: Désinstaller et re-installer Spécifier un port différent:
```
msiexec /I WebDeploy_x86_en-US.msi /passive ADDLOCAL=ALL LISTENURL=http://+:8172/MsDeployAgentService
```
De la ligne de commande installe le MsDeployAgentService et le configure pour qu'il écoute sur le port 8172 comme sur IIS7.

Option 2: Re-configurer les Services Existants pour écouter sur le port 8172:
1. Arrêt de l'installation de ce (net stop msdepsvc)
2. Modifier la valeur de registre suivante:
```
HKLM\SYSTEM\CurrentControlSet\Services\MsDepSvc\Parameters\ListenUrl
```
  Ça va ressembler à quelque chose comme:
```
http://+:80/MsDeployAgentService
```
  Changement:
```
http://+:8172/MsDeployAgentService
```
3. Requête HTTP auditeurs:
```
httpcfg query urlacl
```
  Votre devrait voir l'entrée suivante figurant dans les résultats:
```
URL : http://+:80/MsDeployAgentService/
ACL : D:(A;;GX;;;NS)
```
4. Modifier le port d'écoute:
```
httpcfg delete urlacl /u http://+:80/MsDeployAgentService/
```
  Cela devrait répondre à: HttpDeleteServiceConfiguration completed with 0.
```
httpcfg set urlacl /u http://+:8172/MsDeployAgentService//a D:(A;;GX;;;NS)
```
  Cela devrait répondre à: HttpSetServiceConfiguration completed with 0.
  
  L'ACL spécifié dans le /a commutateur doit correspondre à l'ACL rapporté par le httpcfg query urlacl commande
5. Redémarrage de l'installation de ce (net start msdepsvc).
6. Vous pouvez confirmer que le service est à l'écoute sur le port 8172 par:
```
netstat -an
```
  Vous devriez voir ce qui suit:
```
TCP    0.0.0.0:8172           0.0.0.0:0              LISTENING
```
Avertissement:

Je voudrais essayer cela sur une non-production de la machine, pour garantir cela fonctionne comme vous le souhaitez.
- Épique fu il Kev - si c'était ebay, je serais "AAAA++++"ing vous fo showa
- Je viens de trouver cette réponse lors de la recherche pour la même question, mais en ayant un Windows 7 boite, et le processus a fonctionné pour moi, avec le léger changement de l'utilisation de la "netsh" commande " à la place. Ref: msdn.microsoft.com/en-us/library/ms733768.aspx
- J'ai été faire les erreurs suivantes, et de changer le port a fonctionné pour moi. "La nouvelle tentative de la synchronisation car une erreur de socket (10054) a eu lieu. Réessayer l'opération "Sérialisation" sur l'objet sitemanifest (sourcePath)." Côté serveur le journal des événements contenus, "le Système de.Net.HttpListenerException: Une opération a été tentée sur une inexistant connexion réseau." Merci pour la correction.
- Juste un suivi sur Kev réponse: httpcfg est distribué dans le cadre de "Windows Server 2003 Service Pack 2 32 bits des Outils de Soutien (microsoft.com/download/en/...)".
- L'Option 1 a échoué pour moi: je n'ai pas pu réinstaller parce que 8172 est déjà utilisé par WMSvc (Gestion Web). Je ne peux pas le comprendre - installation de ce besoin WMSvc de travailler et pourtant, les deux utilisent le même port qui n'est pas logique sur le papier, et dans la pratique, pour moi, s'avère ne pas travailler! Comment ça marche pour tout le monde??
- ne pas être désinvolte...mais avez-vous essayé l'option 2? Aussi quel système d'exploitation avez-vous été d'essayer ce sur. Je sais que cette réponse ne travailler spécifiquement sur Windows 2003, mais je n'ai jamais essayé sur Win7/2008/2008R2
- - Vous savez, je crois que j'ai compris qu'il y a le déploiement Web et MS Déployer et qu'une seule est nécessaire. Le second est à l'intérieur de la Web de Gestion de la fonction. Je pense que... c'est si confus.
- Je suis avec Windows Server 2016, je ne trouve pas "httpcfg.exe".
InformationsquelleAutor Kev
26

Ce sont les changements que j'avais à faire pour Windows 7, à la suite de Kev de la recette:

L'étape 3:
netsh http show urlacl

L'étape 4:
netsh http delete urlacl url=http://+:80/MSDEPLOYAGENTSERVICE/

netsh http add urlacl url=http://+:8172/MSDEPLOYAGENTSERVICE/sddl=D:(A;;GX;;;NS)
- cela a fonctionné pour moi de commencer le service, mais les icônes de Gestion sont toujours portées disparues dans IIS. Une idée?
- Merci cela a fonctionné pour moi
InformationsquelleAutor Paul Spaulding

Pour ce que ça vaut, j'ai collé ensemble Kev solide de conseils dans un script batch pour one stop shopping sur la modification des numéros de port.

:: Name:     MsDepSvc.Port.cmd
:: Purpose:  Modifies the TCP/IP port that the Web Deployment Agent Service
::           (MsDepSvc) listens on.  Tested on Win7 Enterprise 32-bit.
:: Author:   [email protected]
:: Revision: January 2013

@ECHO OFF
SETLOCAL ENABLEEXTENSIONS
SETLOCAL ENABLEDELAYEDEXPANSION

:: variables
SET me=%~n0
SET url=
SET port=
IF NOT "%~1"=="" (
  SET /A port=%~1
)

ECHO %me%: Web Deployment Agent Service (MsDepSvc) port change script

:: default argument values
IF "%port%"=="" (
  SET /A port=8172
  ECHO %me%: INFO - using default port value of 8172
)

SC.EXE query msdepsvc >NUL 2>NUL
IF NOT "%ERRORLEVEL%"=="0" (
  ECHO %me%: ERROR - MsDepSvc not installed
  ECHO %me%: exiting
  EXIT /B 1
)

ECHO %me%: stopping MsDepSvc
NET STOP msdepsvc >NUL 2>NUL

:: check if the default port is set
REG.EXE QUERY HKLM\SYSTEM\CurrentControlSet\Services\MsDepSvc\Parameters /v ListenUrl >NUL
IF NOT "%ERRORLEVEL%"=="0" (
  ECHO %me%: ERROR - MsDepSvc ListenUrl registry key not found
  REG.EXE QUERY HKLM\SYSTEM\CurrentControlSet\Services\MsDepSvc\Parameters
  ECHO %me%: exiting
  EXIT /B 2
)

FOR /F "tokens=3" %%I IN ('REG.EXE QUERY HKLM\SYSTEM\CurrentControlSet\Services\MsDepSvc\Parameters /v ListenUrl ^| FINDSTR ListenUrl') DO (
  SET url=%%I
)
ECHO %me%: INFO - MsDepSvc current reservation is "%url%"

NETSH.EXE http show urlacl "%url%" >NUL
IF NOT "%ERRORLEVEL%"=="0" (
  ECHO %me%: ERROR - reservation for "%url%" not found
  EXIT /B 4
)

:: save the existing urlacl properties for User, Listen, Delegate, and SDDL
FOR /F "tokens=1,* delims=: " %%A IN ('NETSH.exe http show urlacl %url%  ^| FINDSTR "User Listen Delegate SDDL"') DO (
  SET URLACL.%%A=%%B
)

IF NOT DEFINED URLACL.User     ECHO %me%: Failed to read the exising URLACL setting for User     &&GOTO :ERROR
IF NOT DEFINED URLACL.Listen   ECHO %me%: Failed to read the exising URLACL setting for Listen   &&GOTO :ERROR
IF NOT DEFINED URLACL.Delegate ECHO %me%: Failed to read the exising URLACL setting for Delegate &&GOTO :ERROR
IF NOT DEFINED URLACL.SDDL     ECHO %me%: Failed to read the exising URLACL setting for SDDL     &&GOTO :ERROR

ECHO %me%: updating MsDepSvc to listen on port %port%
REG.EXE ADD HKLM\SYSTEM\CurrentControlSet\Services\MsDepSvc\Parameters /v ListenUrl /t REG_SZ /f /d "http://+:%port%/MSDEPLOYAGENTSERVICE/"

ECHO %me%: deleting the existing reservation for MsDepSvc
NETSH.EXE http delete urlacl "%url%" || GOTO :ERROR

ECHO %me%: adding the port %port% reservation for MsDepSvc
NETSH.EXE http add urlacl url=http://+:%port%/MsDeployAgentService/user="%URLACL.User%" listen="%URLACL.Listen%" delegate="%URLACL.Delegate%" SDDL="%URLACL.SDDL%"  || GOTO :ERROR

ECHO %me%: starting MsDepSvc
NET START msdepsvc >NUL 2>NUL

ECHO %me%: process info for MsDepSvc
QUERY.EXE PROCESS MSDEPSVC.EXE
ECHO.
ECHO %me%: port bindings for MsDepSvc
NETSTAT.EXE -a -n -o | FINDSTR /R "TCP.*:%port%.*LISTENING Proto"
ECHO.
ECHO %me%: finished

:END
ENDLOCAL
ECHO ON
@EXIT /B 0

:ERROR
ECHO %me%: ERROR - exiting with errorlevel %ERRORLEVEL%
ECHO ON
@EXIT/B %ERRORLEVEL%

Lire La Suite:

Juste tombé sur cette. Belle adaptation +1 🙂
Merci - je obtenir une erreur cependant: "l'Url de réservation d'ajouter échec, Erreur: 183" "Ne peut pas créer un fichier existe déjà"
Salut @niico, ce numéro de port que vous souhaitez utiliser, vous êtes sûr que c'est un port inutilisé, et en ce que la sortie ne vous voir avant le message d'erreur?
Je vais pas en arrière si je peut. Je veux juste arrêter d'utiliser le port 80 - parce que c'est ouvert sur le pare-feu matériel et d'utiliser un autre port qui est fermé (la plupart le sont) donc ce n'est pas ouverte sur le monde, seulement pour les utilisateurs VPN. Je n'ai pas l'esprit qui port. Pensées?
(la ligne avant que l'erreur était: ajout du port 1872 réservation pour l'installation de ce) - c'est une installation propre de Web Deploy 3.5 sur Windows Server 2012
Quelque chose doit être différent pour Windows Server 2012; malheureusement, je n'ai pas accès à 2012 de la boîte. Pouvez-vous coller la sortie de NETSH.exe http show urlacl %url% dit, où %url% est la valeur de sortie par le journal en ligne INFO - MsDepSvc current reservation is "%url%"?
Il convient de mentionner que le script échoue sur la non-anglais Windows. En danois (ma langue de l'os), remplacement global URLACL.User avec URLACL.Bruger, URLACL.Listen avec URLACL.Lyt, URLACL.Delegate avec URLACL.Deleger. Laisser URLACL.SDDL que c'est le même dans les deux langues.

InformationsquelleAutor Steve Jansen

0

Il est également utile de connaître la magie de découvrir ce bien est stockée dans lequel la clé de registre - entrez Orca.exe - précieux et simple à utiliser l'outil pour la lecture et la modification de la base de données MSI (essayez de ne pas modifier si).

Tout d'abord, nous avons besoin de trouver la propriété de la table

Une fois que la propriété est trouvé, allez à la table du Registre et de trouver où il est inséré.

InformationsquelleAutor Ostati

Vous devez vous connecter pour publier un commentaire.