PowerPoint VBA: de la commande (ou un ensemble de commandes), serait de créer des ppt images sur mon .des photos en format jpg?

J'ai un peu de .les fichiers jpg dans C:\my_folder

Voici leurs noms: pic_1.jpg , pic_2.jpg , pic_3.jpg , pic_4.jpg , pic_5.jpg .

Quelle commande ou d'un groupe de commandes Power Point VBA dois-je utiliser pour être en mesure de créer automatiquement plusieurs images dans PowerPoint afin que chaque cadre contient une image?

tu veux dire quoi par "cadre"? est-ce à dire un effet de relief sur une image? une diapositive par l'image? toutes les photos sur une diapositive? aussi, vous êtes à la recherche d'avoir powerpoint extraire les images à partir de votre dossier et de les insérer ou...?
Oui, Otaku, je suis désolé pour ma mauvaise formulation. Oui, je veux dire un "slide" par un "cadre". Oui, je veux PowerPoint pour créer des diapositives (tout autant que les images que j'ai), puis récupérer les photos de mon dossier, et l'insertion de chaque image dans chaque diapositive. Un glisser - une image
Alivo la réponse ci-dessous est sur la bonne voie pour une solution de programmation, bien qu'à partir de PowerPoint vous utiliser VBA au lieu de VBScript et dans .NET/VSTO vous pouvez utiliser C# ou VB.NET. Mais ce n'est possible sans la programmation aussi bien - il suffit d'utiliser la "Album Photo" pour sélectionner votre dossier/images, puis appuyez sur OK. Une diapositive sera créé pour chaque image. Dans PowerPoint 2007/2010 il est disponible dans le Ruban son onglet Insertion.
Merci. Pouvez-vous, s'il vous plaît, me donner une idée sur comment je pourrais le faire en VBA? J'ai créé une macro de son script, mais il ne fonctionne pas. Mon PowerPoint 2003 - c'est peut-être pourquoi son macro ne fonctionne pas.

OriginalL'auteur brilliant | 2011-02-18

  1. 6

    Ce VBScript crée une nouvelle présentation PowerPoint et ajoute deux lames, chacune avec une photo. Vous aurez besoin d'ajuster l'image de l'emplacement et de la taille pour convenir à votre goût. Aussi, vous aurez besoin d'utiliser le Script.FileScriptingObject pour énumérer vos images si vous voulez saisir automatiquement ce que des photos sont disponibles dans un répertoire pour l'incorporation dans la présentation. Si vous voulez que votre script peut également enregistrer la présentation en appelant pptPresentation.SaveAs après vos diapositives sont générés.

    La documentation MSDN est situé à http://msdn.microsoft.com/en-us/library/ff746873.aspx.

    Dim pptDoc
Dim pptPresentation
Dim pptSlide

Set pptDoc = WScript.CreateObject( "PowerPoint.Application" )
pptDoc.Visible = True
Set pptPresentation = pptDoc.Presentations.Add( True )

' Add a new slide with a blank layout to the end of the Slides collection
' 12 = ppLayoutBlank
Set pptSlide = pptPresentation.Slides.Add( pptPresentation.Slides.Count + 1, 12 )

' Add a picture into the slide, saving the picture into the PowerPoint document
' 10, 10 are the Left and Top coordinates respectively
pptSlide.Shapes.AddPicture "c:\FullPath.JPG", False, True, 10, 10

' Add another slide with a picture
Set pptSlide = pptPresentation.Slides.Add( pptPresentation.Slides.Count + 1, 12 )
pptSlide.Shapes.AddPicture "c:\FullPath.jpg", False, True, 10, 10
    Merci pour votre temps, mais quand j'ai créé une macro dans PowerPoint avec votre script dans l'éditeur de Macro Visual Basic fenêtre, il ne fonctionne pas. Non seulement les photos ne sont pas récupérées à partir de mon dossier, mais même de nouvelles diapositives ne sont pas créés. Ce que je manque ici?
    Désolé, ce script s'exécute en dehors de PowerPoint. Je n'avais pas réalisé que tu avais écrit un PowerPoint VBA macro. Si vous placez le code que j'ai posté dans un fichier VBS (ex. CreatePresentation.vbs) et de l'exécution qu'il va travailler.
    "Je n'avais pas réalisé que tu avais écrit un PowerPoint VBA macro" - Ma faute, désolé. J'aurais dit tout de suite. Puis-je tout simplement de placer votre code dans un .fichier txt puis, ayant changé son extension .txt pour .vbs, l'exécuter en quelque sorte? Dois-je besoin d'avoir un logiciel spécial installé précédemment om mon ordinateur pour exécuter la commande .vbs fichiers? Je suis désolé, je ne sais rien à propos de VBScripting.
    Oui, vous l'avez droit. VBS fichiers peuvent être gérés par Windows sans aucun logiciel supplémentaire.
    Avez-vous copier les deux lignes, à l'appel de Diapositives.Ajouter et de Formes.AddPicture? Il sonne comme il vous manque les Diapositives.Ajouter un appel. Comme pour la lecture en boucle à travers les fichiers dans un répertoire, voir ma deuxième réponse que j'ai posté juste pour vous. Le FileSystemObject code peut être utilisé dans le script VBS d'une manière similaire.

    OriginalL'auteur Avilo

  2. 4

    Comme la réponse précédente était spécifique à VBS script, voici une version pour l'incorporation dans PowerPoint comme une macro VBA. Il a été créé avec PowerPoint 2010.

    Ce qui a le répertoire codé en dur, donc c'est un exercice pour le lecteur choisisse un nom de répertoire à scanner.

    Sub CreatePictureSlideshow( )
  Dim presentation
  Dim layout
  Dim slide

  Dim FSO
  Dim folder
  Dim file
  Dim folderName

  ' Set this to point at the folder you wish to import JPGs from
  ' Note: make sure this ends with a backslash \
  folderName = "c:\somedirectory\"

  ' Delete all slides and setup variables
  Set presentation = Application.ActivePresentation
  If presentation.Slides.count > 0 Then
     presentation.Slides.Range.Delete
  End If
  Set layout = Application.ActivePresentation.SlideMaster.CustomLayouts(1)
  Set FSO = CreateObject("Scripting.FileSystemObject")

  ' Retrieve the folder's file listing and process each file
  Set folder = FSO.GetFolder(folderName)
  For Each file In folder.Files

     ' Filter to only process JPG images
     If LCase(Mid(file.Name, Len(file.Name) - 3, 4)) = ".jpg" Then

        ' Create the new slide and delete any pre-existing contents
        Set slide = presentation.Slides.AddSlide(presentation.Slides.count + 1, layout)
        While slide.Shapes.count > 0
          slide.Shapes(1).Delete
        Wend

        ' Add the picture
        slide.Shapes.AddPicture folderName + file.Name, False, True, 10, 10

        ' Optional: create a textbox with the filename on the slide for reference
        '   Dim textBox
        '   Set textBox = slide.Shapes.AddTextbox(msoTextOrientationHorizontal, 10, 10, 200, 200)
        '   textBox.TextFrame.TextRange.Text = file.Name
     End If
  Next

End Sub

    OriginalL'auteur Avilo