Quels sont les avantages de l'utilisation de Classes en VBA?

L'avantage de l'utilisation de classes au lieu de simplement les sous-programmes est que les classes de créer un niveau d'abstraction qui vous permettent d'écrire plus propre code. Certes, si vous n'avez jamais utilisé des classes avant d'en VBA, il y a une courbe d'apprentissage, mais je crois qu'il vaut certainement la peine de le temps de le comprendre.

Une indication clé que vous devriez passer à des classes est si vous êtes constamment en ajoutant des paramètres à vos fonctions et sous-routines. Dans ce cas, il est presque toujours préférable d'utiliser des classes.

J'ai copié une explication des classes à partir de un de mes précédents Débordement de Pile réponses:

---

Voici un long exemple de la façon dont l'aide d'une classe peut vous aider. Bien que cet exemple est long, il va vous montrer comment quelques principes de la programmation orientée objet peut vraiment vous aider à nettoyer votre code.

Dans l'éditeur VBA, allez à la Insert > Class Module. Dans la fenêtre des Propriétés (en bas à gauche de l'écran par défaut), modifier le nom du module à WorkLogItem. Ajoutez le code suivant à la classe:

Option Explicit

Private pTaskID As Long
Private pPersonName As String
Private pHoursWorked As Double

Public Property Get TaskID() As Long
    TaskID = pTaskID
End Property

Public Property Let TaskID(lTaskID As Long)
    pTaskID = lTaskID
End Property

Public Property Get PersonName() As String
    PersonName = pPersonName
End Property

Public Property Let PersonName(lPersonName As String)
    pPersonName = lPersonName
End Property

Public Property Get HoursWorked() As Double
    HoursWorked = pHoursWorked
End Property

Public Property Let HoursWorked(lHoursWorked As Double)
    pHoursWorked = lHoursWorked
End Property

Le code ci-dessus va nous donner un typage fort des objets spécifiques pour les données avec lesquelles nous travaillons. Lorsque vous utilisez multi-dimension des tableaux pour stocker vos données, votre code ressemble à ceci: arr(1,1) est l'ID, arr(1,2) est le PersonName, et arr(1,3) est le HoursWorked. En utilisant cette syntaxe, il est difficile de savoir ce qui est quoi. Imaginons que vous toujours charger vos objets dans un tableau, mais au lieu d'utiliser la WorkLogItem que nous avons créé ci-dessus. Ce nom, vous seriez en mesure de faire arr(1).PersonName pour obtenir le nom de la personne. Qui rend votre code plus facile à lire.

Nous allons continuer d'avancer avec cet exemple. Au lieu de stocker les objets dans le tableau, nous allons essayer d'utiliser un collection.

Ensuite, ajoutez un nouveau module de classe et de l'appeler ProcessWorkLog. Placez le code suivant dedans:

Option Explicit

Private pWorkLogItems As Collection

Public Property Get WorkLogItems() As Collection
    Set WorkLogItems = pWorkLogItems
End Property

Public Property Set WorkLogItems(lWorkLogItem As Collection)
    Set pWorkLogItems = lWorkLogItem
End Property

Function GetHoursWorked(strPersonName As String) As Double
    On Error GoTo Handle_Errors
    Dim wli As WorkLogItem
    Dim doubleTotal As Double
    doubleTotal = 0
    For Each wli In WorkLogItems
        If strPersonName = wli.PersonName Then
            doubleTotal = doubleTotal + wli.HoursWorked
        End If
    Next wli

Exit_Here:
    GetHoursWorked = doubleTotal
        Exit Function

Handle_Errors:
        'You will probably want to catch the error that will '
        'occur if WorkLogItems has not been set '
        Resume Exit_Here


End Function

