ReDim Preserve pour un Tableau multidimensionnel en Visual Basic 6

Je suis l'aide de VB6 et j'ai besoin de faire un ReDim Preserve pour un Tableau multidimensionnel:

 Dim n, m As Integer
    n = 1
    m = 0
    Dim arrCity() As String
    ReDim arrCity(n, m)

    n = n + 1
    m = m + 1
    ReDim Preserve arrCity(n, m)

Chaque fois que je le fais comme je l'ai écrit, j'obtiens l'erreur suivante:

erreur d'exécution 9: indice en dehors de la plage de

Parce que je ne peut modifier la dernière dimension de la matrice, bien dans ma tâche, j'ai changer tout le tableau (2 dimensions dans mon exemple) !

Est-il une solution ou une autre solution pour cela?

OriginalL'auteur Ouerghi Yassine | 2013-05-04

6

Comme vous le précisez à juste titre, on peut ReDim Preserve seulement la dernière dimension d'un tableau (Instruction ReDim sur MSDN):

Si vous utilisez le mot clé Preserve, vous pouvez redimensionner seulement le dernier tableau
dimension et vous ne pouvez pas modifier le nombre de dimensions. Pour
exemple, si votre tableau n'a qu'une dimension, vous pouvez la redimensionner pour qu'
dimension parce que c'est la dernière et la seule dimension. Toutefois, si votre
tableau a deux dimensions ou plus, vous pouvez modifier la taille de la
dernière dimension et de préserver le contenu de la matrice

Par conséquent, la première question à décider est de savoir si le tableau en 2 dimensions est la meilleure structure de données pour le travail. Peut-être, 1 tableau multidimensionnel est un meilleur ajustement que vous devez faire ReDim Preserve?

Une autre façon est d'utiliser de tableau en escalier comme par Pieter Geerkens la suggestion de. Il n'y a pas de support direct pour les tableaux irréguliers en VB6. Un moyen de code de "tableau de tableaux" en VB6 est de déclarer un tableau de Variant et faire de chaque élément d'un tableau de type désiré (String dans votre cas). Le code de démonstration ci-dessous.

Encore une autre option est de mettre en œuvre Preserve partie sur votre propre. Pour cela, vous aurez besoin de créer une copie des données qui doivent être préservées et puis remplissez redimensionné tableau avec elle.
```
Option Explicit
Public Sub TestMatrixResize()
Const MAX_D1 As Long = 2
Const MAX_D2 As Long = 3
Dim arr() As Variant
InitMatrix arr, MAX_D1, MAX_D2
PrintMatrix "Original array:", arr
ResizeMatrix arr, MAX_D1 + 1, MAX_D2 + 1
PrintMatrix "Resized array:", arr
End Sub
Private Sub InitMatrix(a() As Variant, n As Long, m As Long)
Dim i As Long, j As Long
Dim StringArray() As String
ReDim a(n)
For i = 0 To n
ReDim StringArray(m)
For j = 0 To m
StringArray(j) = i * (m + 1) + j
Next j
a(i) = StringArray
Next i
End Sub
Private Sub PrintMatrix(heading As String, a() As Variant)
Dim i As Long, j As Long
Dim s As String
Debug.Print heading
For i = 0 To UBound(a)
s = ""
For j = 0 To UBound(a(i))
s = s & a(i)(j) & "; "
Next j
Debug.Print s
Next i
End Sub
Private Sub ResizeMatrix(a() As Variant, n As Long, m As Long)
Dim i As Long
Dim StringArray() As String
ReDim Preserve a(n)
For i = 0 To n - 1
StringArray = a(i)
ReDim Preserve StringArray(m)
a(i) = StringArray
Next i
ReDim StringArray(m)
a(n) = StringArray
End Sub
```
J'ai peur que si il y aura une "incompatibilité de type" erreur dans la ligne "StringArray=a(i)" dans la fonction ResizeMatrix. Si je passe devant la plage de la vieille matrice a(i) est de type Variant/Vide. Peut être passé à quelque chose du type Chaîne de caractères()?

