Prologue de supprimer plusieurs éléments d'une liste

Je sais comment faire pour supprimer un élément d'une liste, mais est-il un moyen de supprimer plus d'un des éléments d'une liste? Par exemple,

deletelist([a,b,c,a,b],[a,c],X)
X = [b,b] % delete a and c from the list.

OriginalL'auteur MaXX99 | 2011-05-23

  1. 5

    SWI-Prolog offre subtract/3:

    ?- subtract([a,b,c,a,b], [a,c], X).
X = [b, b].

?- listing(subtract).
lists:subtract([], _, []) :- !.
lists:subtract([A|C], B, D) :-
    memberchk(A, B), !,
    subtract(C, B, D).
lists:subtract([A|B], C, [A|D]) :-
    subtract(B, C, D).

    OriginalL'auteur Kaarel

  2. 3

    Pour supprimer plusieurs éléments, nous vérifions si un élément est dans la deuxième liste et de le retirer lorsque la condition est vraie:

    deletelist([], _, []).                  
deletelist([X|Xs], Y, Z) :- member(X, Y), deletelist(Xs, Y, Z), !.
deletelist([X|Xs], Y, [X|Zs]) :- deletelist(Xs, Y, Zs).
    J'aurais mis la ! entre le membre et deleteList.
    deletelist([a],[a],[a]). réussit, mais il doit échouer.

    OriginalL'auteur pad

  3. 1

    Voici une définition que donne toujours des réponses correctes (modulo la résiliation):

    deletelist(Xs, Ys, Zs) :-
   tfilter(not(list_memberd_truth(Ys)),Xs, Zs).

not(G, E, T) :-
   call(G, E, NT),
   ( NT = true, T = false
   ; NT = false, T = true
   ).

list_memberd_truth(Xs, X, Truth) :-
   memberd_truth(X, Xs, Truth).

    À l'aide de tfilter/3 et
    memberd_truth/3 d'autres réponses. Dans le cas où votre Prolog ne prend pas en charge dif/2, voir iso_dif/2 pour un coffre-fort rapprochement.

    Certains des plus inhabituels, des questions qui doivent encore sortir correct:

    ?- deletelist([a], [X], Zs).
X = a,
Zs = [] ;
Zs = [a],
dif(X, a) ;
false.

?- deletelist([X], [Y], [X]).
 dif(X, Y) ;
false.

    Et voici quelques requêtes qui ne devrait en fait pas (et donc mettre fin), mais plutôt de la boucle. Notez que la boucle est beaucoup mieux que de donner une réponse incorrecte.

    ?- deletelist([a], Zs, Zs).
ERROR: Out of global stack

?- deletelist(Xs, Xs, Xs).
Xs = [] ;
ERROR: Out of local stack

    OriginalL'auteur false

  4. 0
    
% sorry!

deletelist(Xs,Ys,Zs) :-
        findall(A,(
                    member(A,Xs),
                    \+(member(A,Ys))),
                Zs).

    OriginalL'auteur 尾崎隆大

  5. 0
    deletelist(Xs,[],Xs).
deletelist(Xs,[Y|Ys],Zs):-
    delete(Xs,Y,As),
    deletelist(As,Ys,Zs).

    Pour supprimer un seul élément dans une liste, il est une fonction de la bibliothèque "supprimer/3' pour une liste et un élément que vous souhaitez supprimer de la liste et retourne la nouvelle liste, avec l'élément supprimé. J'ai fait usage de cette et recuresed overs la liste des articles qui ont besoin de les retirer de la liste.

    OriginalL'auteur Tom3993