Quelle est la meilleure pratique pour rendre les sprites en DirectX 11?

Je suis en train d'essayer de s'habituer à l'API DirectX et je me demande qu'est-ce que l'approche habituelle pour afficher un sprite en DirectX 11 (par exemple, pour un clone de tetris).

Est-il un simmilar interface ID3DX10Sprite, et si non, quel serait la méthode habituelle pour dessiner des sprites en DirectX 11?

Edit: Voici le code HLSL qui a fonctionné pour moi (le calcul de la projection de coordonner pourrait faire mieux):

struct SpriteData
{
    float2 position;
    float2 size;
    float4 color;
};

struct VSOut
{
    float4 position : SV_POSITION;
    float4 color : COLOR;
};

cbuffer ScreenSize : register(b0)
{
    float2 screenSize;
    float2 padding; //cbuffer must have at least 16 bytes
}

StructuredBuffer<SpriteData> spriteData : register(t0);

float2 GetVertexPosition(uint VID)
{
    [branch] switch(VID)
    {
        case 0:
            return float2(0, 0); 
        case 1:
            return float2(1, 0); 
        case 2:
            return float2(0, 1); 
        default:
            return float2(1, 1);
    }
}

float4 ComputePosition(float2 positionInScreenSpace, float2 size, float2 vertexPosition)
{
    float2 origin = float2(-1, 1);
    float2 vertexPositionInScreenSpace = positionInScreenSpace + (size * vertexPosition);

    return float4(origin.x + (vertexPositionInScreenSpace.x /(screenSize.x /2)), origin.y - (vertexPositionInScreenSpace.y /(screenSize.y /2)), 1, 1);
}

VSOut VShader(uint VID : SV_VertexID, uint SIID : SV_InstanceID)
{
    VSOut output;

    output.color = spriteData[SIID].color;
    output.position = ComputePosition(spriteData[SIID].position, spriteData[SIID].size, GetVertexPosition(VID));

    return output;
}

float4 PShader(float4 position : SV_POSITION, float4 color : COLOR) : SV_TARGET
{
    return color;
}

OriginalL'auteur Mario Pistrich | 2010-10-07

  1. 6

    Pas il n'y a pas d'équivalent. La méthode habituelle serait de tracer un triangle bande formant un quad.

    Vous pourriez faire usage de l'instanciation, donc vous avez juste à mettre à jour un tampon avec le sprite de données (x, y de la position de l'écran en pixels, de l'id de la texture fetch dans une texture tableau, mise à l'échelle, rotation, couche, etc) et l'utilisation des shaders pour le rendu de tous les sprites en un seul appel.

    Voici quelques HLSL informations croustillantes sur le dessus de ma tête:

    //--------------------------------------------------------------------------------------
//Shader code for Sprite Rendering
//--------------------------------------------------------------------------------------

struct Sprite {
    float2 position; //x, y world position
    float rotation;
    float scaling;

    float layer; //if you have multiple layers of sprites (e.g. background sprites)
    uint textureId;
};

StructuredBuffer<Sprite> SpritesRO : register( t0 );
Texture2DArray<float4> TextureSlices : register (t1);

cbuffer cbRenderConstants : register( b0 )
{
    matrix g_mViewProjection;
    //other constants
};

struct VSSpriteOut
{
    float3 position : SV_Position;
    uint textureId;
};

//-------------------------------------------------------------------------------------            
//Sprite Vertex Shader
//-------------------------------------------------------------------------------------

VSSpriteOut SpriteVS(uint VID : SV_VertexID, uint SIID : SV_InstanceID)
{
    VSSpriteOut Out = (VSSpriteOut)0;

    //VID is either 0, 1, 2 or 3
    //We can map 0 to position (0,0), 1 to (0,1), 2 to (1,0), 3 to (1,1)

    //We fetch the sprite instance data accord SIID
    Sprite sdata = SpritesRO[SIID];

    //function f computes screen space vertex position
    float3 pos = f (g_mViewProjection, VID, position, rotation, scaling, layer etc)

    Out.position = pos;
    Out.textureId = sdata.textureId;

    return Out;
}

//-------------------------------------------------------------------------------------
//Sprite Pixel Shader
//-------------------------------------------------------------------------------------

float4 SpritePS(VSSpriteOut In) : SV_Target
{
    //use In.textureId to fetch the right texture slice in texture array
    return color;
}
    Pourriez-vous me donner un court exemple de code s'il vous plaît? J'ai du mal à commencer avec le tampon.
    Découvrez tous les D3D11 échantillons de DXSDK, et d'examiner attentivement la façon dont ils le font pour la création de Tampons, de les lier, de les mettre à jour, etc.
    Wow, merci. Cela m'a vraiment aidé pour commencer 🙂

    OriginalL'auteur Stringer