OriginalL'auteur Ilya Kurnosov
4

Depuis VB6 est très similaire à VBA, je pense que je pourrais avoir une solution qui ne nécessite pas de cette quantité de code à ReDim un tableau en 2 dimensions - à l'aide de Transpose.

La solution (VBA):
```
Dim n, m As Integer
n = 2
m = 1
Dim arrCity() As Variant
ReDim arrCity(1 To n, 1 To m)
m = m + 1
ReDim Preserve arrCity(1 To n, 1 To m)
arrCity = Application.Transpose(arrCity)
n = n + 1
ReDim Preserve arrCity(1 To m, 1 To n)
arrCity = Application.Transpose(arrCity)
```
Ce qui est différent de l'OP de la question: la limite inférieure de arrCity tableau n'est pas 0, mais 1. C'est dans le but de laisser Application.Transpose faire son travail.

Je pense que vous devriez avoir le Transpose méthode en VB6.

Pas de. La transposition est une méthode de l'objet d'Application Excel (qui en réalité est un raccourci vers l'Application.WorksheetFunction.La transposition). Il n'en est rien en VB6. Et en VBA, il faut prendre soin lors de l'utilisation de Transposer comme il a deux limitations importantes. Si le tableau a plus de 65536 éléments, il échouera. Dans n'IMPORTE quel élément de la longueur d'dépasser 256 caractères, il échouera. Si cela n'est pas un problème, alors Transposer faudra bien convertir le rang d'une matrice de la forme 1D 2D ou vice-versa.
Puis-je vous demander où/comment avez-vous appris de cette Application.La transposition est un raccourci à la Demande.WorksheetFunction.Transposer ?

OriginalL'auteur ZygD
2

En ce qui concerne cette:

"dans ma tâche, j'ai changer tout le tableau (2 dimensions"

Il suffit d'utiliser un tableau en escalier (c'est à dire un tableau de tableaux de valeurs). Ensuite, vous pouvez modifier les dimensions que vous souhaitez. Un peu plus de travail, peut-être, mais une solution.

VB6 ne prend pas en charge des tableaux de tableaux
oui, c'est fait. Vous pouvez avoir un 1-D tableau de variantes, et les variantes peuvent contenir des tableaux.

OriginalL'auteur Pieter Geerkens

Je n'ai pas testé chacun de ces réponses, mais vous n'avez pas besoin d'utiliser de fonctions complexes pour accomplir cette tâche. C'est tellement plus simple! Mon code ci-dessous dans n'importe quel bureau VBA application (Word, Access, Excel, Outlook, etc.) et est très simple. Espérons que cela aide:

''Dimension 2 Arrays
Dim InnerArray(1 To 3) As Variant ''The inner is for storing each column value of the current row
Dim OuterArray() As Variant ''The outer is for storing each row in
Dim i As Byte
i = 1
Do While i <= 5
''Enlarging our outer array to store a/another row
ReDim Preserve OuterArray(1 To i)
''Loading the current row column data in
InnerArray(1) = "My First Column in Row " & i
InnerArray(2) = "My Second Column in Row " & i
InnerArray(3) = "My Third Column in Row " & i
''Loading the entire row into our array
OuterArray(i) = InnerArray
i = i + 1
Loop
''Example print out of the array to the Intermediate Window
Debug.Print OuterArray(1)(1)
Debug.Print OuterArray(1)(2)
Debug.Print OuterArray(2)(1)
Debug.Print OuterArray(2)(2)

OriginalL'auteur Sam Slaughterbeck

1

Je sais c'est un peu vieux, mais je pense qu'il y a peut-être une solution beaucoup plus simple qui ne nécessite pas de codage supplémentaire:

Au lieu de transposition, de redimming et la transposition de nouveau, et si l'on parle d'un tableau à deux dimensions, pourquoi ne pas stocker les valeurs transposé pour commencer avec. Dans ce cas, l'instruction redim preserve augmente de fait la droite (deuxième) dimension depuis le début. Ou en d'autres termes, de visualiser, pourquoi ne pas stocker dans des deux lignes, au lieu de deux colonnes si seulement le nombre de colonnes peut être augmenté avec l'instruction redim preserve.

