Puis-je obtenir les résultats d'une procédure stockée dans un curseur dans une autre procédure stockée dans SQL

Je suis en train de mettre les résultats d'une procédure stockée dans un curseur à utiliser dans la procédure en cours. J'ai ajouté mon code ci-dessous mais je ne suis pas sûr si cela est possible ou si ma syntaxe est correcte?

DECLARE cursorIDList CURSOR FOR
    EXEC spGetUserIDs
OPEN cursorIDList

FETCH NEXT FROM cursorIDList INTO @ID

Je reçois l'erreur suivante: syntaxe Incorrecte près de 'EXEC'. Attend SÉLECTIONNER, '(' ou AVEC.

Merci d'avance.

source d'informationauteur Sun

  1. 7

    Vous pouvez le faire comme ceci:

    DECLARE @t TABLE (ID INT)
INSERT INTO @t
EXEC spGetUserIDs

DECLARE cursorIDList CURSOR FOR
    SELECT * FROM @t
OPEN cursorIDList

FETCH NEXT FROM cursorIDList INTO @ID
  2. 0

    à mon avis très intéressante approche serait d'utiliser le curseur en paramètre (bien que si tu ne va pas mettre à jour le tableau, je ne pense pas que son meilleur choix):

    create Table dbo.MyTable
(
    i int 
);
Insert Into dbo.MyTable (i) values (1)
Insert Into dbo.MyTable (i) values (2)
Insert Into dbo.MyTable (i) values (3)
Insert Into dbo.MyTable (i) values (4)
Go
Set NoCount ON;
Go
Create Proc dbo.myProc 
(
    @someValue int,
    @cur Cursor Varying Output
)
As
Begin 
    declare @x int;

    Set @cur = Cursor for
        Select i From dbo.MyTable
        Where i < @someValue;

    open @cur
End
Go
-- Use of proc
declare @cur cursor;
declare @x int;
Exec dbo.myProc 3, @cur output


fetch next from @cur into @x
while @@fetch_status = 0
begin
    print 'value: ' + cast(@x as varchar)
    fetch next from @cur into @x
end

close @cur;
Deallocate @cur;

Go
--Cleanup
Drop Proc dbo.myProc 
Drop Table dbo.MyTable
  3. 0

    La syntaxe de curseur dans SQL-Server:

    DECLARE cursor_name [ INSENSITIVE ] [ SCROLL ] CURSOR FOR select_statement

    Après FOR vous devez écrire un SELECT.

    Pour plus d'infos, voir:
    https://msdn.microsoft.com/it-it/library/ms180169.aspx