Quelle est la façon la plus simple d'appeler Http OBTENIR l'url à l'aide de Delphi?

Il y a des services web j'ai envie d'appeler ma demande, je peux l'utiliser à l'importation de l'WSDL ou par l'utilisation juste "HTTP GET" avec l'URL et les paramètres, donc je préfère le plus tard parce que c'est quelque chose de simple.

Je sais que je peux utiliser indy idhttp.obtenir, pour faire le travail, mais c'est très simple et je ne veux pas ajouter des indy code de mon application.

Mise à JOUR: désolé si je n'ai pas été clair, je voulais dire par "ne pas ajouter des indy code", que je ne veux pas ajouter des composants indy pour cette tâche simple, et préfèrent plus de manière plus légère pour cette.

Pensez-vous simplement à l'aide de HTTP GET est assez pour invocating un webservice fonction ?
Si c'est un service web RESTful.
je ne savais pas de REPOS peut avoir wsdl trop
AhmetCiftci, comme je l'ai dit avant, le service a "HTTP GET", url de l'appeler, alors pouvez utiliser le WSDL ou par simple requête HTTP GET"

InformationsquelleAutor Mohammed Nasman | 2008-11-19

27

Vous pouvez utiliser le API WinINet comme ceci:
```
uses WinInet;

function GetUrlContent(const Url: string): string;
var
  NetHandle: HINTERNET;
  UrlHandle: HINTERNET;
  Buffer: array[0..1024] of Char;
  BytesRead: dWord;
begin
  Result := '';
  NetHandle := InternetOpen('Delphi 5.x', INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0);

  if Assigned(NetHandle) then 
  begin
    UrlHandle := InternetOpenUrl(NetHandle, PChar(Url), nil, 0, INTERNET_FLAG_RELOAD, 0);

    if Assigned(UrlHandle) then
      { UrlHandle valid? Proceed with download }
    begin
      FillChar(Buffer, SizeOf(Buffer), 0);
      repeat
        Result := Result + Buffer;
        FillChar(Buffer, SizeOf(Buffer), 0);
        InternetReadFile(UrlHandle, @Buffer, SizeOf(Buffer), BytesRead);
      until BytesRead = 0;
      InternetCloseHandle(UrlHandle);
    end
    else
      { UrlHandle is not valid. Raise an exception. }
      raise Exception.CreateFmt('Cannot open URL %s', [Url]);

    InternetCloseHandle(NetHandle);
  end
  else
    { NetHandle is not valid. Raise an exception }
    raise Exception.Create('Unable to initialize Wininet');
end;
```
source: http://www.scalabium.com/faq/dct0080.htm

L'API WinINet utilise les mêmes choses InternetExplorer est à l'aide de sorte que vous obtenez également toute connexion et les paramètres de proxy défini par internet explorer gratuitement.
- Obtenir les paramètres d'internet explorer "gratuit" n'est qu'une fonction de si vous utilisez internet explorer. 🙂
- Merci Lars, c'est la voie lumineuse 🙂
- Comme le dit bruce, si vous aviez un IE mal configuré pour utiliser un paramètre de proxy qui est en panne, par exemple, vous serez assailli, trop. Obscure, et frustrant, si c'est arrivé.
- J'ai appris d'expérience maintenant que vous bénéficiez également de tous les bugs d'IE wininet.dll qui est installé sur votre système du client, gratuitement, y compris la crainte DÉLAI de bug. ÊTRE CONSCIENT.
- ceux qui se fixe dans la sécurité des mises à jour et des service packs, tandis que votre propre code ou de quelqu'un elses ne fait pas passer le même examen critique par de nombreux globes oculaires.
- Et ils se cassent. Pourquoi sont cassés WinInet versions jamais fixe jusqu'à ce que la mise à niveau vers une nouvelle version de IE? Terrible. Pas corrigés dans un service pack à moins que IE lui-même est forcée de passer par un service pack.
- Notez que WinInet ne doit pas être utilisée dans les services.
- Notez que ce code ne prend pas les encodages de caractères en compte. Il suppose char/string sont de 8 bits et les magasins de la crue de réponse octets en tant que-est dans le retour de l' string. Le corps de la réponse a un encodage, ce qui est spécifié/déduit de l'-têtes de réponse HTTP. Et string a un codage de trop, qu'il s'agisse de l'ANSI en D2007 et plus tôt, ou UTF-16 dans D2009 et plus tard. Le code doit convertir le corps de la réponse des données à partir de la réponse de l'encodage Unicode, et puis de l'Unicode pour strings'encodage natif.
- Indy TIdHTTP composant gère les conversions pour vous quand il retourne une réponse du corps comme un string.
InformationsquelleAutor Lars Truijens
33