l'index serait que d'être 00-01, 01-11, 02-12, 03-13, 04-14, 05-15 ... 0 25-1 25 etc au lieu de 00-01, 10-11, 20-21, 30-31, 40-41, etc..

Tant qu'il y a une seule dimension qui doit être redimmed conservé l'approche fonctionne encore: il suffit de mettre cette dimension dernier.

Le second (ou le dernier) dimension peut être conservé pendant redimming, on pourrait peut-être dire que c'est la façon dont les tableaux sont censés être utilisés pour commencer avec.
Je n'ai pas vu cette solution, n'importe où, alors peut-être que je suis surplombant quelque chose?

(Posté plus tôt sur la même question, concernant les deux dimensions, l'étendue de réponse ici pour plus d'dimensions)

OriginalL'auteur hombibi

Vous pouvez utiliser un type défini par l'utilisateur contenant un tableau de chaînes de caractères qui seront à l'intérieur de la matrice. Ensuite, vous pouvez utiliser un tableau de ce type défini par l'utilisateur comme à l'extérieur de la matrice.

Ont un look à la suite d'un projet de test:

'1 form with:
'  command button: name=Command1
'  command button: name=Command2
Option Explicit
Private Type MyArray
strInner() As String
End Type
Private mudtOuter() As MyArray
Private Sub Command1_Click()
'change the dimensens of the outer array, and fill the extra elements with "1"
Dim intOuter As Integer
Dim intInner As Integer
Dim intOldOuter As Integer
intOldOuter = UBound(mudtOuter)
ReDim Preserve mudtOuter(intOldOuter + 2) As MyArray
For intOuter = intOldOuter + 1 To UBound(mudtOuter)
ReDim mudtOuter(intOuter).strInner(intOuter) As String
For intInner = 0 To UBound(mudtOuter(intOuter).strInner)
mudtOuter(intOuter).strInner(intInner) = "1"
Next intInner
Next intOuter
End Sub
Private Sub Command2_Click()
'change the dimensions of the middle inner array, and fill the extra elements with "2"
Dim intOuter As Integer
Dim intInner As Integer
Dim intOldInner As Integer
intOuter = UBound(mudtOuter) / 2
intOldInner = UBound(mudtOuter(intOuter).strInner)
ReDim Preserve mudtOuter(intOuter).strInner(intOldInner + 5) As String
For intInner = intOldInner + 1 To UBound(mudtOuter(intOuter).strInner)
mudtOuter(intOuter).strInner(intInner) = "2"
Next intInner
End Sub
Private Sub Form_Click()
'clear the form and print the outer,inner arrays
Dim intOuter As Integer
Dim intInner As Integer
Cls
For intOuter = 0 To UBound(mudtOuter)
For intInner = 0 To UBound(mudtOuter(intOuter).strInner)
Print CStr(intOuter) & "," & CStr(intInner) & " = " & mudtOuter(intOuter).strInner(intInner)
Next intInner
Print "" 'add an empty line between the outer array elements
Next intOuter
End Sub
Private Sub Form_Load()
'init the arrays
Dim intOuter As Integer
Dim intInner As Integer
ReDim mudtOuter(5) As MyArray
For intOuter = 0 To UBound(mudtOuter)
ReDim mudtOuter(intOuter).strInner(intOuter) As String
For intInner = 0 To UBound(mudtOuter(intOuter).strInner)
mudtOuter(intOuter).strInner(intInner) = CStr((intOuter + 1) * (intInner + 1))
Next intInner
Next intOuter
WindowState = vbMaximized
End Sub

Exécutez le projet et cliquez sur le formulaire pour afficher le contenu des tableaux.

Cliquez sur Command1 pour agrandir l'extérieur de tableau, et cliquez sur le formulaire à nouveau pour afficher les résultats.

Cliquez sur Command2 pour agrandir intérieure d'un tableau, et cliquez sur le formulaire à nouveau pour afficher les résultats.

