Quelle est la bonne méthode pour insérer des valeurs dans un tableau excel en utilisant VBA?

J'ai besoin d'être en mesure d'insérer un grand ensemble de valeurs dans une table vide dans excel à l'aide du code VBA.
Voici comment le code fonctionne jusqu'à présent.

Tout d'abord, l'utilisateur doit entrer une valeur dans un objet userform. Le code puis efface la table puis s'en va et trouve une plage de nombres en fonction de critères de recherche déjà dans le code. Les données extraites sont tous les contenus dans une seule colonne, et stockée comme un tableau.

À partir d'ici, j'ai besoin de placer toutes les valeurs d'une colonne dans la table (Politique no), élargissant ainsi le tableau des lignes, cependant, le nombre de lignes dans le jeu de données récupérées. (J'ai le comte déjà stockées séparément "AC" si c'est nécessaire) L'en-tête de colonne je veux insérer dans est Politique"#".

En gardant à l'esprit qu'il y a seulement une ligne vide dans la table à l'heure actuelle du code, comment puis-je insérer les données correctement? J'ai essayé

 range("commissionstatement[Policy #]").value = Als

mais qui ne fonctionne pas. La sla est le tableau de valeurs. Généralement pour insérer le tableau que j'ai insérer dans une gamme de taille égale, ce qui est pourquoi j'ai pris le nombre de lignes comme CA déjà.

J'ai aussi essayé d'utiliser range("commissionstatement").listobject.listrows mais qui ne fonctionne pas non plus.

Des conseils? Vais-je avoir besoin d'insérer un certain nombre de lignes dans la table égal au nombre de données im ajoutant, avant que je place les données dans là comme ça...

range("commissionstatement").listobject.listrows.add ()

suivi en insérant les données?

Laissez-moi savoir si plus d'informations sont nécessaires. Merci!

OriginalL'auteur Ashton Sheets | 2012-08-22

  1. 6

    En supposant que vous utilisez Excel 2010, essayez ceci (peut ne pas fonctionner avec les versions antérieures d'Excel)

    Sub AddToList()
    Dim lo As ListObject
    Dim ws As Worksheet
    Dim Als() As Variant
    Dim rng As Range

    Set ws = ActiveSheet

    ' Get reference to table
    Set lo = ws.ListObjects("MyTable")  ' <--- Update this with your table name

    If lo.InsertRowRange Is Nothing Then
        ' List already has data
        Set rng = lo.ListRows.Add.Range
    Else
        ' List is empty
        Set rng = lo.InsertRowRange
    End If

    '  *** Remove one of these two lines ***
    ' If Als is a 1 dimensional array
    rng.Cells(1, lo.ListColumns("Policy #").Index).Resize(UBound(Als) - LBound(Als) + 1, 1) = Application.Transpose(Als)

    ' If Als is 2 dimensional array (1 to rows, 1 to 1)
    rng.Cells(1, lo.ListColumns("Policy #").Index).Resize(UBound(Als, 1), 1) = Als
End Sub
    J'aime à quoi ça ressemble, je vais certainement donner un coup de feu. J'ai fait une solution de contournement qui a fait le tour temporairement, mais il n'est pas aussi dynamique et flexible que lorsque la table est correctement redimensionnée comme dans votre exemple.

    OriginalL'auteur chris neilsen

  2. 0

    Cela a fonctionné pour moi. Je suis également remplir un vide ListObject avec des données d'un tableau. Pour que cela fonctionne, le tableau matriu doit être un tableau en 2 dimensions.

    Dim matriu() As Variant
Dim ls As ListObject

Set ls = Hoja1.ListObjects(1)

' Retrieve data
matriu = Hoja1.Range("Origen")

' Erease all rows of the ListObject, if needed
ls.DataBodyRange.Delete

' This line is needed in order for the next line 
' not to throw an error if the listobject is empty.
ls.ListRows.Add

' Fill the ListObject with all data in one operation to reduce execution time    
Range(ls.DataBodyRange.Cells(1, 1), _
   ls.DataBodyRange.Cells(UBound(matriu, 1), UBound(matriu, 2))) = matriu

    OriginalL'auteur Jordi