Appel d'un service web RESTful à l'aide d'Indy est assez simple.

Ajouter IdHTTP à votre clause uses. Rappelez-vous que IdHTTP besoins de la "HTTP://" préfixe sur votre Url.
```
function GetURLAsString(const aURL: string): string;
var
  lHTTP: TIdHTTP;
begin
  lHTTP := TIdHTTP.Create;
  try
    Result := lHTTP.Get(aURL);
  finally
    lHTTP.Free;
  end;
end;
```
- La question était de savoir si elle pourrait se faire sans l'Indy
- La question était de ne pas ajouter des Indy code. Le code n'est pas complexe.
- Bruce, Lars est bon, je l'ai dit dans mes questions, je ne veux pas utiliser indyt "idhttp.get", c'est la façon la plus simple, mais je voulais la voie lumineuse 🙂
- Votre "plus léger" option consiste à utiliser un code externe, si c'est Indy, Synapse ou WinINet. Si vous ne pouvez pas ou ne voulez pas utiliser Delphi composants ou des classes, l'utilisation de Delphi fonctions wrapper autour de WinINet. À l'extérieur, mais au moins, la DLL est installé avec Windows.
- Dans sa défense, Indy est livré avec Delphi, mais WinInet version et les changements de comportement installé avec la version de IE, qui est comme l'enfer des DLL.
- Dans ma situation, ajoutant idHTTP fait mon exe sauter de 300K à 2 mo qui ne marche pas toujours la matière, mais dans mon cas, n'importe.
- Je serais très curieux de savoir pourquoi. Quelle version de Delphi, et du type de demande (VCL/Console)?
- Je pense que c'était Delphi XE . Dans Delphi 7, il est un peu un saut peut-être à environ 800K mais dans le XE beaucoup plus grand. Application Console. Aucune idée de pourquoi ça fait tellement de bien plus gros, beaucoup de code à compiler dans, je suppose.
- Une console vide app est 40K en D7 et 83K dans DXE. L'ajout de IdHttp à la clause uses prend à 139K et 739K respectivement. Je ne suis pas sûr où que 2 MO vient de. Il sonne comme il pourrait être une version de Delphi compilé en mode Debug.
- TIdHTTP.Create(nil); peut être raccourcie à TIdHTTP.Create; avec Indy 10.6
InformationsquelleAutor Bruce McGee

En fait le code accepté réponse n'a pas fonctionné pour moi. Alors je l'ai modifié un peu de sorte qu'il renvoie en fait à Cordes et gracieusement se ferme tout le temps après l'exécution. Exemple renvoie les données récupérées comme UTF8String de sorte qu'il va bien travailler pour ASCII ainsi que pour de l'utf-8 pages.

uses WinInet;

function GetUrlContent(const Url: string): UTF8String;
var
  NetHandle: HINTERNET;
  UrlHandle: HINTERNET;
  Buffer: array[0..1023] of byte;
  BytesRead: dWord;
  StrBuffer: UTF8String;