Attention cependant: lorsque vous redim que l'extérieur de la matrice, vous avez également de redimensionner l'intérieur des tableaux pour tous les nouveaux éléments de l'extérieur de la matrice de

OriginalL'auteur Hrqls

0

Je suis tombé sur cette question, tout en frappant de ce bloc de route moi-même. J'ai fini par écrire un morceau de code réel rapide à manipuler ce ReDim Preserve sur un nouveau tableau de taille (première ou la dernière dimension). Peut-être que ça aidera d'autres personnes qui font face au même problème.

Donc, pour l'utilisation, disons que vous avez de votre tableau défini à l'origine comme MyArray(3,5), et vous voulez faire les dimensions (la première!) plus grand, permet de dire à MyArray(10,20). Vous avez l'habitude de faire quelque chose comme ce droit?
```
 ReDim Preserve MyArray(10,20) '<-- Returns Error
```
Mais malheureusement, cela renvoie une erreur, parce que vous avez essayé de modifier la taille de la première dimension. Donc, avec ma fonction, vous faites juste quelque chose comme ceci à la place:
```
 MyArray = ReDimPreserve(MyArray,10,20)
```
Maintenant le tableau est plus grand, et les données sont conservées. Votre ReDim Preserve pour un Multi-Dimension tableau est complet. 🙂

Et le dernier mais non le moindre, le miracle de la fonction: ReDimPreserve()
```
'redim preserve both dimensions for a multidimension array *ONLY
Public Function ReDimPreserve(aArrayToPreserve,nNewFirstUBound,nNewLastUBound)
ReDimPreserve = False
'check if its in array first
If IsArray(aArrayToPreserve) Then       
'create new array
ReDim aPreservedArray(nNewFirstUBound,nNewLastUBound)
'get old lBound/uBound
nOldFirstUBound = uBound(aArrayToPreserve,1)
nOldLastUBound = uBound(aArrayToPreserve,2)         
'loop through first
For nFirst = lBound(aArrayToPreserve,1) to nNewFirstUBound
For nLast = lBound(aArrayToPreserve,2) to nNewLastUBound
'if its in range, then append to new array the same way
If nOldFirstUBound >= nFirst And nOldLastUBound >= nLast Then
aPreservedArray(nFirst,nLast) = aArrayToPreserve(nFirst,nLast)
End If
Next
Next            
'return the array redimmed
If IsArray(aPreservedArray) Then ReDimPreserve = aPreservedArray
End If
End Function
```
J'ai écrit cela dans 20 minutes, donc il n'y a pas de garanties. Mais si vous souhaitez utiliser ou à le prolonger, n'hésitez pas. J'aurais pensé que quelqu'un aurait un code comme celui-là déjà, eh bien, apparemment pas. Donc, ici, ya aller collègues réducteurs.

OriginalL'auteur Control Freak

C'est plus compact et le respect de la intial première position dans le tableau et il suffit d'utiliser le premier lié à ajouter de la valeur ancienne.

Public Sub ReDimPreserve(ByRef arr, ByVal size1 As Long, ByVal size2 As Long)
Dim arr2 As Variant
Dim x As Long, y As Long
'Check if it's an array first
If Not IsArray(arr) Then Exit Sub
'create new array with initial start
ReDim arr2(LBound(arr, 1) To size1, LBound(arr, 2) To size2)
'loop through first
For x = LBound(arr, 1) To UBound(arr, 1)
For y = LBound(arr, 2) To UBound(arr, 2)
'if its in range, then append to new array the same way
arr2(x, y) = arr(x, y)
Next
Next
'return byref
arr = arr2
End Sub

J'appelle ce sous avec cette ligne pour redimensionner la première dimension

ReDimPreserve arr2, UBound(arr2, 1) + 1, UBound(arr2, 2)

Vous pouvez ajouter un autre test afin de vérifier si la taille initiale n'est pas supérieure à nouveau tableau. Dans mon cas, il n'est pas nécessaire

OriginalL'auteur GeoStoneMarten

Vous devez vous connecter pour publier un commentaire.