Pourquoi ne puis-je pas utiliser “CompactDatabase” dans DAO.DBEngine.36 à l'aide de VBscript?

Je suis en train de faire un petit script VBScript qui compresse un MS Access 2007 de base de données de fichier.

Le code que j'ai est:

Set acc2007 = CreateObject("DAO.DBEngine.36")
acc2007.CompactDatabase "C:\test.accdb", "C:\test2.accdb", Nothing, Nothing, ";pwd=test"
Set acc2007 = Nothing

J'obtiens cette erreur quand je lance les trois lignes "cscript test.vbs" à partir d'un 32 bits cmd.exe:

C:\test.vbs(10, 1) DAO.DbEngine: format de données non reconnu 'C:\test.accdb'.

La base de données a été créée avec MS Access 2007, quand je l'ouvre en double-cliquant sur l'icône I tapez le mot de passe "test" et puis je l'ouvre normalement. Il dit: "Access 2007" dans le haut de sorte qu'il a le format correct.

Voici la documentation de la fonction, je suis en train d'utiliser: http://msdn.microsoft.com/en-us/library/bb220986.aspx

L'objet DAO.DBEngine.36 est créé avec succès depuis je ne reçois pas toutes les erreurs sur la ligne. Quel est le problème?

C'est pourquoi vous devez vérifier dans le code pour le .ldb fichier (fichier de verrouillage) première et continuer uniquement si il n'est pas trouvé.
Je peux vivre heureux avec cela. =) A bientôt.

OriginalL'auteur Mike | 2010-06-28

6

DAO 3.6 ne prend pas en charge le nouveau ACCDB format de base de données. Essayez de DAO.DBEngine.De 120 à la place.

Voici un exemple qui fonctionne sur mon système.
```
Dim objFSO
Dim objEngine
Dim strLckFile
Dim strSrcName
Dim strDstName
Dim strPassword

strLckFile =  "C:\Access\webforums\foo.laccdb"
strSrcName =  "C:\Access\webforums\foo.accdb"
strDstName =  "C:\Access\webforums\compacted.accdb"
strBackup = "C:\Access\webforums\foobackup.accdb"
strPassword = "foo"

Set objEngine = CreateObject("DAO.DBEngine.120")

Set objFSO = CreateObject("Scripting.FileSystemObject")
If Not (objFSO.FileExists(strLckFile)) Then
    If (objFSO.FileExists(strBackup)) Then
        objFSO.DeleteFile strBackup
    End If
    If (objFSO.FileExists(strDstName)) Then
        objFSO.DeleteFile strDstName
    End If
    objFSO.CopyFile strSrcName, strBackup

    ''dbVersion120 = 128 
    objEngine.CompactDatabase strSrcName, strDstName, , 128, ";pwd=" & strPassword

    objFSO.DeleteFile strSrcName
    objFSO.MoveFile strDstName, strSrcName
End If 'LckFile
```
Note: j'ai décidé de faire une sauvegarde de ma base de données avant de compact. À la fin, j'ai supprimer l'original (sous forme non compressée) de la base de données et de renommer le compactée un nom d'origine. Si vous n'êtes pas intéressé par ça, on peut le simplifier en supprimant le objFSO choses.

Modifier: mise à jour pour vérifier les fichier de verrouillage; si trouvé ne rien faire.

Je pourrais vous embrasser, mais je me contenterai de faire bouger votre main. 🙂 Merci beaucoup, cela fonctionne! La base de données Access 2007 est compressé avec succès et ne pas changer le format d'un Accès plus précoce de la base de données (comme il le fera avec d'autres méthodes), ET il répare également des bases de données avec un état incohérent! Pour toute personne qui lit ce mais ne pas le faire fonctionner: Si vous êtes sur une version 64bit de Windows n'oubliez pas d'exécuter le script par l'intermédiaire d'un 32bit cmd (qui se trouve dans SysWOW64). Merci encore HansUp, ce ne pouvait pas être plus utile.

OriginalL'auteur HansUp
3

La commande ci-dessus ne fonctionne pas pour Access 2007 et 2010.

Alors que toutes les versions de Windows remontant à 2000, et peut-être même Windows 98, sont livrés avec un exemplaire du moteur à réaction, pour Access 2007 et au-delà, si vous êtes en utilisant le NOUVEAU format (accdb), alors vous avez besoin pour utiliser la nouvelle version du moteur Jet appelé ACE. Notez que ce moteur de données n'est PAS installé par défaut sur Windows, donc vous devez le télécharger à partir de Microsoft.

Bien sûr, en supposant que vous avez déjà Accès à 2007 est installé, alors vous AVEZ de la nouvelle Jet engine (ACE) et vous n'avez PAS besoin de télécharger et d'installer le logiciel mentionné ci-dessus.

Le nouveau nom de l'objet que vous avez besoin est DAO.DBEngine.120, afin de modifier votre code:
```
Set acc2007 = CreateObject("DAO.DBEngine.120") 
```
Noter qu'une version 64 bits est également disponible.

Merci à vous ainsi.

OriginalL'auteur Albert D. Kallal

Vous devez vous connecter pour publier un commentaire.