PL / SQL: Sélection d'une table dans un tableau assoc

Je suis en train de sélectionner des données en pl/sql tableau associatif dans une requête. Je sais que je peux le faire avec une clé codée en dur, mais je voulais voir si il y avait moyen que je pouvais faire référence à une autre colonne (la colonne de la clé) à la place.


DECLARE
TYPE VarAssoc IS TABLE OF varchar2(2) INDEX BY varchar2(3);
vars VarAssoc;
BEGIN
SELECT foo, bar INTO vars(foo) FROM schema.table;
END;

Je reçois un message d'erreur indiquant foo doit être déclarée quand je fais cela. Est-il possible de créer mon associé de tableau dans une seule requête ou dois-je me rabattre sur une boucle FOR?

source d'informationauteur Seaux

  1. 16

    Viens de lire votre commentaire sur l'APC de réponse, il semble que vous avez compris ce sur votre propre. Mais j'ai pensé que je l'avais mis la réponse en tout cas pour les futurs chercheurs.

    C'est plus simple de code, mais n'a pas l'avantage de vitesse de l'aide de BULK COLLECT. Juste une boucle sur les lignes retournées par la requête et de définir les éléments du tableau associatif individuellement.

    DECLARE
  TYPE VarAssoc IS TABLE OF varchar2(200) INDEX BY varchar2(30);
  vars VarAssoc;
BEGIN
  FOR r IN (SELECT table_name,tablespace_name FROM user_tables) LOOP
    vars(r.table_name) := r.tablespace_name;
  END LOOP;

  dbms_output.put_line( vars('JAVA$OPTIONS') );
END;
  2. 6

    Qu'il serait bien si c'était possible, mais ce n'est pas un moyen simple d'y parvenir.

    Ce que nous pouvons faire est de charger les données dans une régulière, PL/SQL de la collecte et ensuite chargez-la dans un tableau associatif. Whethter c'est plus rapide que seulement en boucle autour de la table est une question de tatse: il n'a probablement pas d'importance, sauf si nous avons affaire à des charges de données.

    Compte tenu de ce test de données ...

    SQL> select * from t23
  2  order by c1
  3  /

C1 C2
-- ---
AA ABC
BB BED
CC CAR
DD DYE
EE EYE
ZZ ZOO

6 rows selected.

SQL>

    ...nous pouvons remplir un tableau associatif en deux étapes:

    SQL> set serveroutput on
SQL>
SQL> declare
  2      type varassoc is table of varchar2(3) index by varchar2(2);
  3      vars varassoc;
  4
  5      type nt is table of t23%rowtype;
  6      loc_nt nt;
  7
  8  begin
  9      select * bulk collect into loc_nt from t23;
 10      dbms_output.put_line('no of recs = '||sql%rowcount);
 11
 12      for i in loc_nt.first()..loc_nt.last()
 13      loop
 14          vars(loc_nt(i).c1) := loc_nt(i).c2;
 15      end loop;
 16
 17      dbms_output.put_line('no of vars = '||vars.count());
 18
 19      dbms_output.put_line('ZZ = '||vars('ZZ'));
 20
 21  end;
 22  /
no of recs = 6
no of vars = 6
ZZ = ZOO

PL/SQL procedure successfully completed.

SQL>

    La vraie question est probablement celle de savoir si le remplissage d'un tableau associatif effectue mieux que de simplement la sélection de lignes dans la table. Certes, si vous avez 11g Enterprise edition, vous devriez envisager jeu de résultats de la mise en cache à la place.

  3. 0

    êtes-vous absolument mariés à des tableaux associatifs? Et je suppose que vous faites cela parce que vous voulez être en mesure de faire une recherche sur le tableau à l'aide d'une touche de caractère.

    Si oui, avez-vous envisagé la mise en œuvre de la présente comme un type de collection à la place?

    par exemple

    CREATE OR REPLACE TYPE VAR_ASSOC as OBJECT(
  KEYID   VARCHAR2(3),
  DATAVAL VARCHAR2(2)
)
/

CREATE OR REPLACE TYPE VAR_ASSOC_TBL AS TABLE OF VAR_ASSOC
/

CREATE OR REPLACE PROCEDURE USE_VAR_ASSOC_TBL
AS
  vars Var_Assoc_tbl; 
  -- other variables...
BEGIN 
    select cast ( multiset (
                        select foo as keyid,
                               bar as dataval
                        from   schema.table
                           ) as var_Assoc_tbl
                )
     into vars
     from dual;   
     -- and later, when you want to do your lookups
     select  ot.newfoo 
            ,myvars.dataval
            ,ot.otherval
     into   ....       
     from   schema.other_Table ot
     join   table(vars) as myvars
     on     ot.newfoo = myvars.keyid;
end;
/

    Cela vous donne la liste de choix de par son caractère de valeur de la clé et vous permet de faire tout en vrac.