Quelle est la meilleure façon d'ouvrir et de lire un fichier en Perl?

Veuillez noter que je ne suis pas à la recherche de la "bonne" façon d'ouvrir/lire un fichier, ou la façon dont je devrais ouvrir/lire un fichier à chaque fois. Je suis juste intéressé de savoir quelle façon la plupart des gens utilisent, et peut-être apprendre quelques nouvelles méthodes en même temps :)*

Très commun de bloc de code de mes programmes Perl est l'ouverture d'un fichier et de la lecture ou de l'écriture pour elle. J'ai vu tellement de façons de le faire, et mon style sur la réalisation de cette tâche a changé au fil des ans un certain nombre de fois. Je me demandais simplement ce que le meilleur (si il y a une meilleure façon) la méthode est de faire cela?

J'ai utilisé pour ouvrir un fichier comme ceci:

my $input_file = "/path/to/my/file";
open INPUT_FILE, "<$input_file"  || die "Can't open $input_file: $!\n";

Mais je pense qui a des problèmes avec la récupération d'erreur.

L'ajout d'une parenthèse semble corriger l'erreur de piégeage:

open (INPUT_FILE, "<$input_file")  || die "Can't open $input_file: $!\n";

Je sais que vous pouvez également attribuer un descripteur de fichier à une variable, donc au lieu d'utiliser "INPUT_FILE" comme je l'ai fait ci-dessus, j'aurais pu utiliser $input_filehandle - est de cette façon mieux?

Pour la lecture d'un fichier, si il est petit, il n'y a rien de mal avec d'expansion, comme ça?

my @array = <INPUT_FILE>;

ou

my $file_contents = join( "\n", <INPUT_FILE> );

ou devriez-vous toujours en boucle, comme ceci:

my @array;
while (<INPUT_FILE>) {
  push(@array, $_);
}

Je sais qu'il y a de nombreuses façons d'accomplir des choses en perl, je me demandais simplement si il y a des privilégiés/des méthodes standard de l'ouverture et de la lecture dans un fichier?

  • Le perlopentut de la page de manuel couvre la plupart de ce problème assez bien.
InformationsquelleAutor BrianH | 2008-11-25
  1. 58

    Il n'existe pas de normes universelles, mais il y a des raisons de préférer l'un ou l'autre. Ma forme préférée est: est-ce

    open( my $input_fh, "<", $input_file ) || die "Can't open $input_file: $!";

    Les raisons sont:

    • Vous signaler les erreurs immédiatement. (Remplacer "mourir" à "avertir" si c'est ce que vous voulez.)
    • Votre descripteur de fichier est maintenant de référence-compté, donc une fois que vous ne l'utilisez pas, il sera automatiquement fermé. Si vous utilisez le nom global INPUT_FILEHANDLE, alors vous devez fermer le fichier manuellement ou il restera ouvert jusqu'à ce que le programme se termine.
    • La lecture indicateur de mode "<" est séparé de l' $input_file, l'augmentation de la lisibilité.

    La suite est grande si le fichier est petit et vous savez que vous voulez toutes les lignes:

    my @lines = <$input_fh>;

    Vous pouvez même le faire, si vous avez besoin de traiter toutes les lignes comme une seule chaîne:

    my $text = join('', <$input_fh>);

    Pour les longs fichiers que vous voulez pour effectuer une itération sur les lignes avec tout, ou utiliser la lecture.

    • ou une légère variation... open my $input_fh, '<', $input_file or die "impossible d'ouvrir $input_file: $!";
    • Je pense toujours que ce est réutilisable. Utilisez simplement File::Slurp ou Tie::File.
    • __Édition belles tof!
    • Également envisager de use autodie; qui feront de vos opérations d'e / s mortels par défaut. Plus facile que d'écrire "ou mourir" partout.
    • Un peu plus de raisons pourquoi cela est bon: 1) descripteur de fichier est dans le domaine lexical, pas de paquet (global), de sorte que vous êtes moins susceptibles d'avoir d'autres code de l'utiliser par accident 2) vous pouvez facilement passer le descripteur de fichier pour les sous-routines sans vous embêter avec typeglobs 3) séparant le mode de lecture de l'indicateur "<" c'est plus que juste des raisons de lisibilité; il empêche les effets désastreux que si un nom de fichier commence (par exemple) avec une "> le caractère".
    InformationsquelleAutor JSBձոգչ
  2. 15

    Si vous voulez que le fichier entier comme une seule chaîne de caractères, il n'est pas nécessaire d'itérer à travers elle.

    use strict;
