Problème de la construction d'un document XML à l'aide TXMLDocument

Je suis nouveau sur delphi et maintenant je dois lire de créer un fichier xml. mon code est le suivant:

function foo.createXMLDocument(): TXMLDocument;
var
  res: TXMLDocument;
  rootNode: IXMLNode;
  sl : TStringList;
begin
  res := TXMLDocument.Create(nil);
  res.Active := true;
  rootNode := res.AddChild('label');
  // create string for debug purposes
  sl := TStringList.Create;
  sl.Assign(res.XML);// sl is empty after this assignment
  //add more elements
  generateDOM(rootNode);

  Result := res;
end;

Le problème, c'est le nombre de nœuds enfants augmente, mais res.XML est vide. Pour ne pas mentionner que le reste des éléments dans la generateDOM procédure ne semble pas faire quoi que ce soit. Je vais être très heureux avec votre aide.

Ce serait bien si vous nous avez fourni les Delphi version que vous utilisez. Voir ma réponse dans le cas de D2007.

OriginalL'auteur Sambatyon | 2009-10-07

delphi txmldocument

Avertissement: Testé avec D2007.

Votre code ne prévoit en effet de créer le XML ( <label/> ), comme indiqué dans modifiés en fonction:

function createXMLDocument(): TXMLDocument;
var
  res: TXMLDocument;
  rootNode: IXMLNode;
  sl : TStringList;
begin
  res := TXMLDocument.Create(nil);
  res.Active := true;
  rootNode := res.AddChild('label');
  // create string for debug purposes
  sl := TStringList.Create; // not needed
  sl.Assign(res.XML);  // Not true: sl is empty after this assignment
  ShowMessage(sl.text);// sl is NOT empty!
  sl.Free;             // don't forget to free it! use try..finally.. to guarantee it!
  //add more elements
//  generateDOM(rootNode);
  Result := res;
end;

Mais il demande un beaucoup de remarques:

- Vous n'avez pas besoin d'un local res variable, il suffit d'utiliser le Résultat.

- Vous n'avez pas besoin d'un supplément StringList pour voir le XML: Résultat.Xml.Texte

- N'oubliez pas de Gratuit la sl StringList si vous en créer un.

- XmlDocument de votre retour est inutilisable en dehors de la fonction et donne un AV si vous essayez.

Pourquoi?

C'est parce que un XMLDocument est destiné à être utilisé comme un Composant avec un Propriétaire, ou comme un Interface par ailleurs, afin de gérer ses vie.

Le fait que vous utilisez une Interface de tenir rootNode causes d'être détruits à la fin de la CreateXmlDocument fonction. Et si vous regardez le code de la TXMLNode._Release, vous verrez qu'il déclenche des TXMLDocument._Release qui appelle à Détruire, à moins qu'un Propriétaire pour la XMLDocument (ou d'une interface d'y faire référence).

C'est pourquoi le XMLDocument est valide et peuplée à l'intérieur de la CreateXMLDocument fonction, mais pas disponible à l'extérieur, sauf si vous revenez d'une Interface ou de fournir un Propriétaire.

Voir le des solutions de rechange ci-dessous:

function createXMLDocumentWithOwner(AOwner: TComponent): TXMLDocument;
var
  rootNode: IXMLNode;
begin
  Assert(AOwner <> nil, 'createXMLDocumentWithOwner cannot accept a nil Owner');
  Result := TXMLDocument.Create(AOwner);
  Result.Active := True;
  rootNode := Result.AddChild('label');
  OutputDebugString(PChar(Result.Xml.Text));
  //add more elements
//  generateDOM(rootNode);
end;

function createXMLDocumentInterface(): IXMLDocument;
var
  rootNode: IXMLNode;
begin
  Result := TXMLDocument.Create(nil);
  Result.Active := True;
  rootNode := Result.AddChild('label');
  OutputDebugString(PChar(Result.Xml.Text));
  //add more elements
//  generateDOM(rootNode);
end;


procedure TForm7.Button1Click(Sender: TObject);
var
  doc: TXmlDocument;
  doc2: IXMLDocument;
begin
  ReportMemoryLeaksOnShutdown := True;

  doc := createXMLDocument;
  // ShowMessage( doc.XML.Text ); // cannot use it => AV !!!!
  // already freed, cannot call doc.Free;

  doc := createXMLDocumentWithOwner(self);
  ShowMessage( doc.XML.Text );

  doc2 := createXMLDocumentInterface;
  ShowMessage( doc2.XML.Text );
end;

OriginalL'auteur François

4

La Delphi Aider de TXMLDocument.Méthode AddChild dit (au bas):

Remarque: Ne pas appeler la méthode AddChild pour ajouter un enfant à l'élément de document de ce document. Lors de l'ajout de données du document XML, l'utilisation de la méthode AddChild méthode de l'élément de document ou d'un nœud de la hiérarchie qui doit être le parent d'un nouveau nœud.

Et c'est ce que vous êtes en train de faire? 🙂

Voici une introduction de l'article sur Delphi Document XML Programmation et montre comment vous pouvez travailler avec le TXMLDocument.DocumentElement propriété à la place de votre définition de la rootnode variable dans votre code.

L'introduction vous citez n'est pas de montrer comment créer un nouveau document à partir de zéro. Pas plus que la page d'aide. Comment le code dans la question du changement pour le faire?
dans D2007 TXmlDocument.AddChild crée la DocumentNode si ce n'est déjà là et appelle sa méthode AddChild. Il n'est donc pas le problème.
Erwin, vous permet de modifier votre réponse, mais je ne pense pas que vous avez tenu compte de mon commentaire.
Ce n'était pas exactement ce que je cherchais, mais le lien pour l'aide a été extrêmement utile puisque je n'ai accès qu'à la version allemande de l'delphi aider et je cherchais la version anglaise en ligne.

OriginalL'auteur Erwin
2

Dans mon semblable mise en œuvre, je déclare res comme IXMLDocument au lieu de TXMLDocument.
```
var
   XMLDoc: IXMLDocument;
.
.
   XMLDoc := TXMLDocument.Create(nil);
   XMLDoc.Active := True;
.
.
   XMLDoc.SaveToFile(Filename);
   XMLDoc.Active := False;
```
Même si c'est la bonne chose à faire lors de l'instanciation d'un TXmlDocument sans un propriétaire composant, ce n'est pas pertinent pour le problème à portée de main.

OriginalL'auteur J__

Vous devez vous connecter pour publier un commentaire.