Puis-je passer un curseur explicite d'une fonction/procédure pour l'utilisation en boucle?

J'ai une procédure qui effectue des calculs sur tous les enregistrements renvoyés par un curseur. Il ressemble un peu à ceci:

PROCEDURE do_calc(id table.id_column%TYPE)
IS
  CURSOR c IS
    SELECT col1, col2, col3
      FROM table
     WHERE ...;
BEGIN
  FOR r IN c LOOP
    -- do some complicated calculations using r.col1, r.col2, r.col3 etc.
  END LOOP;
END;

Maintenant j'ai le cas où j'ai besoin d'effectuer exactement le même calcul sur un ensemble de dossiers qui viennent d'une autre table. Cependant, elles ont la même "forme" comme ci-dessus dans l'exemple.

Est-il possible d'écrire une procédure qui ressemble à ceci:

PROCEDURE do_calc2(c some_cursor_type)
IS
BEGIN
  FOR r IN c LOOP
    -- do the calc, knowing we have r.col1, r.col2, r.col3, etc.
  END LOOP;
END;

Je sais à propos de SYS_REFCURSOR, mais je me demandais si il était possible d'utiliser le beaucoup plus pratique FOR ... LOOP syntaxe et implicites de type d'enregistrement.

Non, vous ne pouvez pas passer un curseur statique en tant que paramètre. Les réponses ci-dessous vous suggérons déclaration de plusieurs curseurs statiques dans certains étendue partagée et de manière sélective les appeler à l'intérieur de procédures, probablement à l'aide de certains if...then logique que personne ne l'a spécifié, ou encore le passage d'un curseur ref. Vous pourriez peut-être convertir un ref cursor en statique à l'aide d'un pipeline de la table de fonction similaire à williamrobertson.net/documents/refcursor-to-csv.shtml, cependant, il peut être un peu de un projet, donc si vous êtes simplement à la recherche pour la commodité du curseur DE la boucle, alors vous êtes hors de la chance.

OriginalL'auteur David Sykes | 2012-05-17

plsql

11

Créer un package.

Déclarer votre curseur en tant que variable de package.

Utilisation %rowtype pour définir les paramètres de la fonction type.
```
create or replace package test is
  cursor c is select 1 as one, 2 as two from dual;

  procedure test1;
  function test2(test_record c%ROWTYPE) return number;

end test;


create or replace package body test is
  procedure test1 is    
  begin
    for r in c loop      
      dbms_output.put_line(test2(r));
    end loop;
  end;

  function test2(test_record c%ROWTYPE) return number is
    l_summ number;
  begin
    l_summ := test_record.one + test_record.two;
    return l_summ;
  end;
end test;
```
Merci Vassili, je n'étais pas sûr de PL/SQL peut gérer que le niveau de l'structurelle de frappe, mais il fonctionne comme un charme! 🙂
Vous êtes les bienvenus )
salut @VasilyKomarov.. si le curseur de la déclaration de paramètre que vous transmettez en tant qu'entrée à toutes les fonctions et procédures dans l'ensemble.. comme par exemple.. curseur c est 1 sélectionnez l'un, 2 que les deux de double où row = row_id ; où row_id est le paramètre

OriginalL'auteur Vasily Komarov

J'ai eu un problème similaire, où j'ai eu deux curseurs qui devaient être traitées de la même façon, donc, c'est comment j'ai pensé à elle.

DECLARE
   --Define our own rowType
   TYPE employeeRowType IS RECORD (
      f_name           VARCHAR2(30),
      l_name            VARCHAR2(30));
   --Define our ref cursor type
   --If we didn't need our own rowType, we could have this: RETURN employees%ROWTYPE
   TYPE empcurtyp IS REF CURSOR RETURN employeeRowType;

   --Processes the cursors
   PROCEDURE process_emp_cv (emp_cv IN empcurtyp) IS
      person employeeRowType;
   BEGIN
      LOOP
         FETCH emp_cv INTO person;
         EXIT WHEN emp_cv%NOTFOUND;
         DBMS_OUTPUT.PUT_LINE('Name = ' || person.f_name ||
                          ' ' || person.l_name);
      END LOOP;
   END;

   --Defines the cursors
   PROCEDURE mainProcedure IS
    emp empcurtyp;
   BEGIN
      OPEN emp FOR SELECT first_name, last_name FROM employees WHERE salary > 50000;
      process_emp_cv(emp);
      CLOSE emp;

      OPEN emp FOR SELECT first_name, last_name FROM kuren WHERE first_name LIKE 'J%';
      process_emp_cv(emp);
      CLOSE emp;
   END;

BEGIN
  mainProcedure;
END;
/

Vous pouvez également utiliser cette option si vous souhaitez en vrac recueillir vos curseurs. Vous avez juste besoin de changer votre assistant de procédure process_emp_cv; le reste peut rester la même.

En VRAC à l'aide de RECUEILLIR

 --Processes the cursors
   PROCEDURE process_emp_cv (emp_cv IN empcurtyp) IS
      TYPE t_employeeRowTable IS TABLE OF employeeRowType;
      employeeTable   t_employeeRowTable;
   BEGIN
      LOOP
         FETCH emp_cv BULK COLLECT INTO employeeTable LIMIT 50;
         FOR indx IN 1 .. employeeTable.Count
         LOOP
            DBMS_OUTPUT.PUT_LINE('Name = ' || employeeTable(indx).f_name ||
                          ' ' || employeeTable(indx).l_name);
         END LOOP;
         EXIT WHEN emp_cv%NOTFOUND;
      END LOOP;
   END;

OriginalL'auteur plasmaTonic

Essayer celui-ci, Usong curseur ref.

    declare
    type c is ref cursor;
    c2 c;
    type rec is record(
    id number,
    name varchar(20)
    );
    r rec;
    procedure p1(c1 in out c,r1 in out rec)is begin

    loop
    fetch c1 into r1;
    exit when c1%notfound;
    dbms_output.put_line(r1.id || ' ' ||r1.name);
    end loop;
    end;
    begin
    open c2 for select id, name from student;
    p1(c2,r);
    end;

OriginalL'auteur Amalendu Kar

-1

Oui, vous pouvez utiliser le Curseur explicitement dans la procédure et de la fonction,pour que le curseur besoin de le déclarer dans le package comme variable

OriginalL'auteur user2001117

Vous devez vous connecter pour publier un commentaire.