use warnings;
use Carp;
use English qw( -no_match_vars );
my $data = q{};
{
   local $RS = undef; # This makes it just read the whole thing,
   my $fh;
   croak "Can't open $input_file: $!\n" if not open $fh, '<', $input_file;
   $data = <$fh>;
   croak 'Some Error During Close :/' if not close $fh;
}

    Ci-dessus satisfait perlcritic --brutal, ce qui est un bon moyen de tester les "meilleures pratiques":). $input_file est toujours pas défini ici, mais le reste est casher.

    • Ce n'local $RS = undef; faire?
    • $RS est le même que $/ qui English met en place pour vous. $/ est la variable qui suit la row seperator valeur pour <$fh>, qui est synonyme de la notion de get-line , ou $fh->getline(). Essentiellement, il contient la valeur interne de lire algorithme utilise pour savoir quand il a lu un plein line de données, et de mettre ce paramètre à undef signifie "il n'y a pas de marqueur qui indique une ligne complète" de sorte qu'il lit dans le fichier entier comme une "ligne"
    InformationsquelleAutor Kent Fredric
  3. 13

    Avoir à écrire "ou la mort" partout me pousse à la noix. Mon préféré d'ouvrir un fichier ressemble à ceci:

    use autodie;

open(my $image_fh, '<', $filename);

    Alors que c'est très peu de frappe, il y a beaucoup de choses importantes à noter qui sont en cours:

    • Nous sommes à l'aide de la autodie pragma, ce qui signifie que tous Perl intégré-ins va lever une exception si quelque chose va mal. Il élimine le besoin d'écrire un or die ... dans votre code, il produit de l'amicale, lisible par l'homme, les messages d'erreur, et l'a portée lexicale. Il est disponible sur le CPAN.

    • Nous utilisons les trois-argument version de open. Cela signifie que même si nous avons un drôle de nom de fichier contenant des caractères tels que <, > ou |, Perl va toujours faire la bonne chose. Dans mon Perl Sécurité tutoriel à OSCON j'ai montré un certain nombre de façons d'obtenir 2-argument open à mal se conduire. Les billets pour ce tutoriel sont disponibles pour téléchargement gratuit à partir de Perl Formation de l'Australie.

    • Nous sommes à l'aide d'un scalaire descripteur de fichier. Cela signifie que nous n'allons pas être une coïncidence de clôture de quelqu'un d'autre descripteur de fichier du même nom, ce qui peut arriver si nous utilisons paquet de descripteurs de fichiers. Il signifie aussi strict pouvez repérer les fautes de frappe, et que notre descripteur de fichier sera nettoyé automatiquement si elle est hors de portée.

    • Nous sommes à l'aide d'un significative descripteur de fichier. Dans ce cas, il semble bien que nous allons écrire à une image.

    • Le descripteur de fichier se termine avec _fh. Si nous nous voir en l'utilisant comme un scalaire, alors nous savons que c'est probablement une erreur.

    • Très bonne idée, merci! J'ai aussi n'avait jamais vu les 3 argument de la méthode pour "ouvrir" - je crois que j'aime de cette façon! Merci!
    InformationsquelleAutor pjf
  4. 11

    Si vos fichiers sont suffisamment petits pour que la lecture de toute la chose dans la mémoire est possible, utilisez Fichier::Slurp. Il lit et écrit les fichiers complets avec un très API simple, plus il effectue toutes les vérification d'erreur si vous n'avez pas à.

    • Fichier::Slurp est génial, mais il est beaucoup plus lent que Kent Fredric la lecture directe. (~4000 10-30k fichiers dans 7s direct vs 56s slurped par nytprof)
    InformationsquelleAutor Dave Rolsky
  5. 6

    Il n'y a pas de meilleur moyen pour ouvrir et lire un fichier. C'est pas la bonne question à se poser. Ce qui est dans le fichier? Quelle quantité de données que vous avez besoin à tout moment? Avez-vous besoin de toutes les données à la fois? Que devez-vous faire avec ces données? Vous avez besoin de trouver des personnes avant de penser à la façon dont vous avez besoin pour ouvrir et lire le fichier.

    Est tout ce que vous faites maintenant vous cause des problèmes? Si non, vous n'avez pas mieux les problèmes à résoudre? 🙂

    Plus de votre question est simplement de la syntaxe, et qui tous ont répondu dans la documentation Perl (en particulier (perlopentut). Vous pouvez également ramasser L'Apprentissage De Perl, qui répond à la plupart des problèmes que vous avez dans votre question.

    Bonne chance 🙂

    • Alors peut-être que je ne devrais pas avoir demandé à ce que le meilleur moyen d'ouvrir/lire un fichier, mais ce que font la plupart des gens. J'ai écrit des centaines de programmes perl que les fichiers ouverts, et vous voulez juste pour s'assurer que je vais à ce sujet dans le bon sens. Je n'ai pas eu de problèmes, je suis juste curieux de voir comment d'autres personnes le font. Merci!
    • Encore une fois, lisez le premier paragraphe. Le meilleur moyen dépend de ce que vous faites.
    • Je ne dis pas le Perl::Critic est la loi, mais de nombreuses façons d'ouvrir des fichiers dans "l'Apprentissage de Perl" ne passent pas Perl::Critic. En fait, la façon dont j'ai utilisé pour ouvrir les fichiers de tous les temps est la façon dont je l'ai appris dans "l'Apprentissage de Perl". Je dirais que les meilleures pratiques peuvent être appliquées à la plupart des situations où un fichier doit être ouvert, et que vous n'avez pas besoin de connaître les petits détails - sinon, je voudrais demander, "Quelle est la meilleure manière d'ouvrir un fichier binaire et compter les octets" ou quelque chose comme ça. 99% des fichiers que j'ai ouvert sont en texte brut, et j'ai juste envie de la lire dans un tableau. Je suis intéressé à connaître les meilleures pratiques
    • Vous devez avoir une vieille Apprentissage de Perl, alors.
    • Que pourrait - 3ème outre, en 2002, je vais devoir chercher une version plus récente.
    • Vous n'avez pas à chercher pour trouver la Cinquième édition, qui est l'actuel.
    • Est sorti et a acheté la 5ème plus - heureux que j'ai fait il y a quelques grandes mises à jour! Le critique n'apprécie pas de mot nu descripteurs de fichiers, et je ne vois pas d'exemples dans la 5ème édition où le non-mot nu les descripteurs de fichiers sont utilisés. Nouveau - ne pas dire Critique est la loi, mais c'était le point de ma question: PBP/Critique dit d'utiliser 3 argument s'ouvre, et non de mot nu de descripteurs de fichiers. L'apprentissage de Perl n'est pas de montrer des exemples de non-mot nu descripteurs de fichiers (que je peux trouver). Ne pas dire de toute façon est bon/mauvais - mais ma question était de voir comment la plupart des gens le faire.

    InformationsquelleAutor brian d foy
  6. 5

    C'est vrai qu'il y a comme un grand nombre des meilleures façons d'ouvrir un fichier en Perl comme il y a

    $files_in_the_known_universe * $perl_programmers

    ...mais c'est toujours intéressant de voir qui habituellement t-il la voie. Ma forme préférée de siphonage (lecture de l'ensemble de fichiers à la fois) est:

    use strict;
