Rechercher un tableau de chaînes dans Delphi

Est-il une fonction dans le Delphi standard de la bibliothèque à la recherche de tableaux de chaîne pour une valeur particulière?

par exemple

someArray:=TArray<string>.Create('One','Two','Three');
if ArrayContains(someArray, 'Two') then
    ShowMessage('It contains Two');

source d'informationauteur awmross

  1. 27

    Il n'y a absolument pas besoin de réinventer la roue. StrUtils.MatchStr fait le travail.

    procedure TForm1.FormCreate(Sender: TObject);
var
  someArray: TArray<string>;
begin
  someArray:=TArray<string>.Create('One','Two','Three');
  if MatchStr('Two', someArray) then
    ShowMessage('It contains Two');
end;

    Remarque le paramètre d'ordre de la convention.

    Une autre remarque: MatchStr est un standardisée nom attribué à cette fonction quelque part entre Delphi 7 et Delphi 2007. Historique du nom est AnsiMatchStr (convention est la même que dans le reste de RTL: Str/Texte suffixe pour la casse, Ansi préfixe pour MBCS/Locale)

  2. 5

    vous pouvez utiliser le TArray.BinarySearch fonction, qui fait partie des médicaments Génériques.L'unité Collections.

    vérifier cet échantillon

    {$APPTYPE CONSOLE}

{$R *.res}

uses    
  Generics.Defaults,
  Generics.Collections,
  System.SysUtils;

Var
  someArray: TArray<string>;
  FoundIndex : Integer;

begin
  try
    someArray:=TArray<string>.Create('a','b','c');
    if TArray.BinarySearch<String>(someArray, 'b', FoundIndex, TStringComparer.Ordinal) then
     Writeln(Format('Found in index %d',[FoundIndex]))
    else
     Writeln('Not Found');
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.

    Remarque: BinarySearch exige que le tableau soit trié.

  3. 4

    J'ai écrit un j'ai modélisé d'après l'ancienne Clipper AScan fonction (testé dans XE). @RRUZ la réponse est plus correct (il y a un existant), mais le mien ne nécessite pas le tableau à trier premier et est assez rapide sur les petits tableaux. (Il fonctionne aussi dans les pré-génériques de versions de Delphi.) J'ai aussi de la surcharge de différents types de tableau - voici les implémentations pour string et integer:

    // Returns the 0-based index of Value if it's found in the array,
// -1 if not. (Similar to TStrings.IndexOf)
function AScan(const Ar: array of string; const Value: string): Integer; overload;
var
i: Integer;
begin
Result := -1;
for i := Low(Ar) to High(Ar) do
if SameText(Ar[i], Value) then
begin
Result := i;
Break
end;
end;
function AScan(const Ar: array of Integer; const Value: Integer): Integer; overload;
var
i: Integer;
begin
Result := -1;
for i := Low(Ar) to High(Ar) do
if (Ar[i] = Value) then
begin
Result := i;
Break
end;
end;
procedure TForm2.FormShow(Sender: TObject);
var
someStrArray: TArray<string>;
someIntArray: TArray<Integer>;
Idx: Integer;
begin
someStrArray := TArray<string>.Create('One', 'Two', 'Three');
Idx := AScan(someStrArray, 'Two');
if Idx > -1 then
ShowMessage(Format('It contains Two at index %d', [Idx]))
else
ShowMessage('Not found');
someIntArray := TArray<Integer>.Create(8, 16, 32);
Idx := AScan(someIntArray, 32);
if Idx > -1 then
ShowMessage(Format('It contains 32 at %d', [Idx]))
else
ShowMessage('16 not found');
end;

    Pour les versions de Delphi qui prennent en charge les génériques, voici une version qui ne nécessite pas le tableau à trier, et qui permet aussi de fournir la fonction de comparaison en cas de besoin:

    Interface:

    type
TGenericsUtils = class
public
class function AScan<T>(const Arr: array of T; const Value: T; const Comparer: IEqualityComparer<T>):  Integer; overload;
class function AScan<T>(const Arr: array of T; const Value: T): Integer; overload;
end;

    Mise en œuvre

    class function TGenericsUtils.AScan<T>(const Arr: array of T; const Value: T): Integer;
begin
Result := AScan<T>(Arr, Value, TEqualityComparer<T>.Default);
end;
class function TGenericsUtils.AScan<T>(const Arr: array of T; const Value: T;
const Comparer: IEqualityComparer<T>): Integer;
var
i: Integer;
begin
for i := Low(Arr) to High(Arr) do
if Comparer.Equals(Arr[i], Value) then
Exit(i);
Exit(-1);
end;

    Code de Test:

    var
AIntTest: TIntegerDynArray;
AStrTest: TStringDynArray;
begin
AIntTest := TIntegerDynArray.Create(12, 15, 6, 1, 4, 9, 5);
AStrTest := TStringDynArray.Create('One', 'Six', 'Three', 'Four', 'Twelve');
WriteLn('AIntTest contains 9 at index ', TGenericsUtils.AScan<Integer>(AIntTest, 9));
WriteLn('AStrTest contains ''Four'' at index ', TGenericsUtils.AScan<String>(AStrTest, 'Four'));
ReadLn;
end.