begin
  Result := '';
  NetHandle := InternetOpen('Delphi 2009', INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0);
  if Assigned(NetHandle) then
    try
      UrlHandle := InternetOpenUrl(NetHandle, PChar(Url), nil, 0, INTERNET_FLAG_RELOAD, 0);
      if Assigned(UrlHandle) then
        try
          repeat
            InternetReadFile(UrlHandle, @Buffer, SizeOf(Buffer), BytesRead);
            SetString(StrBuffer, PAnsiChar(@Buffer[0]), BytesRead);
            Result := Result + StrBuffer;
          until BytesRead = 0;
        finally
          InternetCloseHandle(UrlHandle);
        end
      else
        raise Exception.CreateFmt('Cannot open URL %s', [Url]);
    finally
      InternetCloseHandle(NetHandle);
    end
  else
    raise Exception.Create('Unable to initialize Wininet');
end;

Espère que cela aide pour quelqu'un comme moi qui était à la recherche de code facile comment faire pour récupérer le contenu de la page en Delphi.
Cheers, Aldis 🙂

Et il fonctionne avec des Url HTTPS 😉
Cela ne fonctionne que si la réponse est en fait codé en ASCII ou UTF-8, ce qui n'est pas une garantie.

InformationsquelleAutor Aldis

7

Si c'est ok pour télécharger un fichier, vous pouvez utiliser TDownloadURL de la ExtActns unité. Beaucoup plus simple que l'utilisation de WinInet directement.
```
procedure TMainForm.DownloadFile(URL: string; Dest: string);
var
  dl: TDownloadURL;
begin
  dl := TDownloadURL.Create(self);
  try
    dl.URL := URL;
    dl.FileName := Dest;
    dl.ExecuteTarget(nil); //this downloads the file
  finally
    dl.Free;
  end;
end;
```
Il est également possible d'obtenir des notifications de progression lors de l'utilisation de ce. Il suffit d'assigner un gestionnaire d'événement pour TDownloadURL de OnDownloadProgress événement.

InformationsquelleAutor Michael Madsen

Dans les plus récentes versions de Delphi, il est préférable d'utiliser THTTPClient de System.Net.HttpClient unité, puisque c'est la norme et de la croix-plate-forme. Exemple Simple est

function GetURL(const AURL: string): string;
var
  HttpClient: THttpClient;
  HttpResponse: IHttpResponse;
begin
  HttpClient := THTTPClient.Create;
  try
    HttpResponse := HttpClient.Get(AURL);
    Result := HttpResponse.ContentAsString();
  finally
    HttpClient.Free;
  end;
end;

InformationsquelleAutor EugeneK

4

À l'aide de Windows HTTP API peut être trop facile.
```
procedure TForm1.Button1Click(Sender: TObject);
var http: variant;
begin
 http:=createoleobject('WinHttp.WinHttpRequest.5.1');
 http.open('GET', 'http://lazarus.freepascal.org', false);
 http.send;
 showmessage(http.responsetext);
end;
```
Dans le code ci-dessus, je suppose que COM a déjà été initialisé pour le principal VCL fil. Apparemment, il pourrait ne pas être toujours le cas pour simpliste applications ou pour LCL apps. Aussi il serait certainement pas le cas pour les async (multithread) de travail.