use warnings;

use IO::File;

my $file = shift @ARGV or die "what file?";

my $fh = IO::File->new( $file, '<' ) or die "$file: $!";
my $data = do { local $/; <$fh> };
$fh->close();

# If you didn't just run out of memory, you have:
printf "%d characters (possibly bytes)\n", length($data);

    Et quand aller ligne par ligne:

    my $fh = IO::File->new( $file, '<' ) or die "$file: $!";
while ( my $line = <$fh> ) {
    print "Better than cat: $line";
}
$fh->close();

    Caveat lector de cours: ce sont des approches que je leur ai promis de muscle de la mémoire de travail de tous les jours, et ils peuvent être radicalement inadapté pour le problème que vous essayez de résoudre.

    InformationsquelleAutor
  7. 5

    Pour OO, j'aime:

    use FileHandle;
...
my $handle = FileHandle->new( "< $file_to_read" );
croak( "Could not open '$file_to_read'" ) unless $handle;
...
my $line1 = <$handle>;
my $line2 = $handle->getline;
my @lines = $handle->getlines;
$handle->close;
    • Et puis ne vous le lisez avec <$handle> ?
    • Oui, il va travailler avec le "itération de l'opérateur", mais vous pouvez également le lire avec $handle->getline ou $handle->getlines
    InformationsquelleAutor Axeman
  8. 4

    Une fois, j'ai utilisé le

    open (FILEIN, "<", $inputfile) or die "...";
