Pivot dans Excel sans l'agrégation, pour afficher le texte, pas les chiffres?

Ajouter le MyText comme une étiquette de ligne sous le Pays de l'étiquette, puis affichage du tableau croisé dynamique sous forme de tableau dans le Tableau croisé dynamique onglet conception. Répétez les étiquettes de l'élément pour le pays d'étiquette de ligne de champ.

OriginalL'auteur cronos2546

Cela peut être fait, mais nécessite VBA pour remplacer temporairement un numérique 'placeholder' valeur dans votre tableau croisé dynamique avec du texte. Pour ce faire, vous devez définir EnableDataValueEditing = True pour le tableau croisé dynamique. Lors de l'actualisation, vous ensuite d'effectuer une recherche sur le numérique de la valeur de l'espace réservé, et de le remplacer par le texte. Compliqué, oui. Solution de contournement, oui. Mais il fait l'affaire. Notez que cela ne colle' jusqu'à ce que la prochaine fois que le tableau croisé dynamique est actualisé, de sorte que ce code doit être triggerred à chaque actualisation.

Voici le code que j'utilise pour ce faire, dans un de mes propres projets. Mettez ceci dans un Module de Code Standard:

Function Pivots_TextInValuesArea(pt As PivotTable, rngNumeric As Range, rngText As Range, Optional varNoMatch As Variant)

Dim cell As Range
Dim varNumeric As Variant
Dim varText As Variant
Dim varResult As Variant
Dim bScreenUpdating As Boolean
Dim bEnableEvents As Boolean
Dim lngCalculation As Long


On Error GoTo errHandler
With Application
    bScreenUpdating = .ScreenUpdating
    bEnableEvents = .EnableEvents
    lngCalculation = .Calculation
    .ScreenUpdating = False
    .EnableEvents = False
    .Calculation = xlCalculationManual
End With


varNumeric = rngNumeric
varText = rngText

pt.EnableDataValueEditing = True
'Setting this to TRUE allow users or this code to temporarily overwrite PivotTable cells in the VALUES area.
'Note that this only 'sticks' until the next time the PivotTable is refreshed, so this code needs to be
' triggerred on every refresh

For Each cell In pt.DataBodyRange.Cells
    With cell
        varResult = Application.Index(varText, Application.Match(.Value2, varNumeric, 0))
        If Not IsError(varResult) Then
            cell.Value2 = varResult
        Else:
            If Not IsMissing(varNoMatch) Then cell.Value2 = varNoMatch
        End If
    End With
Next cell

errHandler:
 If Err.Number > 0 Then
    If gbDebug Then
        Stop: Resume
    Else:
        MsgBox "Whoops, there was an error: Error#" & Err.Number & vbCrLf & Err.Description _
         , vbCritical, "Error", Err.HelpFile, Err.HelpContext
    End If
End If

With Application
    .ScreenUpdating = bScreenUpdating
    .EnableEvents = bEnableEvents
    .Calculation = lngCalculation
End With


End Function

Et voici le résultat: un tableau croisé dynamique avec le Texte dans la zone VALEURS:

Voici la "conversion" de la table que dit le code des éléments à afficher pour chaque numéro:

J'ai attribué deux plages nommées à ces derniers, de sorte que mon code sait où trouver de la table de recherche:

• tbl_PivotValues.TextValue
• tbl_PivotValues.NumericValue

...et voici comment j'ai déclencher la Fonction et le passer dans les arguments requis:

Option Explicit

Private Sub Worksheet_PivotTableUpdate(ByVal Target As PivotTable)

If Target.Name = "GroupView" Then Pivots_TextInValuesArea Target, [tbl_PivotValues.NumericValue], [tbl_PivotValues.TextValue]

End Sub

Que le code va dans la Feuille de calcul Module de Code qui correspond à la feuille de calcul où le tableau croisé dynamique est:

OriginalL'auteur jeffreyweir