Ci-dessous l'extrait d'un véritable code en cours d'exécution. Remarque: la fonctionnalité est bonus. Il n'est pas nécessaire de travailler. Ainsi, alors que je ne émettre des demandes, je ne se soucient pas de leurs résultats, que le résultat est ignoré et sous-évaluées.
```
procedure TfmHaspList.YieldBlinkHTTP(const LED: boolean; const Key_Hardware_ID: cardinal);
var URL: WideString;
begin
  URL := 'http://127.0.0.1:1947/action.html?blink' +
    IfThen( LED, 'on', 'off') + '=' + IntToStr(Key_Hardware_ID);

  TThread.CreateAnonymousThread(
    procedure
    var Request: OleVariant;
    begin
      // COM library initialization for the current thread
      CoInitialize(nil);
      try
        // create the WinHttpRequest object instance
        Request := CreateOleObject('WinHttp.WinHttpRequest.5.1');
        // open HTTP connection with GET method in synchronous mode
        Request.Open('GET', URL, False);
        // set the User-Agent header value
//        Request.SetRequestHeader('User-Agent', 'Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.0');
        // sends the HTTP request to the server, the Send method does not return
        // until WinHTTP completely receives the response (synchronous mode)
        Request.Send;
//        // store the response into the field for synchronization
//        FResponseText := Request.ResponseText;
//        // execute the SynchronizeResult method within the main thread context
//        Synchronize(SynchronizeResult);
      finally
        // release the WinHttpRequest object instance
        Request := Unassigned;
        // uninitialize COM library with all resources
        CoUninitialize;
      end;
    end
  ).Start;
end;
```
- Oui, c'est une excellente solution et simple, mais n'oubliez pas d'appeler CoInitialize(nil); et CoUninitialize au début et à la fin, respectivement.
- Qui est mentionné dans les liens vers le thread asynchrone cas. Dans cet exemple précis cependant l'objet s'opère au sein des principaux VCL fil, où COM déjà été initialisé. Je suppose (mais n'a pas vérifié) en est de même pour LCL sur Windows
- Peut-être que quelqu'un devrait mentionner TJvURLGrabber objet de JediVCL ainsi...
- Salut, oui. Je l'ai mentionné parce que mon appli m'a donné "Com pas initialisé, ou quelque chose d'erreur" quand je l'ai utilisé (standard TForm avec un bouton). Également pour quelque raison que quand j'ai arrêté l'application, il s'est écrasé après l'utilisation de la CoInitialize et CoUninitialize méthodes. Juste pour info.
- A été votre "http" variable locale? Se pourrait-il que vous n'avez pas détruit/effacé la variable avant de CoUnInitialize, si elle a conservé le pointeur de l'objet COM après COM sous-système fermé?
- Dans mon cas précis j'avais besoin de faire des appels à localhost service, donc il ne devrait pas bloquer l'interface graphique et je n'ai pas besoin de résultats du tout, même pas de succès/d'état d'erreur. Alors j'ai continué de frai TThread.Travailleurs anonymes, qui initialisé et fermée COM en eux-mêmes. A travaillé comme un charme.
- Bonjour, @supersan . Un peu de necroposting ici. Juste tombé sur une situation dans Delphi XE2 lorsque la norme des dialogues Ouvrir/Enregistrer n'a tout simplement pas de travail. Principalement PromptForFileName fonction, mais en réalité l'ensemble de la sous-système. Il s'est avéré, dans XE2 les enregistrer/ouvrir la fonctionnalité est implémentée via COM, et que la fonction a été appelée à l'intérieur d'un thread, COM Pas Initialisé, l'erreur a été signalée par Windows et avalé par la VCL. Toutefois, depuis TOpenFileDialog est un standard de Delphi composant et de travaux simples et fiables dans les principales VCL fil, que signifie COM devient auto-initialisée dans le thread principal, quelque part
- Juste pour la référence à mon précédent commentaire: stackoverflow.com/questions/6719853/...
InformationsquelleAutor Arioch 'The
2

Utiliser le Synapse TCP/IP fonction dans le HTTPSEND unité (HTTPGetText, HTTPGetBinary). Il fera le HTTP pull pour vous et ne nécessite pas de DLL externes autres que Winsock. La dernière version SVN fonctionne parfaitement bien dans Delphi 2009. On utilise à cette fonction de blocage des appels, donc pas d'événements au programme.

Mise à jour: Les unités sont très légers, et ne sont pas à base de composants. La dernière version de SVN fonctionne parfaitement bien en Delphi XE4 aussi.
- HTTP appels à Indy sont également de blocage.
InformationsquelleAutor skamradt
0

Si votre application est uniquement pour Windows, je vous recommande d'utiliser WinSock. C'est assez simple, permet d'exécuter une requête HTTP, peut fonctionner en mode synchrone et asynchrone (à l'aide de non-blocage WSASend/WSARecv avec des rappels ou des bons vieux send/recv dans un thread dédié).
- Bien que Winsock peut être utilisée directement pour cela, je ne le recommanderais pas. HTTP est un complexe bête à mettre en œuvre à partir de zéro manuellement.
InformationsquelleAutor user2024154

Vous devez vous connecter pour publier un commentaire.