my @FileContents = <FILEIN>;
close FILEIN;

    réutilisable régulièrement. Aujourd'hui, j'utilise File::Slurp pour les petits fichiers que je veux la tenir entièrement dans la mémoire, et Tie::File pour les gros fichiers que je veux de manière échelonnée adresse et/ou les fichiers que je veux changer de place.

    InformationsquelleAutor Svante
  9. 3

    Lire l'intégralité du fichier $fichier dans la variable $texte avec une seule ligne

    $text = do {local(@ARGV, $/) = $file ; <>};

    ou comme une fonction

    $text = load_file($file);
sub load_file {local(@ARGV, $/) = @_; <>}
    InformationsquelleAutor
  10. 2

    Si ces programmes sont juste pour votre productivité, tout ce qui fonctionne! Construire en autant d'erreur de manipulation que vous pensez que vous avez besoin.

    Lecture dans un fichier entier si c'est important peut-être pas le meilleur moyen à long terme de faire des choses, de sorte que vous pouvez les lignes de production à mesure qu'ils sont plutôt que de les charger dans un tableau.

    Une astuce que j'ai reçu de l'un des chapitres de La Pragmatique Programmeur (Hunt & Thomas) est ce que vous pourriez voulez avoir le script enregistrer une copie de sauvegarde du fichier pour vous avant qu'il se met au travail, trancher et couper en dés.

    InformationsquelleAutor John
  11. 2

    La || opérateur a une priorité plus élevée, de sorte qu'il est évalué en premier, avant d'envoyer le résultat à "ouvrir"... Dans le code que vous avez mentionné, utilisez l'opérateur "ou" à la place, et tu n'aurais pas ce problème.

    open INPUT_FILE, "<$input_file"
  or die "Can't open $input_file: $!\n";
    InformationsquelleAutor Ape-inago
  12. 1

    Damian Conway est-il de cette façon:

    $data = readline!open(!((*{!$_},$/)=$_)) for "filename";

    Mais je ne le recommande pas pour vous.

    • Comment ça fonctionne?
    • il définit $/ par le fnud (slurp mode) et affecte \$_ à *{""}; attribution d'une référence à un glob remplace simplement la fente de la catégorie de référence, de sorte que ${""} est un alias pour $_ (qui a de la valeur "nom de fichier"). l' ! nie la valeur de la cession (1 depuis la liste d'affectation dans un contexte scalaire donne le nombre d'éléments sur le droit de la assingment) est donc fausse. ouvrir traite la valeur false "", ouvre la *{""} descripteur de fichier, et un arg ouvrir obtient le nom du fichier à ouvrir dans le scalaire de la goutte. si ouvrir renvoie la valeur true, la readline traite également la fausse donnée par la ! comme l' *{""} descripteur de fichier
    InformationsquelleAutor ysth