La classe ci-dessus est destiné à être utilisé pour "faire quelque chose" avec une collection de WorkLogItem. D'abord, nous avons juste mis à compter le nombre total d'heures travaillées. Nous allons tester le code que nous avons écrit. Créer un nouveau Module (pas un module de classe cette fois, il suffit d'un "régulier" module). Collez le code suivant dans le module:

Option Explicit

Function PopulateArray() As Collection
    Dim clnWlis As Collection
    Dim wli As WorkLogItem
    'Put some data in the collection'
    Set clnWlis = New Collection

    Set wli = New WorkLogItem
    wli.TaskID = 1
    wli.PersonName = "Fred"
    wli.HoursWorked = 4.5
    clnWlis.Add wli

    Set wli = New WorkLogItem
    wli.TaskID = 2
    wli.PersonName = "Sally"
    wli.HoursWorked = 3
    clnWlis.Add wli

    Set wli = New WorkLogItem
    wli.TaskID = 3
    wli.PersonName = "Fred"
    wli.HoursWorked = 2.5
    clnWlis.Add wli

    Set PopulateArray = clnWlis
End Function

Sub TestGetHoursWorked()
    Dim pwl As ProcessWorkLog
    Dim arrWli() As WorkLogItem
    Set pwl = New ProcessWorkLog
    Set pwl.WorkLogItems = PopulateArray()
    Debug.Print pwl.GetHoursWorked("Fred")

End Sub

Dans le code ci-dessus, PopulateArray() crée simplement une collection de WorkLogItem. Dans votre propre code, vous pouvez créer une classe pour analyser vos feuilles de calcul Excel ou vos objets de données pour remplir une collection ou un tableau.

La TestGetHoursWorked() code montre comment les classes ont été utilisés. Vous remarquez que ProcessWorkLog est instancié comme un objet. Après il est instancié, une collection de WorkLogItem devient une partie de la pwl objet. C'est dans la ligne de Set pwl.WorkLogItems = PopulateArray(). Ensuite, nous avons simplement appeler la fonction que nous avons écrit ce qui agit sur la collection WorkLogItems.

Pourquoi est-ce utile?

Supposons que vos changements de données et vous souhaitez ajouter une nouvelle méthode. Supposons que votre WorkLogItem comprend maintenant un champ pour HoursOnBreak et vous voulez ajouter une nouvelle méthode de calcul qui.

Tout ce que vous devez faire est d'ajouter une propriété à WorkLogItem comme suit:

Private pHoursOnBreak As Double

Public Property Get HoursOnBreak() As Double
    HoursOnBreak = pHoursOnBreak
End Property

Public Property Let HoursOnBreak(lHoursOnBreak As Double)
    pHoursOnBreak = lHoursOnBreak
End Property

Bien sûr, vous aurez besoin de changer votre méthode pour remplir votre collection (l'exemple de la méthode que j'ai utilisé était PopulateArray(), mais vous devez probablement avoir une classe juste pour cela). Ensuite, il suffit d'ajouter votre nouvelle méthode de votre ProcessWorkLog classe:

Function GetHoursOnBreak(strPersonName As String) As Double
     'Code to get hours on break
End Function

Maintenant, si nous voulions mettre à jour notre TestGetHoursWorked() méthode pour retourner un résultat de GetHoursOnBreak, tout ce que nous aurions à faire que d'ajouter la ligne suivante:

    Debug.Print pwl.GetHoursOnBreak("Fred")

Si vous avez passé dans un tableau de valeurs qui représentait vos données, vous devez trouver tous les endroits dans votre code où vous avez utilisé les tableaux et les mettre à jour en conséquence. Si vous utilisez des classes (et leurs objets instanciés) au lieu de cela, on peut très facilement mettre à jour votre code pour travailler avec les changements. Aussi, lorsque vous permettez à la classe pour être consommés dans de multiples manières (peut-être une fonction a besoin de seulement 4 des propriétés des objets si une autre fonction aurez besoin de 6), ils peuvent toujours référence au même objet. Ceci vous évite d'avoir plusieurs tableaux pour les différents types de fonctions.

Pour en savoir plus, je très vous recommandons d'obtenir une copie de VBA Manuel du Développeur, 2e édition. Le livre est plein de bons exemples et bonnes pratiques et des tonnes d'exemples de code. Si vous êtes à investir beaucoup de temps dans VBA pour un projet sérieux, il est bien utile de votre temps à regarder dans ce livre.

Il y a une autre chose que vous pourriez ajouter des avantages que d'autres contributeurs ont dit (désolé si c'est quelque part dans Ben McCormack excellente réponse et je l'ai raté). Les Classes peuvent avoir leurs utilisations si votre script VBA est susceptible d'être re-programmé à un certain point.

Par exemple, je suis en train de concevoir une sorte de système de gestion de commandes. Il est utilisé par plusieurs collègues pendant un certain temps, mais il peut avoir besoin de re-progamming si la commande de changement des règles. J'ai donc conçu une base de classe de l'élément, qui rassemble toutes les informations sur un élément de stock. Les règles sur la façon dont ces données sont analysées pour toute commande sont, cependant, écrit en facilement accessible et bien commenté sous-routines. En faisant cela, j'espère que les futurs programmeurs VBA pouvez facilement changer les règles mathématiques par les commandes qui sont générés, sans avoir à traiter de la façon dont les données sont recueillies au sujet d'un élément de stock (ce qui est fait par les sous-routines et fonctions au sein de la classe, qui sont activés lorsque la classe est remis un numéro de stock). Une Classe de propriétés publiques sont également enregistrées par l'intellisense, permettant à la prochaine programmeur, ainsi que vous-même, pour avoir un temps plus facile de lui.

Je suppose que le point est que les classes peuvent rendre la vie plus facile pour plus tard les utilisateurs de cette façon si ils codent de base d'une série d'informations, ou quelque objet conceptuel, qui est toujours susceptible d'être pertinente pour le contexte de l'utilisation du programme.