procédure de déclaration ne correspond pas à la description de l'événement ou de la procédure ayant le même nom

Je suis juste novice et j'ai essayé de faire un simple programme en Visual Basic 6. Le code est presque équivalente à celle du manuel. Il était censé être une sorte de programme de peinture. Étonnamment, il ne pouvait pas être compilé avec le message d'erreur mentionné dans le titre de cette question.
C'est le code:

Option Explicit

Dim Col As Long

Private Sub Form_Load()
    AutoRedraw = True
    BackColor = vbWhite
    Col = vbBlack
    DrawWidth = 3
End Sub

Private Sub Command1_Click()
    CommonDialog1.ShowOpen
    Form1.Picture = LoadPicture(CommonDialog1.FileName)
End Sub

Private Sub Command2_Click()
    CommonDialog1.ShowSave
    SavePicture Image, CommonDialog1.FileName
End Sub

Private Sub Command3_Click()
    CommonDialog1.ShowColor
    Col = CommonDialog1.Color
End Sub

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    PSet (X, Y), Col
End Sub

Private Sub Toolbar1_ButtonClick(ByVal Button As MSComctlLib.Button)
    Select Case Button.Key
    Case "Line1"
        DrawWidth = 3
    Case "Line2"
        DrawWidth = 20
    End Select
End Sub

L'application se bloque sur la ligne suivante:

Private Sub Toolbar1_ButtonClick(ByVal Button As MSComctlLib.Button)

Avec l'erreur:

procédure de déclaration ne correspond pas à la description de l'événement ou de la procédure
ayant le même nom

OriginalL'auteur user1700848 | 2012-09-26

  1. 21

    Le problème est ici:

    Private Sub Toolbar1_ButtonClick(ByVal Button As MSComctlLib.Button)

    Ok, depuis l'écriture du code en VB6, vous arrivez à apprendre quelques trucs dans le VB6 playbook. Renommer temporairement la méthode à autre chose comme qqToolbar_ButtonClick, puis aller à la designer et cliquez sur le bouton dans la barre d'outils pour régénérer l'événement dans le code.

    Dans le cas où la signature a été une erreur de frappe, il se régénère à partir de la designer correctement et vous risquez de voir le problème.

    Une autre vérification est de voir si le ToolBar1 a été ajouté à un tableau de contrôle? Dans ce cas, la signature de la méthode doit ressembler à ceci:

    Private Sub Toolbar1_ButtonClick(ByVal Index as Integer, ByVal Button As MSComctlLib.Button)

    J'espère que l'un de ces permet de résoudre le problème pour vous.

    Merci pour la réponse rapide!!! La première de vos conseils m'ont aidé à surmonter ce problème!
    Le tableau de contrôle a été mon problème, merci

    OriginalL'auteur Jason Hermann